[gentoo-commits] gentoo-x86 commit in net-libs/gnutls: gnutls-3.3.11.ebuild ChangeLog

[Alon Bar-Lev (alonbl)]

alonbl      14/12/30 11:05:18

  Modified:             ChangeLog
  Added:                gnutls-3.3.11.ebuild
  Log:
  Version bump, bug#533298
  
  (Portage version: 2.2.14/cvs/Linux x86_64, signed Manifest commit with key BF20DC51)

Revision  Changes    Path
1.522                net-libs/gnutls/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/gnutls/ChangeLog?rev=1.522&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/gnutls/ChangeLog?rev=1.522&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/gnutls/ChangeLog?r1=1.521&r2=1.522

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-libs/gnutls/ChangeLog,v
retrieving revision 1.521
retrieving revision 1.522
diff -u -r1.521 -r1.522
--- ChangeLog	15 Dec 2014 20:05:09 -0000	1.521
+++ ChangeLog	30 Dec 2014 11:05:17 -0000	1.522
@@ -1,6 +1,11 @@
 # ChangeLog for net-libs/gnutls
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-libs/gnutls/ChangeLog,v 1.521 2014/12/15 20:05:09 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-libs/gnutls/ChangeLog,v 1.522 2014/12/30 11:05:17 alonbl Exp $
+
+*gnutls-3.3.11 (30 Dec 2014)
+
+  30 Dec 2014; Alon Bar-Lev <alonbl@g.o> +gnutls-3.3.11.ebuild:
+  Version bump, bug#533298
 
   15 Dec 2014; Jeroen Roovers <jer@g.o> gnutls-3.3.10-r2.ebuild:
   Stable for HPPA (bug #492522).



1.1                  net-libs/gnutls/gnutls-3.3.11.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/gnutls/gnutls-3.3.11.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/gnutls/gnutls-3.3.11.ebuild?rev=1.1&content-type=text/plain

Index: gnutls-3.3.11.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-libs/gnutls/gnutls-3.3.11.ebuild,v 1.1 2014/12/30 11:05:17 alonbl Exp $

EAPI=5

inherit autotools libtool eutils multilib-minimal versionator

DESCRIPTION="A TLS 1.2 and SSL 3.0 implementation for the GNU project"
HOMEPAGE="http://www.gnutls.org/"
SRC_URI="mirror://gnupg/gnutls/v$(get_version_component_range 1-2)/${P}.tar.xz"

# LGPL-3 for libgnutls library and GPL-3 for libgnutls-extra library.
# soon to be relicensed as LGPL-2.1 unless heartbeat extension enabled.
LICENSE="GPL-3 LGPL-3"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~x86-interix ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x86-solaris"
IUSE_LINGUAS=" en cs de fi fr it ms nl pl sv uk vi zh_CN"
IUSE="+cxx +crywrap dane doc examples guile nls pkcs11 static-libs test zlib ${IUSE_LINGUAS// / linguas_}"
# heartbeat support is not disabled until re-licensing happens fullyf

# NOTICE: sys-devel/autogen is required at runtime as we
# use system libopts
RDEPEND=">=dev-libs/libtasn1-3.9[${MULTILIB_USEDEP}]
	>=dev-libs/nettle-2.7[gmp,${MULTILIB_USEDEP}]
	>=dev-libs/gmp-5.1.3-r1[${MULTILIB_USEDEP}]
	sys-devel/autogen
	crywrap? ( net-dns/libidn )
	dane? ( >=net-dns/unbound-1.4.20[${MULTILIB_USEDEP}] )
	guile? ( >=dev-scheme/guile-1.8[networking] )
	nls? ( >=virtual/libintl-0-r1[${MULTILIB_USEDEP}] )
	pkcs11? ( >=app-crypt/p11-kit-0.20.7[${MULTILIB_USEDEP}] )
	zlib? ( >=sys-libs/zlib-1.2.8-r1[${MULTILIB_USEDEP}] )
	abi_x86_32? (
		!<=app-emulation/emul-linux-x86-baselibs-20140508
		!app-emulation/emul-linux-x86-baselibs[-abi_x86_32(-)]
	)"
DEPEND="${RDEPEND}
	>=sys-devel/automake-1.11.6
	>=virtual/pkgconfig-0-r1[${MULTILIB_USEDEP}]
	doc? ( dev-util/gtk-doc )
	nls? ( sys-devel/gettext )
	test? ( app-misc/datefudge )"

DOCS=( AUTHORS ChangeLog NEWS README THANKS doc/TODO )

S="${WORKDIR}/${PN}-$(get_version_component_range 1-3)"

pkg_setup() {
	# bug#520818
	export TZ=UTC
}

src_prepare() {
	sed -i \
		-e 's/imagesdir = $(infodir)/imagesdir = $(htmldir)/' \
		doc/Makefile.am || die

	# force regeneration of autogen-ed files
	local file
	for file in $(grep -l AutoGen-ed src/*.c) ; do
		rm src/$(basename ${file} .c).{c,h} || die
	done

	# force regeneration of makeinfo files
	# have no idea why on some system these files are not
	# accepted as-is, see bug#520818
	for file in $(grep -l "produced by makeinfo" doc/*.info) ; do
		rm "${file}" || die
	done

	# support user patches
	epatch_user

	eautoreconf

	# Use sane .so versioning on FreeBSD.
	elibtoolize

	# bug 497472
	use cxx || epunt_cxx
}

multilib_src_configure() {
	LINGUAS="${LINGUAS//en/en@boldquot en@quot}"

	# TPM needs to be tested before being enabled
	# hardware-accell is disabled on OSX because the asm files force
	#   GNU-stack (as doesn't support that) and when that's removed ld
	#   complains about duplicate symbols
	ECONF_SOURCE=${S} \
	econf \
		--htmldir="${EPREFIX}/usr/share/doc/${PF}/html" \
		--disable-valgrind-tests \
		--without-included-libtasn1 \
		--enable-heartbeat-support \
		$(use_enable cxx) \
		$(use_enable dane libdane) \
		$(multilib_native_use_enable doc gtk-doc) \
		$(multilib_native_use_enable doc gtk-doc-pdf) \
		$(multilib_native_use_enable guile) \
		$(multilib_native_use_enable crywrap) \
		$(use_enable nls) \
		$(use_enable static-libs static) \
		$(use_with pkcs11 p11-kit) \
		$(use_with zlib) \
		--without-tpm \
		--with-unbound-root-key-file=/etc/dnssec/root-anchors.txt \
		$([[ ${CHOST} == *-darwin* ]] && echo --disable-hardware-acceleration)

	if multilib_is_native_abi; then
		ln -s "${S}"/doc/reference/html doc/reference/html || die
	fi
}

multilib_src_compile() {
	if multilib_is_native_abi; then
		default

		# symlink certtool for use in other ABIs
		if use test; then
			ln -s "${BUILD_DIR}"/src "${T}"/native-tools || die
		fi
	else
		emake -C gl
		emake -C lib
		emake -C extra
		use dane && emake -C libdane
	fi
}

multilib_src_test() {
	if multilib_is_native_abi; then
		# parallel testing often fails
		emake -j1 check
	else
		# use native ABI tools
		ln -s "${T}"/native-tools/{certtool,gnutls-{serv,cli}} \
			"${BUILD_DIR}"/src/ || die

		emake -C gl -j1 check
		emake -C tests -j1 check
	fi
}

multilib_src_install() {
	if multilib_is_native_abi; then
		emake DESTDIR="${D}" install
	else
		emake -C lib DESTDIR="${D}" install
		emake -C extra DESTDIR="${D}" install
		use dane && emake -C libdane DESTDIR="${D}" install
	fi
}

multilib_src_install_all() {
	einstalldocs
	prune_libtool_files --all

	dodoc doc/certtool.cfg

	if use doc; then
		dodoc doc/gnutls.pdf
		dohtml doc/gnutls.html
	else
		rm -fr "${ED}/usr/share/doc/${PF}/html"
	fi

	if use examples; then
		docinto examples
		dodoc doc/examples/*.c
	fi
}