[gentoo-commits] repo/gentoo:master commit in: dev-python/pycdio/

[Michał Górny]

commit:     3f64e11797d30cd54100ffeca585b09b549c328f
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sat Dec 31 15:49:58 2022 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sat Dec 31 15:54:51 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=3f64e117

dev-python/pycdio: PEP517, pytest

Closes: https://bugs.gentoo.org/888255
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/pycdio/pycdio-2.1.1-r1.ebuild | 55 ++++++++++++++++++++++++++++++++
 1 file changed, 55 insertions(+)

diff --git a/dev-python/pycdio/pycdio-2.1.1-r1.ebuild b/dev-python/pycdio/pycdio-2.1.1-r1.ebuild
new file mode 100644
index 000000000000..94f8d9a685c4
--- /dev/null
+++ b/dev-python/pycdio/pycdio-2.1.1-r1.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..11} )
+
+inherit distutils-r1
+
+DESCRIPTION="Python OO interface to libcdio (CD Input and Control library)"
+HOMEPAGE="
+	https://savannah.gnu.org/projects/libcdio/
+	https://pypi.org/project/pycdio/
+"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="examples"
+
+DEPEND="
+	>=dev-libs/libcdio-2.0.0
+"
+RDEPEND="
+	${DEPEND}
+"
+BDEPEND="
+	dev-lang/swig
+"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# Remove obsolete sys.path and adjust 'data' paths in examples.
+	sed -i \
+		-e "s:^sys.path.insert.*::" \
+		-e "s:\.\./data:./data:g" \
+		example/*.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	epytest -opython_files='test-*.py'
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	if use examples; then
+		docinto examples
+		dodoc -r example/.
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+}