[gentoo-commits] gentoo-x86 commit in app-portage/layman: ChangeLog layman-1.3.2-r1.ebuild layman-1.3.2.ebuild

[Sebastian Pipping (sping)]

sping       10/02/21 16:09:59

  Modified:             ChangeLog
  Added:                layman-1.3.2-r1.ebuild
  Removed:              layman-1.3.2.ebuild
  Log:
  app-portage/layman: Integrate fix for bug #306143
  (Portage version: 2.2_rc61/cvs/Linux i686)

Revision  Changes    Path
1.102                app-portage/layman/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-portage/layman/ChangeLog?rev=1.102&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-portage/layman/ChangeLog?rev=1.102&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-portage/layman/ChangeLog?r1=1.101&r2=1.102

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-portage/layman/ChangeLog,v
retrieving revision 1.101
retrieving revision 1.102
diff -u -r1.101 -r1.102
--- ChangeLog	20 Feb 2010 21:11:38 -0000	1.101
+++ ChangeLog	21 Feb 2010 16:09:59 -0000	1.102
@@ -1,6 +1,12 @@
 # ChangeLog for app-portage/layman
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-portage/layman/ChangeLog,v 1.101 2010/02/20 21:11:38 sping Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-portage/layman/ChangeLog,v 1.102 2010/02/21 16:09:59 sping Exp $
+
+*layman-1.3.2-r1 (21 Feb 2010)
+
+  21 Feb 2010; Sebastian Pipping <sping@g.o> -layman-1.3.2.ebuild,
+  +layman-1.3.2-r1.ebuild, +files/layman-1.3.2-missing-import.patch:
+  Integrate fix for bug #306143
 
 *layman-1.3.2 (20 Feb 2010)
 



1.1                  app-portage/layman/layman-1.3.2-r1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-portage/layman/layman-1.3.2-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-portage/layman/layman-1.3.2-r1.ebuild?rev=1.1&content-type=text/plain

Index: layman-1.3.2-r1.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-portage/layman/layman-1.3.2-r1.ebuild,v 1.1 2010/02/21 16:09:59 sping Exp $

EAPI="2"
NEED_PYTHON=2.5
SUPPORT_PYTHON_ABIS="1"

inherit eutils distutils

DESCRIPTION="A python script for retrieving gentoo overlays."
HOMEPAGE="http://layman.sourceforge.net"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE="bazaar cvs darcs git mercurial subversion test"

COMMON_DEPS="dev-lang/python[xml]"
DEPEND="${COMMON_DEPS}
	test? ( dev-util/subversion )"
RDEPEND="${COMMON_DEPS}
	bazaar? ( dev-util/bzr )
	cvs? ( dev-util/cvs )
	darcs? ( dev-util/darcs )
	git? ( dev-util/git )
	mercurial? ( dev-util/mercurial )
	subversion? (
		|| (
			>=dev-util/subversion-1.5.4[webdav-neon]
			>=dev-util/subversion-1.5.4[webdav-serf]
		)
	)"
RESTRICT_PYTHON_ABIS="2.4 3.*"

src_prepare() {
	epatch "${FILESDIR}"/${P}-missing-import.patch
}

pkg_setup() {
	if ! has_version dev-util/subversion; then
		ewarn "You do not have dev-util/subversion installed!"
		ewarn "While layman does not exactly depend on this"
		ewarn "version control system you should note that"
		ewarn "most available overlays are offered via"
		ewarn "dev-util/subversion. If you do not install it"
		ewarn "you will be unable to use these overlays."
		ewarn
	fi
}

src_test() {
	testing() {
		for suite in layman/tests/{dtest,external}.py ; do
			PYTHONPATH="." "$(PYTHON)" ${suite} \
					|| die "test suite '${suite}' failed"
		done
	}
	python_execute_function testing
}

src_install() {
	distutils_src_install

	dodir /etc/layman

	cp etc/* "${D}"/etc/layman/

	doman doc/layman.8
	dohtml doc/layman.8.html

	keepdir /var/lib/layman
}

pkg_postinst() {
	distutils_pkg_postinst

	einfo "You are now ready to add overlays into your system."
	einfo
	einfo "  layman -L"
	einfo
	einfo "will display a list of available overlays."
	einfo
	elog  "Select an overlay and add it using"
	elog
	elog  "  layman -a overlay-name"
	elog
	elog  "If this is the very first overlay you add with layman,"
	elog  "you need to append the following statement to your"
	elog  "/etc/make.conf file:"
	elog
	elog  "  source /var/lib/layman/make.conf"
	elog
	elog  "If you modify the 'storage' parameter in the layman"
	elog  "configuration file (/etc/layman/layman.cfg) you will"
	elog  "need to adapt the path given above to the new storage"
	elog  "directory."
	elog
	ewarn "Please add the 'source' statement to make.conf only AFTER "
	ewarn "you added your first overlay. Otherwise portage will fail."
	epause 5
}