[gentoo-commits] gentoo-x86 commit in x11-libs/cairo: ChangeLog cairo-1.5.4.ebuild cairo-1.5.2.ebuild

[Doug Klima (cardoe)]

cardoe      07/12/05 18:33:21

  Modified:             ChangeLog
  Added:                cairo-1.5.4.ebuild
  Removed:              cairo-1.5.2.ebuild
  Log:
  new development snapshot
  (Portage version: 2.1.4_rc7)

Revision  Changes    Path
1.154                x11-libs/cairo/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-libs/cairo/ChangeLog?rev=1.154&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-libs/cairo/ChangeLog?rev=1.154&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-libs/cairo/ChangeLog?r1=1.153&r2=1.154

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-libs/cairo/ChangeLog,v
retrieving revision 1.153
retrieving revision 1.154
diff -u -r1.153 -r1.154
--- ChangeLog	4 Dec 2007 12:28:43 -0000	1.153
+++ ChangeLog	5 Dec 2007 18:33:21 -0000	1.154
@@ -1,6 +1,12 @@
 # ChangeLog for x11-libs/cairo
 # Copyright 2000-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-libs/cairo/ChangeLog,v 1.153 2007/12/04 12:28:43 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-libs/cairo/ChangeLog,v 1.154 2007/12/05 18:33:21 cardoe Exp $
+
+*cairo-1.5.4 (05 Dec 2007)
+
+  05 Dec 2007; Doug Klima <cardoe@g.o> -cairo-1.5.2.ebuild,
+  +cairo-1.5.4.ebuild:
+  new development snapshot
 
   04 Dec 2007; Raúl Porcel <armin76@g.o> cairo-1.4.12.ebuild:
   alpha/ia64/sparc stable wrt #200350



1.1                  x11-libs/cairo/cairo-1.5.4.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-libs/cairo/cairo-1.5.4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-libs/cairo/cairo-1.5.4.ebuild?rev=1.1&content-type=text/plain

Index: cairo-1.5.4.ebuild
===================================================================
# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-libs/cairo/cairo-1.5.4.ebuild,v 1.1 2007/12/05 18:33:21 cardoe Exp $

inherit eutils flag-o-matic libtool

DESCRIPTION="A vector graphics library with cross-device output support"
HOMEPAGE="http://cairographics.org/"
SRC_URI="http://cairographics.org/snapshots/${P}.tar.gz"

LICENSE="|| ( LGPL-2.1 MPL-1.1 )"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd"
IUSE="debug directfb doc glitz opengl svg X xcb test"

RDEPEND="media-libs/fontconfig
		>=media-libs/freetype-2.1.4
		sys-libs/zlib
		media-libs/libpng
		>=x11-libs/pixman-0.9.4
		X?	(
				x11-libs/libXrender
				x11-libs/libXext
				x11-libs/libX11
				virtual/xft
				xcb? ( x11-libs/libxcb
						x11-libs/xcb-util )
			)
		directfb? ( >=dev-libs/DirectFB-0.9.24 )
		glitz? ( >=media-libs/glitz-0.5.1 )
		svg? ( dev-libs/libxml2 )"

DEPEND="${RDEPEND}
		>=dev-util/pkgconfig-0.19
		sys-apps/findutils
		test? (
				virtual/ghostscript
				>=app-text/poppler-bindings-0.4.1
				x11-libs/pango
				x11-libs/gtk+
				svg? ( >=gnome-base/librsvg-2.15.0 )
			)
		X? ( x11-proto/renderproto
			xcb? ( x11-proto/xcb-proto ) )
		doc?	(
					>=dev-util/gtk-doc-1.6
					 ~app-text/docbook-xml-dtd-4.2
				)"

src_unpack() {
	unpack ${A}
	cd "${S}"

	# We need to run elibtoolize to ensure correct so versioning on FreeBSD
	elibtoolize
}

src_compile() {
	#gets rid of fbmmx.c inlining warnings
	append-flags -finline-limit=1200

	if use glitz && use opengl; then
		export glitz_LIBS=-lglitz-glx
	fi

	econf $(use_enable X xlib) $(use_enable doc gtk-doc) $(use_enable directfb) \
		  $(use_enable svg) $(use_enable glitz) $(use_enable X xlib-xrender) \
		  $(use_enable debug test-surfaces) --enable-pdf  --enable-png \
		  --enable-freetype --enable-ps $(use_enable xcb) \
		  || die "configure failed"

	emake || die "compile failed"
}

src_install() {
	make DESTDIR="${D}" install || die "Installation failed"
	dodoc AUTHORS ChangeLog NEWS README TODO
}



-- 
gentoo-commits@g.o mailing list