[gentoo-commits] proj/gnome:master commit in: app-office/gnome-todo/

[Gilles Dartiguelongue]

commit:     4a052dc3eac6d1353928074dabd2b3bd31685db5
Author:     Gilles Dartiguelongue <eva <AT> gentoo <DOT> org>
AuthorDate: Sat Dec 29 12:30:24 2018 +0000
Commit:     Gilles Dartiguelongue <eva <AT> gentoo <DOT> org>
CommitDate: Sat Dec 29 12:37:49 2018 +0000
URL:        https://gitweb.gentoo.org/proj/gnome.git/commit/?id=4a052dc3

app-office/gnome-todo: 3.26.2 → 3.28.1

Made introspection optional. Switch to meson eclass so it is suitable
for ::gentoo. Add missing libxml2 and glib-utils to DEPEND.

Package-Manager: Portage-2.3.53, Repoman-2.3.12
Manifest-Sign-Key: 0x5A56C8CD0C13248A
Signed-off-by: Gilles Dartiguelongue <eva <AT> gentoo.org>

 app-office/gnome-todo/gnome-todo-3.28.1.ebuild | 63 ++++++++++++++++++++++++++
 1 file changed, 63 insertions(+)

diff --git a/app-office/gnome-todo/gnome-todo-3.28.1.ebuild b/app-office/gnome-todo/gnome-todo-3.28.1.ebuild
new file mode 100644
index 00000000..98a79d2a
--- /dev/null
+++ b/app-office/gnome-todo/gnome-todo-3.28.1.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit gnome.org gnome2-utils meson xdg
+
+DESCRIPTION="Personal task manager"
+HOMEPAGE="https://wiki.gnome.org/Apps/Todo"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="gtk-doc +introspection"
+
+RDEPEND="
+	>=dev-libs/glib-2.43.4:2
+	>=x11-libs/gtk+-3.22.0:3[introspection?]
+	>=net-libs/gnome-online-accounts-3.25.3
+	>=dev-libs/libpeas-1.17
+	>=gnome-extra/evolution-data-server-3.17.1:=[gtk]
+	>=dev-libs/libical-0.43
+	introspection? ( >=dev-libs/gobject-introspection-1.42:= )
+"
+DEPEND="${RDEPEND}
+	dev-libs/libxml2:2
+	dev-util/glib-utils
+	gtk-doc? ( dev-util/gtk-doc )
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+src_configure() {
+	# TODO: There aren't any consumers of the introspection outside gnome-todo's own plugins, so maybe we
+	# TODO: should just always build introspection support as an application that needs it for full functionality?
+	# Todoist plugin requires 3.25.3 GOA for being able to add a Todoist account
+	local emesonargs=(
+		-Dbackground_plugin=true
+		-Ddark_theme_plugin=true
+		-Dscheduled_panel_plugin=true
+		-Dscore_plugin=true
+		-Dtoday_panel_plugin=true
+		-Dunscheduled_panel_plugin=true
+		-Dtodo_txt_plugin=true
+		-Dtodoist_plugin=true
+		-Dtracing=false
+		$(meson_use gtk-doc gtk_doc)
+		$(meson_use introspection)
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+	gnome2_icon_cache_update
+}