[gentoo-commits] gentoo-x86 commit in sys-devel/libtool: libtool-2.4.2-r1.ebuild libtool-9999.ebuild ChangeLog

[Michal Gorny (mgorny)]

mgorny      14/05/02 10:30:31

  Modified:             libtool-9999.ebuild ChangeLog
  Added:                libtool-2.4.2-r1.ebuild
  Log:
  Introduce multilib support, bug #499390.
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key EFB4464E!)

Revision  Changes    Path
1.16                 sys-devel/libtool/libtool-9999.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-devel/libtool/libtool-9999.ebuild?rev=1.16&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-devel/libtool/libtool-9999.ebuild?rev=1.16&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-devel/libtool/libtool-9999.ebuild?r1=1.15&r2=1.16

Index: libtool-9999.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-devel/libtool/libtool-9999.ebuild,v
retrieving revision 1.15
retrieving revision 1.16
diff -u -r1.15 -r1.16
--- libtool-9999.ebuild	18 Jan 2014 03:56:58 -0000	1.15
+++ libtool-9999.ebuild	2 May 2014 10:30:31 -0000	1.16
@@ -1,12 +1,12 @@
 # Copyright 1999-2014 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sys-devel/libtool/libtool-9999.ebuild,v 1.15 2014/01/18 03:56:58 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-devel/libtool/libtool-9999.ebuild,v 1.16 2014/05/02 10:30:31 mgorny Exp $
 
-EAPI="2" #356089
+EAPI="4"
 
 LIBTOOLIZE="true" #225559
 WANT_LIBTOOL="none"
-inherit eutils autotools multilib unpacker
+inherit eutils autotools multilib unpacker multilib-minimal
 
 if [[ ${PV} == "9999" ]] ; then
 	EGIT_REPO_URI="git://git.savannah.gnu.org/${PN}.git
@@ -26,7 +26,11 @@
 
 RDEPEND="sys-devel/gnuconfig
 	>=sys-devel/autoconf-2.65
-	>=sys-devel/automake-1.11.1"
+	>=sys-devel/automake-1.11.1
+	abi_x86_32? (
+		!<=app-emulation/emul-linux-x86-baselibs-20140406-r2
+		!app-emulation/emul-linux-x86-baselibs[-abi_x86_32(-)]
+	)"
 DEPEND="${RDEPEND}
 	test? ( !<sys-devel/binutils-2.20 )
 	app-arch/xz-utils"
@@ -54,18 +58,17 @@
 	epunt_cxx
 }
 
