[gentoo-commits] repo/gentoo:master commit in: dev-python/datashape/

[Pacho Ramos]

commit:     09881367a674bf725f8365892c1214ccefac5f3d
Author:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
AuthorDate: Sun Jan 19 19:51:21 2020 +0000
Commit:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
CommitDate: Sun Jan 19 19:54:13 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=09881367

(cat_pn): No reverse dep needs py2 support

Package-Manager: Portage-2.3.84, Repoman-2.3.20
Signed-off-by: Pacho Ramos <pacho <AT> gentoo.org>

 dev-python/datashape/datashape-0.5.4-r1.ebuild | 50 ++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)

diff --git a/dev-python/datashape/datashape-0.5.4-r1.ebuild b/dev-python/datashape/datashape-0.5.4-r1.ebuild
new file mode 100644
index 00000000000..ba87920acb0
--- /dev/null
+++ b/dev-python/datashape/datashape-0.5.4-r1.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python3_6 )
+
+inherit distutils-r1
+
+DESCRIPTION="Language defining a data description protocol"
+HOMEPAGE="https://github.com/blaze/datashape"
+SRC_URI="https://github.com/blaze/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/numpy-1.7[${PYTHON_USEDEP}]
+	>=dev-python/multipledispatch-0.4.7[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+"
+DEPEND="
+	doc? ( ${RDEPEND} dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? ( ${RDEPEND}
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}]
+	)
+"
+
+python_prepare_all() {
+	# Prevent un-needed d'loading
+	sed -e "s/'sphinx.ext.intersphinx', //" -i docs/source/conf.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_test() {
+	py.test || die "Tests failed under ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/build/html/. )
+	distutils-r1_python_install_all
+}