[gentoo-commits] gentoo-x86 commit in sys-fs/mdadm: ChangeLog mdadm-2.6.3-r3.ebuild

[Doug Goldstein (cardoe)]

cardoe      07/10/04 14:27:24

  Modified:             ChangeLog
  Added:                mdadm-2.6.3-r3.ebuild
  Log:
  remove lvm from before check since this needs to be user configurable
  (Portage version: 2.1.3.11)

Revision  Changes    Path
1.83                 sys-fs/mdadm/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-fs/mdadm/ChangeLog?rev=1.83&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-fs/mdadm/ChangeLog?rev=1.83&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-fs/mdadm/ChangeLog?r1=1.82&r2=1.83

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-fs/mdadm/ChangeLog,v
retrieving revision 1.82
retrieving revision 1.83
diff -u -r1.82 -r1.83
--- ChangeLog	3 Oct 2007 11:58:45 -0000	1.82
+++ ChangeLog	4 Oct 2007 14:27:23 -0000	1.83
@@ -1,6 +1,12 @@
 # ChangeLog for sys-fs/mdadm
 # Copyright 1999-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-fs/mdadm/ChangeLog,v 1.82 2007/10/03 11:58:45 robbat2 Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-fs/mdadm/ChangeLog,v 1.83 2007/10/04 14:27:23 cardoe Exp $
+
+*mdadm-2.6.3-r3 (04 Oct 2007)
+
+  04 Oct 2007; Doug Goldstein <cardoe@g.o> +files/mdraid.rc-2.6.3-r3,
+  +mdadm-2.6.3-r3.ebuild:
+  remove lvm from before check since this needs to be user configurable
 
 *mdadm-2.6.3-r2 (03 Oct 2007)
 



1.1                  sys-fs/mdadm/mdadm-2.6.3-r3.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-fs/mdadm/mdadm-2.6.3-r3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-fs/mdadm/mdadm-2.6.3-r3.ebuild?rev=1.1&content-type=text/plain

Index: mdadm-2.6.3-r3.ebuild
===================================================================
# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-fs/mdadm/mdadm-2.6.3-r3.ebuild,v 1.1 2007/10/04 14:27:23 cardoe Exp $

inherit eutils flag-o-matic

DESCRIPTION="A useful tool for running RAID systems - it can be used as a replacement for the raidtools"
HOMEPAGE="http://cgi.cse.unsw.edu.au/~neilb/mdadm"
SRC_URI="mirror://kernel/linux/utils/raid/mdadm/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86"
IUSE="static"

src_unpack() {
	unpack ${A}
	cd "${S}"
	epatch "${FILESDIR}"/${PN}-1.9.0-dont-make-man.patch
	epatch "${FILESDIR}"/${PN}-2.6-syslog-updates.patch
	use static && append-ldflags -static
}

src_compile() {
	emake \
		CROSS_COMPILE=${CHOST}- \
		CWFLAGS="-Wall" \
		CXFLAGS="${CFLAGS}" \
		|| die "emake failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "make install failed"
	exeinto /$(get_libdir)/rcscripts/addons
	newexe "${FILESDIR}"/raid-start.sh-2.6.3-r2 raid-start.sh || die "addon failed"
	newexe "${FILESDIR}"/raid-stop.sh-2.6.3-r2 raid-stop.sh || die "addon failed"
	dodoc INSTALL TODO "ANNOUNCE-${PV}"

	insinto /etc
	newins mdadm.conf-example mdadm.conf
	newinitd "${FILESDIR}"/mdadm.rc mdadm || die "installing mdadm.rc failed"
	newconfd "${FILESDIR}"/mdadm.confd mdadm || die "installing mdadm.confd failed"
	newinitd "${FILESDIR}"/mdraid.rc-2.6.3-r3 mdraid || die "installing mdraid.rc failed"

	insinto /etc/udev/rules.d/
	newins "${FILESDIR}"/64-md-raid.rules-2.6.3-r2 64-md-raid.rules || die
}

pkg_postinst() {
	elog "If using baselayout-2 and not relying on kernel auto-detect"
	elog "of your RAID devices, you need to add 'mdraid' to your 'boot'"
	elog "runlevel. Run the following command:"
	elog "rc-update add mdraid boot"
}



-- 
gentoo-commits@g.o mailing list