[gentoo-commits] gentoo-x86 commit in sys-boot/os-prober: ChangeLog os-prober-1.39.ebuild

[Fabio Erculiani (lxnay)]

lxnay       10/07/26 11:00:51

  Modified:             ChangeLog
  Added:                os-prober-1.39.ebuild
  Log:
  Version bump
  (Portage version: 2.2_rc67/cvs/Linux x86_64)

Revision  Changes    Path
1.5                  sys-boot/os-prober/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-boot/os-prober/ChangeLog?rev=1.5&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-boot/os-prober/ChangeLog?rev=1.5&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-boot/os-prober/ChangeLog?r1=1.4&r2=1.5

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-boot/os-prober/ChangeLog,v
retrieving revision 1.4
retrieving revision 1.5
diff -u -r1.4 -r1.5
--- ChangeLog	4 Jun 2010 02:31:38 -0000	1.4
+++ ChangeLog	26 Jul 2010 11:00:51 -0000	1.5
@@ -1,6 +1,11 @@
 # ChangeLog for sys-boot/os-prober
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-boot/os-prober/ChangeLog,v 1.4 2010/06/04 02:31:38 beandog Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-boot/os-prober/ChangeLog,v 1.5 2010/07/26 11:00:51 lxnay Exp $
+
+*os-prober-1.39 (26 Jul 2010)
+
+  26 Jul 2010; Fabio Erculiani <lxnay@g.o> +os-prober-1.39.ebuild:
+  Version bump
 
 *os-prober-1.38 (04 Jun 2010)
 



1.1                  sys-boot/os-prober/os-prober-1.39.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-boot/os-prober/os-prober-1.39.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-boot/os-prober/os-prober-1.39.ebuild?rev=1.1&content-type=text/plain

Index: os-prober-1.39.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-boot/os-prober/os-prober-1.39.ebuild,v 1.1 2010/07/26 11:00:51 lxnay Exp $

EAPI="2"

inherit eutils multilib toolchain-funcs

DESCRIPTION="Utility to detect other OSs on a set of drives"
HOMEPAGE="http://packages.debian.org/source/sid/os-prober"
SRC_URI="mirror://debian/pool/main/${PN::1}/${PN}/${PN}_${PV}.tar.gz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""

S="${WORKDIR}/${PN}"

src_prepare() {
	sed -i -e "s:/lib/udev:/$(get_libdir)/udev:g" common.sh || die "sed failed on common.sh"
	find "${S}" -type f -exec sed -i -e "s:/usr/lib/:/usr/libexec/:g" {} + || die "failed on find and sed lib->libexec"
	sed -i -e "s:/lib/ld\*\.so\*:/lib*/ld*.so*:g" os-probes/mounted/common/90linux-distro  || die "sed failed on 90linux-distro"

	# Just use the default rules provided by GNU Make
	rm Makefile
}

src_compile() {
	tc-export CC
	emake newns || die "emake failed"
}

src_install() {
	dobin os-prober linux-boot-prober || die "dobin failed"

	exeinto /usr/libexec/os-prober
	doexe newns || die "doexe newns failed"

	insinto /usr/share/os-prober
	doins common.sh || die "doins common.sh failed"

	keepdir /var/lib/os-prober

	local debarch=${ARCH%-*} dir

	case ${debarch} in
		amd64)		debarch=x86 ;;
		ppc|ppc64)	debarch=powerpc ;;
	esac

	for dir in os-probes{,/mounted,/init} linux-boot-probes{,/mounted}; do
		exeinto /usr/libexec/$dir
		doexe $dir/common/* || die "doexe failed in $dir/common"
		if [[ -d $dir/$debarch ]]; then
			doexe $dir/$debarch/* || die "doexe failed in $dir/$debarch"
		fi
	done

	if use amd64 || use x86; then
		exeinto /usr/libexec/os-probes/mounted
		doexe os-probes/mounted/powerpc/20macosx || die "doexe failed on 20macosx"
	fi

	dodoc README TODO debian/changelog || die "dodoc failed"
}

pkg_postinst() {
	elog "If you intend for os-prober to detect versions of Windows installed on"
	elog "NTFS-formatted partitions, your system must be capable of reading the"
	elog "NTFS filesystem. One way to do this is by installing sys-fs/ntfs3g"
}