[gentoo-commits] gentoo-x86 commit in app-emulation/virtualbox: virtualbox-9999.ebuild ChangeLog virtualbox-1.5.4.ebuild

[Markus Ullmann (jokey)]

jokey       08/01/05 17:51:48

  Modified:             virtualbox-9999.ebuild ChangeLog
  Added:                virtualbox-1.5.4.ebuild
  Log:
  Version bump wrt bug #203893 thanks to x-drum
  (Portage version: 2.1.4_rc14)

Revision  Changes    Path
1.22                 app-emulation/virtualbox/virtualbox-9999.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-emulation/virtualbox/virtualbox-9999.ebuild?rev=1.22&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-emulation/virtualbox/virtualbox-9999.ebuild?rev=1.22&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-emulation/virtualbox/virtualbox-9999.ebuild?r1=1.21&r2=1.22

Index: virtualbox-9999.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-emulation/virtualbox/virtualbox-9999.ebuild,v
retrieving revision 1.21
retrieving revision 1.22
diff -u -r1.21 -r1.22
--- virtualbox-9999.ebuild	22 Oct 2007 22:19:38 -0000	1.21
+++ virtualbox-9999.ebuild	5 Jan 2008 17:51:47 -0000	1.22
@@ -1,8 +1,8 @@
-# Copyright 1999-2007 Gentoo Foundation
+# Copyright 1999-2008 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/virtualbox/virtualbox-9999.ebuild,v 1.21 2007/10/22 22:19:38 jokey Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/virtualbox/virtualbox-9999.ebuild,v 1.22 2008/01/05 17:51:47 jokey Exp $
 
-inherit eutils flag-o-matic linux-mod qt3 subversion toolchain-funcs
+inherit eutils fdo-mime flag-o-matic linux-mod qt3 subversion toolchain-funcs
 
 DESCRIPTION="Softwarefamily of powerful x86 virtualization"
 HOMEPAGE="http://www.virtualbox.org/"
@@ -11,7 +11,7 @@
 LICENSE="GPL-2"
 SLOT="0"
 KEYWORDS="~amd64 ~x86"
-IUSE="sdk"
+IUSE="pulseaudio sdk"
 
 RDEPEND="!app-emulation/virtualbox-bin
 	!app-emulation/virtualbox-additions
@@ -22,16 +22,18 @@
 	dev-libs/xerces-c
 	media-libs/libsdl
 	x11-libs/libXcursor
-	$(qt_min_version 3.3.5)
-	sys-apps/hal"
+	$(qt_min_version 3.3.5)"
 DEPEND="${RDEPEND}
 	sys-devel/bin86
 	sys-devel/dev86
 	sys-power/iasl
-	>=media-libs/alsa-lib-1.0.13"
+	>=media-libs/alsa-lib-1.0.13
+	pulseaudio? ( media-sound/pulseaudio )"
+# sys-apps/hal is required at runtime (bug #197541)
 RDEPEND="${RDEPEND}
 	sys-apps/usermode-utilities
-	net-misc/bridge-utils"
+	net-misc/bridge-utils
+	sys-apps/hal"
 
 BUILD_TARGETS="all"
 MODULE_NAMES="vboxdrv(misc:${S}/out/linux.${ARCH}/release/bin/src:${S}/out/linux.${ARCH}/release/bin/src)"
@@ -54,9 +56,14 @@
 }
 
 src_compile() {
-	cd "${S}"
 
-	./configure || die "configure failed"
+	local myconf
+	if ! use pulseaudio; then
+			myconf="${myconf} --disable-pulse"
+	fi
+
+	./configure \
+	${myconf} || die "configure failed"
 	source ./env.sh
 
 	# Force kBuild to respect C[XX]FLAGS and MAKEOPTS (bug #178529)
@@ -118,15 +125,13 @@
 	newins "${FILESDIR}/${PN}-interfaces" interfaces
 
 	# desktop entry
-	insinto /usr/share/pixmaps
-	newins "${S}"/src/VBox/Frontends/VirtualBox/images/ico32x01.png ${PN}.png
-	insinto /usr/share/applications
-	doins "${FILESDIR}"/${PN}.desktop
-	dosed -e "s/Version=/Version=${PV}/" /usr/share/applications/${PN}.desktop
+	newicon "${S}"/src/VBox/Frontends/VirtualBox/images/ico32x01.png ${PN}.png
+	domenu "${FILESDIR}"/${PN}.desktop
 }
 
 pkg_postinst() {
 	linux-mod_pkg_postinst
+	fdo-mime_desktop_database_update
 	elog "To launch VirtualBox just type: \"VirtualBox\""
 	elog "You must be in the vboxusers group to use VirtualBox."
 	elog ""
@@ -137,3 +142,7 @@
 	elog "additions available for the live ebuild"
 	elog ""
 }
