[gentoo-commits] gentoo-x86 commit in sys-devel/automake: ChangeLog automake-1.10.1-r1.ebuild

[Ulrich Mueller (ulm)]

ulm         08/05/01 21:33:28

  Modified:             ChangeLog
  Added:                automake-1.10.1-r1.ebuild
  Log:
  Fix internal cross references in Info files, bug 183697.
  (Portage version: 2.1.5_rc6)

Revision  Changes    Path
1.117                sys-devel/automake/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-devel/automake/ChangeLog?rev=1.117&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-devel/automake/ChangeLog?rev=1.117&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-devel/automake/ChangeLog?r1=1.116&r2=1.117

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-devel/automake/ChangeLog,v
retrieving revision 1.116
retrieving revision 1.117
diff -u -r1.116 -r1.117
--- ChangeLog	17 Apr 2008 17:26:41 -0000	1.116
+++ ChangeLog	1 May 2008 21:33:27 -0000	1.117
@@ -1,6 +1,12 @@
 # ChangeLog for sys-devel/automake
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-devel/automake/ChangeLog,v 1.116 2008/04/17 17:26:41 nixnut Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-devel/automake/ChangeLog,v 1.117 2008/05/01 21:33:27 ulm Exp $
+
+*automake-1.10.1-r1 (01 May 2008)
+
+  01 May 2008; Ulrich Mueller <ulm@g.o> +automake-1.10.1-r1.ebuild:
+  Fix internal cross references in Info files, bug 183697. Thanks to
+  Alfredo Tupone <tupone@g.o> for the patch.
 
   17 Apr 2008; nixnut <nixnut@g.o> automake-1.10.1.ebuild:
   Stable on ppc wrt bug 217239



1.1                  sys-devel/automake/automake-1.10.1-r1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-devel/automake/automake-1.10.1-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-devel/automake/automake-1.10.1-r1.ebuild?rev=1.1&content-type=text/plain

Index: automake-1.10.1-r1.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-devel/automake/automake-1.10.1-r1.ebuild,v 1.1 2008/05/01 21:33:27 ulm Exp $

inherit eutils

DESCRIPTION="Used to generate Makefile.in from Makefile.am"
HOMEPAGE="http://sources.redhat.com/automake/"
SRC_URI="mirror://gnu/${PN}/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="${PV:0:4}"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~sparc-fbsd ~x86 ~x86-fbsd"
IUSE=""

RDEPEND="dev-lang/perl
	>=sys-devel/automake-wrapper-2
	>=sys-devel/autoconf-2.60
	>=sys-apps/texinfo-4.7
	sys-devel/gnuconfig"
DEPEND="${RDEPEND}
	sys-apps/help2man"

src_unpack() {
	unpack ${A}
	cd "${S}"
	epatch "${FILESDIR}"/${P}-tests.patch #217513
	chmod a+rx tests/*.test
	sed -i \
		-e "s|: (automake)| v${SLOT}: (automake${SLOT})|" \
		doc/automake.texi || die "sed failed"
	mv doc/automake{,${SLOT}}.texi
	sed -i \
		-e "s:automake.info:automake${SLOT}.info:" \
		-e "s:automake.texi:automake${SLOT}.texi:" \
		doc/Makefile.in || die "sed on Makefile.in failed"
	export WANT_AUTOCONF=2.5
}

src_compile() {
	econf --docdir=/usr/share/doc/${PF} || die
	emake || die
}

src_install() {
	emake DESTDIR="${D}" install || die
	dodoc NEWS README THANKS TODO AUTHORS ChangeLog

	# SLOT the docs and junk
	local x
	for x in aclocal automake ; do
		help2man ./${x} > ${x}-${SLOT}.1
		doman ${x}-${SLOT}.1
		rm -f "${D}"/usr/bin/${x}
	done

	# remove all config.guess and config.sub files replacing them
	# w/a symlink to a specific gnuconfig version
	for x in guess sub ; do
		dosym ../gnuconfig/config.${x} /usr/share/${PN}-${SLOT}/config.${x}
	done
}



-- 
gentoo-commits@l.g.o mailing list