-src_configure() {
+multilib_src_configure() {
 	# the libtool script uses bash code in it and at configure time, tries
 	# to find a bash shell.  if /bin/sh is bash, it uses that.  this can
 	# cause problems for people who switch /bin/sh on the fly to other
 	# shells, so just force libtool to use /bin/bash all the time.
 	export CONFIG_SHELL=/bin/bash
-
+	ECONF_SOURCE="${S}" \
 	econf $(use_enable static-libs static)
 }
 
-src_install() {
-	emake DESTDIR="${D}" install || die
+multilib_src_install_all() {
 	dodoc AUTHORS ChangeLog* NEWS README THANKS TODO doc/PLATFORMS
 
 	# While the libltdl.la file is not used directly, the m4 ltdl logic
@@ -75,7 +78,7 @@
 	# Building libtool with --disable-static will cause the installed
 	# helper to not build static objects by default.  This is undesirable
 	# for crappy packages that utilize the system libtool, so undo that.
-	dosed '1,/^build_old_libs=/{/^build_old_libs=/{s:=.*:=yes:}}' /usr/bin/libtool || die
+	sed -i -e '1,/^build_old_libs=/{/^build_old_libs=/{s:=.*:=yes:}}' "${D}"/usr/bin/libtool || die
 
 	local x
 	for x in $(find "${D}" -name config.guess -o -name config.sub) ; do



1.214                sys-devel/libtool/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-devel/libtool/ChangeLog?rev=1.214&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-devel/libtool/ChangeLog?rev=1.214&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-devel/libtool/ChangeLog?r1=1.213&r2=1.214

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-devel/libtool/ChangeLog,v
retrieving revision 1.213
retrieving revision 1.214
diff -u -r1.213 -r1.214
--- ChangeLog	18 Jan 2014 03:56:58 -0000	1.213
+++ ChangeLog	2 May 2014 10:30:31 -0000	1.214
@@ -1,6 +1,12 @@
 # ChangeLog for sys-devel/libtool
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-devel/libtool/ChangeLog,v 1.213 2014/01/18 03:56:58 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-devel/libtool/ChangeLog,v 1.214 2014/05/02 10:30:31 mgorny Exp $
+
+*libtool-2.4.2-r1 (02 May 2014)
+
+  02 May 2014; Michał Górny <mgorny@g.o> +libtool-2.4.2-r1.ebuild,
+  libtool-9999.ebuild:
+  Introduce multilib support, bug #499390.
 
   18 Jan 2014; Mike Frysinger <vapier@g.o> libtool-2.4.2.ebuild,
   libtool-9999.ebuild:



1.1                  sys-devel/libtool/libtool-2.4.2-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-devel/libtool/libtool-2.4.2-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-devel/libtool/libtool-2.4.2-r1.ebuild?rev=1.1&content-type=text/plain

Index: libtool-2.4.2-r1.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-devel/libtool/libtool-2.4.2-r1.ebuild,v 1.1 2014/05/02 10:30:31 mgorny Exp $

EAPI="4"

LIBTOOLIZE="true" #225559
WANT_LIBTOOL="none"
inherit eutils autotools multilib unpacker multilib-minimal

if [[ ${PV} == "9999" ]] ; then
	EGIT_REPO_URI="git://git.savannah.gnu.org/${PN}.git
		http://git.savannah.gnu.org/r/${PN}.git"
	inherit git-2
else
	SRC_URI="mirror://gnu/${PN}/${P}.tar.xz"
	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~sparc-fbsd ~x86-fbsd"
fi

DESCRIPTION="A shared library tool for developers"
HOMEPAGE="http://www.gnu.org/software/libtool/"

LICENSE="GPL-2"
SLOT="2"
IUSE="static-libs test vanilla"

RDEPEND="sys-devel/gnuconfig
	!<sys-devel/autoconf-2.62:2.5
	!<sys-devel/automake-1.11.1:1.11
	!=sys-devel/libtool-2*:1.5
	abi_x86_32? (
		!<=app-emulation/emul-linux-x86-baselibs-20140406-r2
		!app-emulation/emul-linux-x86-baselibs[-abi_x86_32(-)]
	)"
DEPEND="${RDEPEND}
	test? ( !<sys-devel/binutils-2.20 )
	app-arch/xz-utils"
[[ ${PV} == "9999" ]] && DEPEND+=" sys-apps/help2man"

src_unpack() {
	if [[ ${PV} == "9999" ]] ; then
		git-2_src_unpack
		cd "${S}"
		./bootstrap || die
	else
		unpacker_src_unpack
	fi
}

src_prepare() {
	use vanilla && return 0

	cd libltdl/m4
	epatch "${FILESDIR}"/1.5.20/${PN}-1.5.20-use-linux-version-in-fbsd.patch #109105
	cd ..
	AT_NOELIBTOOLIZE=yes eautoreconf
	cd ..
	AT_NOELIBTOOLIZE=yes eautoreconf
	epunt_cxx
}

multilib_src_configure() {
	# the libtool script uses bash code in it and at configure time, tries
	# to find a bash shell.  if /bin/sh is bash, it uses that.  this can
	# cause problems for people who switch /bin/sh on the fly to other
	# shells, so just force libtool to use /bin/bash all the time.
	export CONFIG_SHELL=/bin/bash
	ECONF_SOURCE="${S}" \
	econf $(use_enable static-libs static)
}

multilib_src_install_all() {
	dodoc AUTHORS ChangeLog* NEWS README THANKS TODO doc/PLATFORMS

	# While the libltdl.la file is not used directly, the m4 ltdl logic
	# keys off of its existence when searching for ltdl support. #293921
	#use static-libs || find "${D}" -name libltdl.la -delete

	# Building libtool with --disable-static will cause the installed
	# helper to not build static objects by default.  This is undesirable
	# for crappy packages that utilize the system libtool, so undo that.
	sed -i -e '1,/^build_old_libs=/{/^build_old_libs=/{s:=.*:=yes:}}' "${D}"/usr/bin/libtool || die

	local x
	for x in $(find "${D}" -name config.guess -o -name config.sub) ; do
		ln -sf /usr/share/gnuconfig/${x##*/} "${x}" || die
	done
}

pkg_preinst() {
	preserve_old_lib /usr/$(get_libdir)/libltdl.so.3
}

pkg_postinst() {
	preserve_old_lib_notify /usr/$(get_libdir)/libltdl.so.3
}