+
+pkg_postrm() {
+	fdo-mime_desktop_database_update
+}



1.31                 app-emulation/virtualbox/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-emulation/virtualbox/ChangeLog?rev=1.31&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-emulation/virtualbox/ChangeLog?rev=1.31&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-emulation/virtualbox/ChangeLog?r1=1.30&r2=1.31

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-emulation/virtualbox/ChangeLog,v
retrieving revision 1.30
retrieving revision 1.31
diff -u -r1.30 -r1.31
--- ChangeLog	5 Dec 2007 22:52:44 -0000	1.30
+++ ChangeLog	5 Jan 2008 17:51:47 -0000	1.31
@@ -1,6 +1,25 @@
 # ChangeLog for app-emulation/virtualbox
-# Copyright 1999-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/virtualbox/ChangeLog,v 1.30 2007/12/05 22:52:44 jokey Exp $
+# Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/virtualbox/ChangeLog,v 1.31 2008/01/05 17:51:47 jokey Exp $
+
+*virtualbox-1.5.4 (05 Jan 2008)
+
+  05 Jan 2008; Markus Ullmann <jokey@g.o>
+  +files/virtualbox-1.5.4-remove-alsa.patch, +virtualbox-1.5.4.ebuild,
+  virtualbox-9999.ebuild:
+  Version bump wrt bug #203893 thanks to x-drum
+
+  03 Jan 2008; Alessio Cassibba (X-Drum) <swapon@×××××.com>
+  virtualbox-1.5.4.ebuild, virtualbox-9999.ebuild:
+  remove redundant cd statements
+
+  02 Jan 2008; Alessio Cassibba (X-Drum) <swapon@×××××.com>
+  -virtualbox-1.5.2.ebuild, -files/virtualbox-1.5.2-remove-alsa.patch,
+  -files/virtualbox-1.5.2-remove-splitted-stuff.patch,
+  +virtualbox-1.5.4.ebuild, +files/virtualbox-1.5.4-remove-alsa.patch,
+  virtualbox-9999.ebuild, files/virtualbox.desktop:
+  version bump; add pulseaudio use flag; fix remove alsa patch; drop unneeded
+  files; disable vboxdrv kernel module compilation
 
   05 Dec 2007; Markus Ullmann <jokey@g.o> files/virtualbox.desktop,
   virtualbox-1.5.2-r1.ebuild:



1.1                  app-emulation/virtualbox/virtualbox-1.5.4.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-emulation/virtualbox/virtualbox-1.5.4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-emulation/virtualbox/virtualbox-1.5.4.ebuild?rev=1.1&content-type=text/plain

Index: virtualbox-1.5.4.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-emulation/virtualbox/virtualbox-1.5.4.ebuild,v 1.1 2008/01/05 17:51:47 jokey Exp $

inherit eutils fdo-mime flag-o-matic qt3 toolchain-funcs

MY_P=VirtualBox-${PV}_OSE
DESCRIPTION="Softwarefamily of powerful x86 virtualization"
HOMEPAGE="http://www.virtualbox.org/"
SRC_URI="http://www.virtualbox.org/download/${PV}/${MY_P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="additions alsa pulseaudio sdk"

RDEPEND="!app-emulation/virtualbox-bin
	~app-emulation/virtualbox-modules-${PV}
	dev-libs/libIDL
	>=dev-libs/libxslt-1.1.19
	dev-libs/xalan-c
	dev-libs/xerces-c
	media-libs/libsdl
	x11-libs/libXcursor
	$(qt_min_version 3.3.5)"
DEPEND="${RDEPEND}
	sys-devel/bin86
	sys-devel/dev86
	sys-power/iasl
	alsa? ( >=media-libs/alsa-lib-1.0.13 )
	pulseaudio? ( media-sound/pulseaudio )"
# sys-apps/hal is required at runtime (bug #197541)
RDEPEND="${RDEPEND}
	additions? ( ~app-emulation/virtualbox-additions-${PV} )
	sys-apps/usermode-utilities
	net-misc/bridge-utils
	sys-apps/hal"

S=${WORKDIR}/${MY_P}

