[gentoo-commits] repo/gentoo:master commit in: dev-lisp/ecls/

[Andrey Grozin]

commit:     f64b9d04818823ed73c8a865112ba10c84fbef6e
Author:     Andrey Grozin <grozin <AT> gentoo <DOT> org>
AuthorDate: Mon Mar  1 04:22:12 2021 +0000
Commit:     Andrey Grozin <grozin <AT> gentoo <DOT> org>
CommitDate: Mon Mar  1 04:22:12 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f64b9d04

dev-lisp/ecls: configure with --enable-libatomic=system

Closes: https://bugs.gentoo.org/710900
Package-Manager: Portage-3.0.16, Repoman-3.0.2
Signed-off-by: Andrey Grozin <grozin <AT> gentoo.org>

 dev-lisp/ecls/ecls-21.2.1-r1.ebuild | 87 +++++++++++++++++++++++++++++++++++++
 1 file changed, 87 insertions(+)

diff --git a/dev-lisp/ecls/ecls-21.2.1-r1.ebuild b/dev-lisp/ecls/ecls-21.2.1-r1.ebuild
new file mode 100644
index 00000000000..6ed6c25641d
--- /dev/null
+++ b/dev-lisp/ecls/ecls-21.2.1-r1.ebuild
@@ -0,0 +1,87 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit eutils multilib
+
+# test phase only works if ecls already installed #516876
+RESTRICT="test"
+
+MY_P=ecl-${PV}
+
+DESCRIPTION="ECL is an embeddable Common Lisp implementation"
+HOMEPAGE="https://common-lisp.net/project/ecl/"
+SRC_URI="https://common-lisp.net/project/ecl/static/files/release/${MY_P}.tgz"
+
+LICENSE="BSD-2 LGPL-2.1+"
+SLOT="0/${PV}"
+KEYWORDS="~amd64 ~ppc ~sparc ~x86 ~amd64-linux"
+IUSE="cxx debug emacs gengc precisegc cpu_flags_x86_sse +threads +unicode X"
+
+CDEPEND="dev-libs/gmp:0
+		dev-libs/libffi
+		dev-libs/libatomic_ops
+		>=dev-libs/boehm-gc-7.1[threads?]
+		>=dev-lisp/asdf-2.33-r3:="
+DEPEND="${CDEPEND}
+		app-text/texi2html
+		emacs? ( >=app-editors/emacs-23.1:* >=app-eselect/eselect-emacs-1.12 )"
+RDEPEND="${CDEPEND}"
+
+S="${WORKDIR}"/${MY_P}
+
+PATCHES=(
+	"${FILESDIR}/${PN}-16.1.3-headers-gentoo.patch"
+	"${FILESDIR}/${PN}-16.1.3-build.patch"
+)
+
+src_prepare() {
+	default
+	cp "${EPREFIX}"/usr/share/common-lisp/source/asdf/build/asdf.lisp contrib/asdf/ || die
+}
+
+src_configure() {
+	econf \
+		--with-system-gmp \
+		--enable-boehm=system \
+		--enable-longdouble=yes \
+		--with-dffi \
+		--enable-libatomic=system \
+		$(use_with cxx) \
+		$(use_enable gengc) \
+		$(use_enable precisegc) \
+		$(use_with debug debug-cflags) \
+		$(use_with cpu_flags_x86_sse sse) \
+		$(use_enable threads) \
+		$(use_with threads __thread) \
+		$(use_enable unicode) \
+		$(use_with unicode unicode-names) \
+		$(use_with X x)
+}
+
+src_compile() {
+	if use emacs; then
+		local ETAGS=$(eselect --brief etags list | sed -ne '/emacs/{p;q}')
+		[[ -n ${ETAGS} ]] || die "No etags implementation found"
+		pushd build > /dev/null || die
+		emake ETAGS=${ETAGS} TAGS
+		popd > /dev/null
+	else
+		touch build/TAGS
+	fi
+
+	#parallel make fails
+	emake -j1
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+
+	dodoc README.md CHANGELOG
+	dodoc "${FILESDIR}"/README.Gentoo
+	pushd build/doc
+	newman ecl.man ecl.1
+	newman ecl-config.man ecl-config.1
+	popd
+}