[gentoo-commits] repo/gentoo:master commit in: gnome-extra/evolution-ews/

[Matt Turner]

commit:     b294efe42d91cb997437e5e884f8bb00658a7d68
Author:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Sun Apr 18 03:46:37 2021 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Sun Apr 18 03:48:36 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=b294efe4

gnome-extra/evolution-ews: Version bump to 3.40.0

Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 gnome-extra/evolution-ews/Manifest                 |  1 +
 .../evolution-ews/evolution-ews-3.40.0.ebuild      | 68 ++++++++++++++++++++++
 2 files changed, 69 insertions(+)

diff --git a/gnome-extra/evolution-ews/Manifest b/gnome-extra/evolution-ews/Manifest
index e04155ba02f..eb5bdc4f583 100644
--- a/gnome-extra/evolution-ews/Manifest
+++ b/gnome-extra/evolution-ews/Manifest
@@ -1 +1,2 @@
 DIST evolution-ews-3.38.4.tar.xz 651384 BLAKE2B e4f71d38ddef6347ba3c137bac2246a6f4ffb5990ac2b6d3be72549326ae579c0a0f2bf11d19ce578ea37b99d0f8613d8d6a7e2ac75b9381e3b8c96646e483fc SHA512 98c1fecfa45bb2fe8337a1da54f09ef620128e4bba28b008aab3117291f7df708e6676421f3b8514448d035f1288591e54642f1426830fca7ba0320e3f3a99fc
+DIST evolution-ews-3.40.0.tar.xz 666148 BLAKE2B f8d7f6c917114e57bcc8ea93072f520069f7f183ce67ef5a5304c6721b3b9dae262ad5a2a8fc78b8ea75495f7f31f565b5db8e5bb02acaa5666ced15c0c3c5f2 SHA512 c5b0fdfbe455941444974738853a1c0346b77b96a483db8ff5b509a7c7dda90a0c1795749f3b17eeef4b3c2aceb06e51d2c5f9d784c0b6c17c78f8c37bc1c9af

diff --git a/gnome-extra/evolution-ews/evolution-ews-3.40.0.ebuild b/gnome-extra/evolution-ews/evolution-ews-3.40.0.ebuild
new file mode 100644
index 00000000000..2088827c202
--- /dev/null
+++ b/gnome-extra/evolution-ews/evolution-ews-3.40.0.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake gnome2
+
+DESCRIPTION="Evolution module for connecting to Microsoft Exchange Web Services"
+HOMEPAGE="https://wiki.gnome.org/Apps/Evolution"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+
+# libical-glib currently (2020-02-29) oddly behind USE=introspection
+RDEPEND="
+	dev-db/sqlite:3
+	>=dev-libs/glib-2.62:2
+	>=dev-libs/libical-3.0.5:0=[introspection(-)]
+	>=dev-libs/json-glib-1.0.4
+	>=dev-libs/libmspack-0.4
+	dev-libs/libxml2:2
+	>=gnome-extra/evolution-data-server-${PV}:0=
+	>=mail-client/evolution-${PV}:2.0
+	>=net-libs/libsoup-2.58:2.4
+	>=x11-libs/gtk+-3.10:3
+"
+DEPEND="${RDEPEND}
+	test? ( net-libs/uhttpmock )
+"
+BDEPEND="
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	>=dev-util/intltool-0.35.5
+	>=sys-devel/gettext-0.18.3
+	virtual/pkgconfig
+"
+
+# Unittests fail to find libevolution-ews.so
+RESTRICT="test !test? ( test )"
+
+# global scope PATCHES or DOCS array mustn't be used due to double default_src_prepare
+# call; if needed, set them after cmake_src_prepare call, if that works
+src_prepare() {
+	cmake_src_prepare
+	gnome2_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DWITH_MSPACK=ON
+		-DENABLE_TESTS=$(usex test)
+	)
+	cmake_src_configure
+}
+
+src_compile() {
+	cmake_src_compile
+}
+
+src_test() {
+	cmake_src_test
+}
+
+src_install() {
+	cmake_src_install
+}