[gentoo-commits] repo/gentoo:master commit in: games-puzzle/neverball/

[Ionen Wolkens]

commit:     87fee83623eb2ab6af08e3fff96681082a8c136f
Author:     Ionen Wolkens <ionen <AT> gentoo <DOT> org>
AuthorDate: Tue Jul 13 14:56:21 2021 +0000
Commit:     Ionen Wolkens <ionen <AT> gentoo <DOT> org>
CommitDate: Tue Jul 13 16:07:44 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=87fee836

games-puzzle/neverball: EAPI 6->7, fix prefix and AbsoluteSymlink

Signed-off-by: Ionen Wolkens <ionen <AT> gentoo.org>

 games-puzzle/neverball/neverball-1.6.0-r1.ebuild | 118 ++++++++++-------------
 1 file changed, 52 insertions(+), 66 deletions(-)

diff --git a/games-puzzle/neverball/neverball-1.6.0-r1.ebuild b/games-puzzle/neverball/neverball-1.6.0-r1.ebuild
index de40b601028..abb40a2d14c 100644
--- a/games-puzzle/neverball/neverball-1.6.0-r1.ebuild
+++ b/games-puzzle/neverball/neverball-1.6.0-r1.ebuild
@@ -1,8 +1,9 @@
-# Copyright 1999-2020 Gentoo Authors
+# Copyright 1999-2021 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=6
-inherit desktop gnome2-utils
+EAPI=7
+
+inherit desktop eapi8-dosym toolchain-funcs xdg
 
 DESCRIPTION="Clone of Super Monkey Ball using SDL/OpenGL"
 HOMEPAGE="https://neverball.org"
@@ -12,87 +13,72 @@ LICENSE="GPL-2+ IJG"
 SLOT="0"
 KEYWORDS="~amd64 ~x86"
 IUSE="nls"
-RESTRICT="test"
+RESTRICT="test" # not a test suite, only starts ./neverball
 
-RDEPEND="
-	media-libs/libsdl2[sound,joystick,opengl,video]
-	media-libs/sdl2-ttf
-	media-libs/libpng:0=
-	virtual/jpeg:0
+DEPEND="
+	dev-games/physfs
+	media-libs/libpng:=
+	media-libs/libsdl2[joystick,opengl,sound,video]
 	media-libs/libvorbis
+	media-libs/sdl2-ttf
+	virtual/jpeg
 	virtual/opengl
-	dev-games/physfs
+	nls? ( virtual/libintl )"
+RDEPEND="
+	${DEPEND}
 	media-fonts/dejavu
-	media-fonts/wqy-microhei
-	nls? ( virtual/libintl )
-"
-DEPEND="${RDEPEND}
-	sys-devel/gettext
-"
+	media-fonts/wqy-microhei"
+BDEPEND="nls? ( sys-devel/gettext )"
 
-PATCHES=("${FILESDIR}"/${P}-gcc-10.patch)
+PATCHES=(
+	"${FILESDIR}"/${P}-gcc-10.patch
+)
 
 src_prepare() {
 	default
-	sed -i \
-		-e 's:mapc:neverball-mapc:g' \
-		-e 's:MAPC:NEVERBALL-MAPC:g' \
-		-e '1 s/ 1 / 6 /' \
-		dist/mapc.1 || die
-	sed -i \
-		-e '/CFLAGS.*O2/s:-O2:$(E_CFLAGS):' \
-		-e '/CXXFLAGS.*O2/s:-O2:$(E_CXXFLAGS):' \
-		-e "/^MAPC_TARG/s/mapc/${PN}-mapc/" \
-		Makefile || die
+
+	# adjust man page for namespaced mapc executable (bug #50538)
+	sed -i "s/mapc/${PN}-mapc/;s/MAPC/${PN^^}-MAPC/;1s/1/6/" dist/mapc.1 || die
 }
 
 src_compile() {
-	emake \
-		ENABLE_NLS=$(use nls && echo 1 || echo 0) \
-		E_CFLAGS="${CFLAGS}" \
-		E_CXXFLAGS="${CXXFLAGS}" \
-		LOCALEDIR=/usr/share/locale \
-		DATADIR="/usr/share/${PN}"
+	tc-export CC CXX
+
+	local emakeargs=(
+		DATADIR="${EPREFIX}"/usr/share/${PN}
+		LOCALEDIR="${EPREFIX}"/usr/share/locale
+		ENABLE_NLS=$(usex nls 1 0)
+		CFLAGS="${CFLAGS}"
+		CPPFLAGS="${CPPFLAGS}"
+		CXXFLAGS="${CXXFLAGS}"
+	)
+	emake "${emakeargs[@]}"
 }
 
 src_install() {
-	local font
-
-	dobin ${PN}-mapc neverball neverputt
-	insinto "/usr/share/${PN}"
-	doins -r data/*
-	for font in DejaVuSans-Bold.ttf wqy-microhei.ttc; do
-		rm -f "${ED}/usr/share/${PN}"/ttf/${font}
-		dosym /usr/share/fonts/*/${font} \
-			"/usr/share/${PN}"/ttf/${font}
-	done
-	if [[ -d locale ]] ; then
-		insinto /usr/share
-		doins -r locale
-	fi
-	dodoc doc/{authors.txt,manual.txt,release-notes.md} README.md
+	dobin neverball neverputt
+	newbin mapc ${PN}-mapc
+
+	doman dist/{neverball,neverputt}.6
+	newman dist/mapc.1 neverball-mapc.6
 
-	local res name
+	insinto /usr/share/${PN}
+	doins -r data/.
+
+	# unbundle fonts
+	dosym8 -r /usr/share/{fonts/dejavu,${PN}/ttf}/DejaVuSans-Bold.ttf
+	dosym8 -r /usr/share/{fonts/wqy-microhei,${PN}/ttf}/wqy-microhei.ttc
+
+	insinto /usr/share
+	[[ -d locale ]] && doins -r locale
+
+	dodoc README.md doc/{authors.txt,manual.txt,release-notes.md}
+
+	local name res
 	for name in ball putt; do
 		for res in 16 32 64 128 256; do
 			newicon -s ${res} dist/never${name}_${res}.png never${name}.png
 		done
 	done
-
-	doman dist/*.6
-	newman dist/mapc.1 neverball-mapc.6
-	make_desktop_entry neverball Neverball
-	make_desktop_entry neverputt Neverputt neverputt
-}
-
-pkg_postinst() {
-	gnome2_icon_cache_update
-}
-
-pkg_preinst() {
-	gnome2_icon_savelist
-}
-
-pkg_postrm() {
-	gnome2_icon_cache_update
+	domenu dist/{neverball,neverputt}.desktop
 }