pkg_setup() {
	# The VBoxSDL frontend needs media-libs/libsdl compiled
	# with USE flag X enabled (bug #177335)
	if ! built_with_use media-libs/libsdl X; then
		eerror "media-libs/libsdl was compiled without the \"X\" USE flag enabled."
		eerror "Please re-emerge media-libs/libsdl with USE=\"X\"."
		die "media-libs/libsdl should be compiled with the \"X\" USE flag."
	fi
}

src_unpack() {
	unpack ${A}
	cd "${S}"

	# Don't build the Alsa audio driver and remove Alsa checks in configure
	# when Alsa is not selected (bug #167739)
	use alsa || epatch "${FILESDIR}/${P}-remove-alsa.patch"
}

src_compile() {

	local myconf
	# Don't build vboxdrv kernel module
	myconf="--disable-kmods"

	if ! use pulseaudio; then
			myconf="${myconf} --disable-pulse"
	fi

	./configure \
	${myconf} || die "configure failed"
	source ./env.sh

	# Force kBuild to respect C[XX]FLAGS and MAKEOPTS (bug #178529)
	# and strip all flags
	strip-flags

	MAKE="kmk" emake TOOL_GCC3_CC="$(tc-getCC)" TOOL_GCC3_CXX="$(tc-getCXX)" \
		TOOL_GCC3_AS="$(tc-getCC)" TOOL_GCC3_AR="$(tc-getAR)" \
		TOOL_GCC3_LD="$(tc-getCXX)" TOOL_GCC3_LD_SYSMOD="$(tc-getLD)" \
		TOOL_GCC3_CFLAGS="${CFLAGS}" TOOL_GCC3_CXXFLAGS="${CXXFLAGS}" \
		all || die "kmk failed"
}

src_install() {
	cd "${S}"/out/linux.${ARCH}/release/bin

	# create virtualbox configurations files
	insinto /etc/vbox
	newins "${FILESDIR}/${PN}-config" vbox.cfg
	newins "${FILESDIR}/${PN}-interfaces" interfaces

	insinto /opt/VirtualBox
	if use sdk; then
		doins -r sdk
		fowners root:vboxusers /opt/VirtualBox/sdk/bin/xpidl
		fperms 0750 /opt/VirtualBox/sdk/bin/xpidl
	fi

	rm -rf sdk src tst* testcase xpidl SUPInstall SUPUninstall VBox.png \
	VBoxBFE vditool VBoxSysInfo.sh

	doins -r *
	for each in VBox{Manage,SDL,SVC,XPCOMIPCD,Tunctl} VirtualBox ; do
		fowners root:vboxusers /opt/VirtualBox/${each}
		fperms 0750 /opt/VirtualBox/${each}
	done

	exeinto /opt/VirtualBox
	newexe "${FILESDIR}/${PN}-wrapper" "VBox.sh" || die
	fowners root:vboxusers /opt/VirtualBox/VBox.sh
	fperms 0750 /opt/VirtualBox/VBox.sh
	newexe "${S}"/src/VBox/Installer/linux/VBoxAddIF.sh "VBoxAddIF.sh" || die
	fowners root:vboxusers /opt/VirtualBox/VBoxAddIF.sh
	fperms 0750 /opt/VirtualBox/VBoxAddIF.sh

	dosym /opt/VirtualBox/VBox.sh /usr/bin/VirtualBox
	dosym /opt/VirtualBox/VBox.sh /usr/bin/VBoxManage
	dosym /opt/VirtualBox/VBox.sh /usr/bin/VBoxSDL
	dosym /opt/VirtualBox/VBoxTunctl /usr/bin/VBoxTunctl
	dosym /opt/VirtualBox/VBoxAddIF.sh /usr/bin/VBoxAddIF
	dosym /opt/VirtualBox/VBoxAddIF.sh /usr/bin/VBoxDeleteIF

	# desktop entry
	newicon "${S}"/src/VBox/Frontends/VirtualBox/images/ico32x01.png ${PN}.png
	domenu "${FILESDIR}"/${PN}.desktop
}

pkg_postinst() {
	fdo-mime_desktop_database_update
	elog ""
	elog "To launch VirtualBox just type: \"VirtualBox\""
	elog "You must be in the vboxusers group to use VirtualBox,"
	elog ""
	elog "The last user manual is available for download at:"
	elog "http://www.virtualbox.org/download/UserManual.pdf"
	elog ""
}

pkg_postrm() {
	fdo-mime_desktop_database_update
}



-- 
gentoo-commits@g.o mailing list