[gentoo-commits] gentoo-x86 commit in x11-wm/fluxbox: ChangeLog fluxbox-1.1.0.1.ebuild fluxbox-1.1.0-r1.ebuild

[Jim Ramsay (lack)]

lack        08/09/04 18:06:14

  Modified:             ChangeLog
  Added:                fluxbox-1.1.0.1.ebuild
  Removed:              fluxbox-1.1.0-r1.ebuild
  Log:
  New version - 1.1.0.1 is released (Fixes some issues with the 1.1.0 release)
  (Portage version: 2.2_rc8/cvs/Linux 2.6.26-gentoo-r1 x86_64)

Revision  Changes    Path
1.258                x11-wm/fluxbox/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-wm/fluxbox/ChangeLog?rev=1.258&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-wm/fluxbox/ChangeLog?rev=1.258&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-wm/fluxbox/ChangeLog?r1=1.257&r2=1.258

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-wm/fluxbox/ChangeLog,v
retrieving revision 1.257
retrieving revision 1.258
diff -u -r1.257 -r1.258
--- ChangeLog	3 Sep 2008 13:34:51 -0000	1.257
+++ ChangeLog	4 Sep 2008 18:06:14 -0000	1.258
@@ -1,6 +1,15 @@
 # ChangeLog for x11-wm/fluxbox
 # Copyright 2002-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-wm/fluxbox/ChangeLog,v 1.257 2008/09/03 13:34:51 lack Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-wm/fluxbox/ChangeLog,v 1.258 2008/09/04 18:06:14 lack Exp $
+
+*fluxbox-1.1.0.1 (04 Sep 2008)
+
+  04 Sep 2008; Jim Ramsay <lack@g.o>
+  +files/1.1.0.1/gentoo_style_location.patch,
+  -files/1.1.0/gentoo_style_location.patch, -files/1.1.0/windowmenu,
+  -fluxbox-1.1.0-r1.ebuild, +fluxbox-1.1.0.1.ebuild:
+  New version - 1.1.0.1 is released (Fixes some issues with the 1.1.0
+  release)
 
   03 Sep 2008; Jim Ramsay <lack@g.o> fluxbox-1.1.0-r1.ebuild:
   Added ewarn message about potential problem from last 1.1.0-r1 install



1.1                  x11-wm/fluxbox/fluxbox-1.1.0.1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-wm/fluxbox/fluxbox-1.1.0.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-wm/fluxbox/fluxbox-1.1.0.1.ebuild?rev=1.1&content-type=text/plain

Index: fluxbox-1.1.0.1.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-wm/fluxbox/fluxbox-1.1.0.1.ebuild,v 1.1 2008/09/04 18:06:14 lack Exp $

EAPI=1
inherit eutils

IUSE="nls xinerama truetype gnome +imlib +slit +toolbar vim-syntax"

DESCRIPTION="Fluxbox is an X11 window manager featuring tabs and an iconbar"

SRC_URI="mirror://sourceforge/fluxbox/${P}.tar.bz2"
HOMEPAGE="http://www.fluxbox.org"

# Please note that USE="gnome" simply adds support for some gnome protocols, and
# does not depend on external libraries.  However, it does make the binary a
# fair bit bigger, so we don't want to turn it on unless the user actually wants
# it.

RDEPEND="x11-libs/libXpm
	x11-libs/libXrandr
	xinerama? ( x11-libs/libXinerama )
	x11-apps/xmessage
	virtual/xft
	truetype? ( media-libs/freetype )
	imlib? ( >=media-libs/imlib2-1.2.0 )
	vim-syntax? ( app-vim/fluxbox-syntax )
	!<x11-themes/fluxbox-styles-fluxmod-20040809-r1
	!<=x11-misc/fluxconf-0.9.9
	!<=x11-misc/fbdesk-1.2.1"
DEPEND="nls? ( sys-devel/gettext )
	x11-proto/xextproto
	xinerama? ( x11-proto/xineramaproto )
	${RDEPEND}"
PROVIDE="virtual/blackbox"

SLOT="0"
LICENSE="MIT"
KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"

pkg_setup() {
	if use imlib && ! built_with_use media-libs/imlib2 X ; then
			eerror "To build fluxbox with imlib in USE, you need an X enabled"
			eerror "media-libs/imlib2 . Either recompile imlib2 with the X"
			eerror "USE flag turned on or disable the imlib USE flag for fluxbox."
			die "USE=imlib requires imlib2 with USE=X"
	fi
}

src_unpack() {
	unpack ${A}
	cd "${S}"

	# We need to be able to include directories rather than just plain
	# files in menu [include] items. This patch will allow us to do clever
	# things with style ebuilds.
	epatch "${FILESDIR}/${PV}/gentoo_style_location.patch"

	# Add in the Gentoo -r number to fluxbox -version output.
	if [[ "${PR}" == "r0" ]] ; then
		suffix="gentoo"
	else
		suffix="gentoo-${PR}"
	fi
	sed -i \
		-e "s~\(__fluxbox_version .@VERSION@\)~\1-${suffix}~" \
		version.h.in || die "version sed failed"
}

src_compile() {
	econf \
		$(use_enable nls) \
		$(use_enable xinerama) \
		$(use_enable truetype xft) \
		$(use_enable gnome) \
		$(use_enable imlib imlib2) \
		$(use_enable slit ) \
		$(use_enable toolbar ) \
		--sysconfdir=/etc/X11/${PN} \
		--with-style=/usr/share/fluxbox/styles/Emerge \
		${myconf} || die "configure failed"

	emake || die "make failed"

	ebegin "Creating a menu file (may take a while)"
	mkdir -p "${T}/home/.fluxbox" || die "mkdir home failed"
	MENUFILENAME="${S}/data/menu" MENUTITLE="Fluxbox ${PV}" \
		CHECKINIT="no. go away." HOME="${T}/home" \
		"${S}/util/fluxbox-generate_menu" -is -ds \
		|| die "menu generation failed"
	eend $?
}

src_install() {
	dodir /usr/share/fluxbox
	emake DESTDIR="${D}" STRIP="" install || die "install failed"
	dodoc README* AUTHORS TODO* ChangeLog NEWS

	dodir /usr/share/xsessions
	insinto /usr/share/xsessions
	doins "${FILESDIR}/${PN}.desktop"

	exeinto /etc/X11/Sessions
	newexe "${FILESDIR}/${PN}.xsession" fluxbox

	dodir /usr/share/fluxbox/menu.d

	# Styles menu framework
	dodir /usr/share/fluxbox/menu.d/styles
	insinto /usr/share/fluxbox/menu.d/styles
	doins "${FILESDIR}/styles-menu-fluxbox" || die
	doins "${FILESDIR}/styles-menu-commonbox" || die
	doins "${FILESDIR}/styles-menu-user" || die
}