[gentoo-commits] repo/gentoo:master commit in: sys-kernel/rt-sources/

[Alice Ferrazzi]

commit:     345fa7148202ae2bb01357d585265373b59bd677
Author:     Alice Ferrazzi <alicef <AT> gentoo <DOT> org>
AuthorDate: Fri Sep 17 12:57:07 2021 +0000
Commit:     Alice Ferrazzi <alicef <AT> gentoo <DOT> org>
CommitDate: Fri Sep 17 13:02:57 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=345fa714

sys-kernel/rt-sources: Bump revision of 4.4.277_p224 to EAPI=8

Package-Manager: Portage-3.0.19, Repoman-3.0.3
Signed-off-by: Alice Ferrazzi <alicef <AT> gentoo.org>

 sys-kernel/rt-sources/rt-sources-4.4.277_p224-r1 | 51 ++++++++++++++++++++++++
 1 file changed, 51 insertions(+)

diff --git a/sys-kernel/rt-sources/rt-sources-4.4.277_p224-r1 b/sys-kernel/rt-sources/rt-sources-4.4.277_p224-r1
new file mode 100644
index 00000000000..6b7a4acca86
--- /dev/null
+++ b/sys-kernel/rt-sources/rt-sources-4.4.277_p224-r1
@@ -0,0 +1,51 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="8"
+ETYPE="sources"
+KEYWORDS="~amd64 ~arm64"
+
+HOMEPAGE="https://wiki.linuxfoundation.org/realtime/start"
+
+CKV="$(ver_cut 1-3)"
+K_SECURITY_UNSUPPORTED="1"
+RT_PATCHSET="${PV/*_p}"
+
+inherit kernel-2
+detect_version
+
+K_BRANCH_ID="${KV_MAJOR}.${KV_MINOR}"
+RT_FILE="patch-${K_BRANCH_ID}.${KV_PATCH}-rt${RT_PATCHSET}.patch.xz"
+RT_URI="https://www.kernel.org/pub/linux/kernel/projects/rt/${K_BRANCH_ID}/${RT_FILE} \
+		https://www.kernel.org/pub/linux/kernel/projects/rt/${K_BRANCH_ID}/older/${RT_FILE}"
+
+DESCRIPTION="Full Linux ${K_BRANCH_ID} kernel sources with the CONFIG_PREEMPT_RT patch"
+SRC_URI="${KERNEL_URI} ${RT_URI}"
+
+KV_FULL="${PVR/_p/-rt}"
+S="${WORKDIR}/linux-${KV_FULL}"
+
+UNIPATCH_LIST="${DISTDIR}/${RT_FILE}"
+UNIPATCH_STRICTORDER="yes"
+
+src_prepare() {
+	default
+
+	# 627796
+	sed \
+		"s/default PREEMPT_NONE/default PREEMPT_RT_FULL/g" \
+		-i "${S}/kernel/Kconfig.preempt" || die "sed failed"
+}
+
+pkg_postinst() {
+	kernel-2_pkg_postinst
+	ewarn
+	ewarn "${PN} are *not* supported by the Gentoo Kernel Project in any way."
+	ewarn "If you need support, please contact the RT project developers directly."
+	ewarn "Do *not* open bugs in Gentoo's bugzilla unless you have issues with"
+	ewarn "the ebuilds."
+	ewarn
+}
+
+K_EXTRAEINFO="For more info on rt-sources and details on how to report problems, see: \
+${HOMEPAGE}."