[gentoo-commits] gentoo-x86 commit in sys-cluster/drbd: drbd-8.3.7.ebuild ChangeLog drbd-8.3.6.ebuild

[Alexys Jacob (ultrabug)]

ultrabug    11/04/29 10:12:47

  Modified:             ChangeLog
  Added:                drbd-8.3.7.ebuild
  Removed:              drbd-8.3.6.ebuild
  Log:
  Add a drbd-8.3.7 version to match sys-kernel/xen-sources-2.6.34 userland needs. Fix bug #365005. Drop old.
  
  (Portage version: 2.1.9.46/cvs/Linux x86_64)

Revision  Changes    Path
1.108                sys-cluster/drbd/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/drbd/ChangeLog?rev=1.108&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/drbd/ChangeLog?rev=1.108&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/drbd/ChangeLog?r1=1.107&r2=1.108

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-cluster/drbd/ChangeLog,v
retrieving revision 1.107
retrieving revision 1.108
diff -u -r1.107 -r1.108
--- ChangeLog	26 Mar 2011 08:43:16 -0000	1.107
+++ ChangeLog	29 Apr 2011 10:12:47 -0000	1.108
@@ -1,6 +1,13 @@
 # ChangeLog for sys-cluster/drbd
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-cluster/drbd/ChangeLog,v 1.107 2011/03/26 08:43:16 xarthisius Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-cluster/drbd/ChangeLog,v 1.108 2011/04/29 10:12:47 ultrabug Exp $
+
+*drbd-8.3.7 (29 Apr 2011)
+
+  29 Apr 2011; Ultrabug <ultrabug@g.o> -drbd-8.3.6.ebuild,
+  +drbd-8.3.7.ebuild:
+  Add a drbd-8.3.7 version to match sys-kernel/xen-sources-2.6.34 userland
+  needs. Fix bug #365005. Drop old. Thanks to Luca Lesinigo for reporting.
 
   26 Mar 2011; Kacper Kowalik <xarthisius@g.o> drbd-8.3.9.ebuild:
   Disable global survey by default in example conf file wrt #360483 by robbat2



1.1                  sys-cluster/drbd/drbd-8.3.7.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/drbd/drbd-8.3.7.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/drbd/drbd-8.3.7.ebuild?rev=1.1&content-type=text/plain

Index: drbd-8.3.7.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-cluster/drbd/drbd-8.3.7.ebuild,v 1.1 2011/04/29 10:12:47 ultrabug Exp $

EAPI="2"

inherit multilib versionator

LICENSE="GPL-2"

DESCRIPTION="mirror/replicate block-devices across a network-connection"
SRC_URI="http://oss.linbit.com/drbd/$(get_version_component_range 1-2 ${PV})/${P}.tar.gz"
HOMEPAGE="http://www.drbd.org"

KEYWORDS="~amd64 ~x86"
IUSE="bash-completion heartbeat pacemaker +udev xen"
SLOT="0"

src_prepare() {
	# respect LDFLAGS
	sed -i -e "s/\$(CC) -o/\$(CC) \$(LDFLAGS) -o/" user/Makefile.in || die
	# respect multilib
	sed -i -e "s:/lib/:/$(get_libdir)/:g" \
		scripts/{Makefile.in,global_common.conf,drbd.conf.example} || die
	# correct install paths
	sed -i -e "s:\$(sysconfdir)/bash_completion.d:/usr/share/bash-completion:" \
		scripts/Makefile.in || die
}

src_configure() {
	econf \
		--localstatedir=/var \
		--with-utils \
		--without-km \
		--without-rgmanager \
		$(use_with udev) \
		$(use_with xen) \
		$(use_with pacemaker) \
		$(use_with heartbeat) \
		$(use_with bash-completion bashcompletion) \
		--with-distro=gentoo
}

src_compile() {
	# only compile the tools
	emake OPTFLAGS="${CFLAGS}" tools || die
}

src_install() {
	# only install the tools
	emake DESTDIR="${D}" install-tools || die
	dodoc README ChangeLog || die

	# install our own init script
	newinitd "${FILESDIR}"/${PN}-8.0.rc ${PN} || die

	# it doesnt make sense to install a default conf in /etc,
	# so we put it to the docs
	rm -f "${D}"/etc/drbd.conf
	dodoc scripts/drbd.conf || die
}

pkg_postinst() {
	einfo
	einfo "Please copy and gunzip the configuration file"
	einfo "from /usr/share/doc/${PF}/drbd.conf.bz2 to /etc"
	einfo "and edit it to your needs. Helpful commands:"
	einfo "man 5 drbd.conf"
	einfo "man 8 drbdsetup"
	einfo "man 8 drbdadm"
	einfo "man 8 drbddisk"
	einfo "man 8 drbdmeta"
	einfo

	elog "Remember to enable drbd support in kernel."
	elog "Or alternatively emerge sys-cluster/drbd-kernel package."
}