[gentoo-commits] gentoo-x86 commit in net-news/quiterss: quiterss-0.16.2.ebuild ChangeLog

[Maxim Koltsov (maksbotan)]

maksbotan    14/09/01 16:26:18

  Modified:             ChangeLog
  Added:                quiterss-0.16.2.ebuild
  Log:
  Bump to 0.16.2, thanks to Nikoli.
  
  (Portage version: 2.2.12/cvs/Linux x86_64, signed Manifest commit with key F8DBDADE)

Revision  Changes    Path
1.48                 net-news/quiterss/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-news/quiterss/ChangeLog?rev=1.48&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-news/quiterss/ChangeLog?rev=1.48&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-news/quiterss/ChangeLog?r1=1.47&r2=1.48

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-news/quiterss/ChangeLog,v
retrieving revision 1.47
retrieving revision 1.48
diff -u -r1.47 -r1.48
--- ChangeLog	14 Jul 2014 14:56:49 -0000	1.47
+++ ChangeLog	1 Sep 2014 16:26:18 -0000	1.48
@@ -1,6 +1,11 @@
 # ChangeLog for net-news/quiterss
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-news/quiterss/ChangeLog,v 1.47 2014/07/14 14:56:49 pinkbyte Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-news/quiterss/ChangeLog,v 1.48 2014/09/01 16:26:18 maksbotan Exp $
+
+*quiterss-0.16.2 (01 Sep 2014)
+
+  01 Sep 2014; Maxim Koltsov <maksbotan@g.o> +quiterss-0.16.2.ebuild:
+  Bump to 0.16.2, thanks to Nikoli.
 
   14 Jul 2014; Sergey Popov <pinkbyte@g.o> quiterss-0.15.4.ebuild:
   Stable on x86, wrt bug #514898



1.1                  net-news/quiterss/quiterss-0.16.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-news/quiterss/quiterss-0.16.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-news/quiterss/quiterss-0.16.2.ebuild?rev=1.1&content-type=text/plain

Index: quiterss-0.16.2.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-news/quiterss/quiterss-0.16.2.ebuild,v 1.1 2014/09/01 16:26:18 maksbotan Exp $

EAPI=5

PLOCALES="ar cs de el_GR es fa fi fr gl hu it ja ko lt nl pl pt_BR pt_PT ro_RO ru sk sr sv tg_TJ tr uk vi zh_CN zh_TW"
EHG_REPO_URI="https://code.google.com/p/quite-rss"
inherit qt4-r2 l10n fdo-mime gnome2-utils
[[ ${PV} == *9999* ]] && inherit mercurial

[[ ${PV} == *9999* ]] || \
MY_P="QuiteRSS-${PV}-src"

DESCRIPTION="A Qt4-based RSS/Atom feed reader"
HOMEPAGE="https://quiterss.org"
[[ ${PV} == *9999* ]] || \
SRC_URI="https://quiterss.org/files/${PV}/${MY_P}.tar.bz2"

LICENSE="GPL-3"
SLOT="0"
[[ ${PV} == *9999* ]] || \
KEYWORDS="~amd64 ~arm ~x86 ~amd64-linux ~x86-linux"
IUSE="debug phonon"

RDEPEND="
	dev-qt/qtcore:4
	dev-qt/qtgui:4
	dev-qt/qtsingleapplication[X]
	dev-qt/qtsql:4[sqlite]
	dev-qt/qtwebkit:4
	dev-db/sqlite:3
	phonon? ( || ( media-libs/phonon dev-qt/qtphonon:4 ) )
"
DEPEND="${RDEPEND}
	virtual/pkgconfig
"

[[ ${PV} == *9999* ]] || \
S="${WORKDIR}/${MY_P}"

DOCS=( AUTHORS HISTORY_EN HISTORY_RU README )

src_prepare() {
	my_rm_loc() {
		sed -i -e "s:lang/${PN}_${1}.ts::" lang/lang.pri || die
	}
	# dedicated english locale file is not installed at all
	rm "lang/${PN}_en.ts" || die

	l10n_find_plocales_changes "lang" "${PN}_" '.ts'
	l10n_for_each_disabled_locale_do my_rm_loc

	qt4-r2_src_prepare
}

src_configure() {
	eqmake4 PREFIX="${EPREFIX}/usr" \
		SYSTEMQTSA=1 \
		$(usex phonon '' 'DISABLE_PHONON=1')
}

pkg_preinst() {
	gnome2_icon_savelist
}

pkg_postinst() {
	fdo-mime_desktop_database_update
	gnome2_icon_cache_update
}

pkg_postrm() {
	fdo-mime_desktop_database_update
	gnome2_icon_cache_update
}