[gentoo-commits] gentoo-x86 commit in app-editors/nano: ChangeLog nano-2.1.2.ebuild

[Mike Frysinger (vapier)]

vapier      08/06/27 16:43:59

  Modified:             ChangeLog
  Added:                nano-2.1.2.ebuild
  Log:
  Version bump.
  (Portage version: 2.2_rc1/cvs/Linux 2.6.25 x86_64)

Revision  Changes    Path
1.192                app-editors/nano/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-editors/nano/ChangeLog?rev=1.192&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-editors/nano/ChangeLog?rev=1.192&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-editors/nano/ChangeLog?r1=1.191&r2=1.192

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-editors/nano/ChangeLog,v
retrieving revision 1.191
retrieving revision 1.192
diff -u -r1.191 -r1.192
--- ChangeLog	16 Jun 2008 03:39:15 -0000	1.191
+++ ChangeLog	27 Jun 2008 16:43:58 -0000	1.192
@@ -1,6 +1,11 @@
 # ChangeLog for app-editors/nano
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-editors/nano/ChangeLog,v 1.191 2008/06/16 03:39:15 josejx Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-editors/nano/ChangeLog,v 1.192 2008/06/27 16:43:58 vapier Exp $
+
+*nano-2.1.2 (27 Jun 2008)
+
+  27 Jun 2008; Mike Frysinger <vapier@g.o> +nano-2.1.2.ebuild:
+  Version bump.
 
   16 Jun 2008; Joseph Jezak <josejx@g.o> nano-2.1.1-r1.ebuild:
   Marked ppc/ppc64 stable.



1.1                  app-editors/nano/nano-2.1.2.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-editors/nano/nano-2.1.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-editors/nano/nano-2.1.2.ebuild?rev=1.1&content-type=text/plain

Index: nano-2.1.2.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-editors/nano/nano-2.1.2.ebuild,v 1.1 2008/06/27 16:43:58 vapier Exp $

inherit eutils
if [[ ${PV} == "9999" ]] ; then
	ECVS_SERVER="savannah.gnu.org:/cvsroot/nano"
	ECVS_MODULE="nano"
	ECVS_AUTH="pserver"
	ECVS_USER="anonymous"
	inherit cvs
else
	MY_P=${PN}-${PV/_}
	SRC_URI="http://www.nano-editor.org/dist/v${PV:0:3}/${MY_P}.tar.gz"
fi

DESCRIPTION="GNU GPL'd Pico clone with more functionality"
HOMEPAGE="http://www.nano-editor.org/"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~sparc-fbsd ~x86 ~x86-fbsd"
IUSE="debug justify minimal ncurses nls slang spell unicode"

DEPEND=">=sys-libs/ncurses-5.2
	nls? ( sys-devel/gettext )
	!ncurses? ( slang? ( sys-libs/slang ) )"

src_unpack() {
	unpack ${A}
	cd "${S}"
	if [[ ! -e configure ]] ; then
		./autogen.sh || die "autogen failed"
	fi
}

src_compile() {
	local myconf=""
	use ncurses \
		&& myconf="--without-slang" \
		|| myconf="${myconf} $(use_with slang)"

	econf \
		--bindir=/bin \
		$(use_enable !minimal color) \
		$(use_enable !minimal multibuffer) \
		$(use_enable !minimal nanorc) \
		--disable-wrapping-as-root \
		$(use_enable spell speller) \
		$(use_enable justify) \
		$(use_enable debug) \
		$(use_enable nls) \
		$(use_enable unicode utf8) \
		$(use_enable minimal tiny) \
		${myconf} \
		|| die "configure failed"
	emake || die
}

src_install() {
	emake DESTDIR="${D}" install || die

	dodoc ChangeLog README doc/nanorc.sample AUTHORS BUGS NEWS TODO
	dohtml *.html
	insinto /etc
	newins doc/nanorc.sample nanorc

	dodir /usr/bin
	dosym /bin/nano /usr/bin/nano

	insinto /usr/share/nano
	local f
	for f in "${FILESDIR}"/*.nanorc ; do
		[[ -e ${D}/usr/share/nano/${f##*/} ]] && continue
		doins "${f}" || die
		echo "# include \"/usr/share/nano/${f##*/}\"" >> "${D}"/etc/nanorc
	done
}

pkg_postinst() {
	elog "More helpful info about nano, visit the GDP page:"
	elog "http://www.gentoo.org/doc/en/nano-basics-guide.xml"
}



-- 
gentoo-commits@l.g.o mailing list