[gentoo-commits] repo/gentoo:master commit in: media-gfx/simple-scan/

[Matt Turner]

commit:     53eca982c1d2a3866593ed5a174ca48ec2f4d6e3
Author:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Fri Mar 25 21:54:15 2022 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Fri Mar 25 21:54:15 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=53eca982

media-gfx/simple-scan: Version bump to 42.0

Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 media-gfx/simple-scan/Manifest                |  1 +
 media-gfx/simple-scan/simple-scan-42.0.ebuild | 75 +++++++++++++++++++++++++++
 2 files changed, 76 insertions(+)

diff --git a/media-gfx/simple-scan/Manifest b/media-gfx/simple-scan/Manifest
index 9c22da42fd1f..324d8274f3f3 100644
--- a/media-gfx/simple-scan/Manifest
+++ b/media-gfx/simple-scan/Manifest
@@ -1 +1,2 @@
 DIST simple-scan-40.7.tar.xz 1480288 BLAKE2B 8068105db77196157495cbb2eb4c3e6a82531ed4bb727c05884154a661a9669426047c6cbbcffdd696c8e4d27721f2ca6249be14b6b4cc62be96bdbfe1b67a4c SHA512 36dc321e83bdf02fb9267d299abeee7f56bb6ee786e09811ba1244a2cee2c3baa0c5bbf3a4d6a6eadfc093d0e792b3511855c7e32caa2f6864face620fa4e7f6
+DIST simple-scan-42.0.tar.xz 1097464 BLAKE2B e2ca253d6fcff9a320312bbf32e50242b64c22a1f89cf99aa705214c5a393f1e76fb14693f508d0bc7231b97d47a5b7fa3fe767527206615df361c9edf5315c6 SHA512 0ccbe82a85fa802f53899df6109be93d58adc5028e6d904da7fc91e25cfd225fff757a7b65380abd7d3e7dfd35feab586bcf5b7504cc46d42822d3b2179bdec0

diff --git a/media-gfx/simple-scan/simple-scan-42.0.ebuild b/media-gfx/simple-scan/simple-scan-42.0.ebuild
new file mode 100644
index 000000000000..0b16fcd3aa71
--- /dev/null
+++ b/media-gfx/simple-scan/simple-scan-42.0.ebuild
@@ -0,0 +1,75 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{8..10} )
+VALA_MIN_API_VERSION="0.34"
+inherit gnome.org gnome2-utils meson python-any-r1 vala xdg
+
+DESCRIPTION="Simple document scanning utility"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/simple-scan"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
+IUSE="colord webp"
+
+DEPEND="
+	>=dev-libs/glib-2.38:2
+	>=x11-libs/gtk+-3.24:3
+	>=gui-libs/libhandy-1.5.0:1=
+	>=sys-libs/zlib-1.2.3.1:=
+	x11-libs/cairo:=
+	x11-libs/gdk-pixbuf:2
+	>=dev-libs/libgusb-0.2.7
+	colord? ( >=x11-misc/colord-0.1.24:=[udev(+)] )
+	webp? ( media-libs/libwebp )
+	>=media-gfx/sane-backends-1.0.20:=
+
+	virtual/jpeg:0=
+"
+# packagekit? ( >=app-admin/packagekit-base-1.1.5 )
+RDEPEND="${DEPEND}
+	x11-misc/xdg-utils
+"
+BDEPEND="
+	${PYTHON_DEPS}
+	$(vala_depend)
+	dev-libs/libxml2:2
+	dev-util/itstool
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	gui-libs/libhandy:1[vala]
+	dev-libs/libgusb[vala]
+	colord? ( x11-misc/colord[vala] )
+"
+
+PATCHES=(
+	# Add control for optional dependencies
+	"${FILESDIR}"/40.0-add-control-optional-deps.patch
+)
+
+src_prepare() {
+	default
+	vala_setup
+	xdg_environment_reset
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use colord)
+		-Dpackagekit=false
+		$(meson_use webp)
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}