[gentoo-commits] gentoo-x86 commit in media-video/griffith: griffith-0.12.ebuild ChangeLog

[Markos Chandras (hwoarang)]

hwoarang    10/10/10 01:49:42

  Modified:             ChangeLog
  Added:                griffith-0.12.ebuild
  Log:
  Version bump
  
  (Portage version: 2.2_rc91/cvs/Linux x86_64)

Revision  Changes    Path
1.49                 media-video/griffith/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/griffith/ChangeLog?rev=1.49&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/griffith/ChangeLog?rev=1.49&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/griffith/ChangeLog?r1=1.48&r2=1.49

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-video/griffith/ChangeLog,v
retrieving revision 1.48
retrieving revision 1.49
diff -u -r1.48 -r1.49
--- ChangeLog	21 Aug 2010 20:13:54 -0000	1.48
+++ ChangeLog	10 Oct 2010 01:49:42 -0000	1.49
@@ -1,6 +1,11 @@
 # ChangeLog for media-video/griffith
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/griffith/ChangeLog,v 1.48 2010/08/21 20:13:54 hwoarang Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-video/griffith/ChangeLog,v 1.49 2010/10/10 01:49:42 hwoarang Exp $
+
+*griffith-0.12 (10 Oct 2010)
+
+  10 Oct 2010; Markos Chandras <hwoarang@g.o> +griffith-0.12.ebuild:
+  Version bump
 
   21 Aug 2010; Markos Chandras <hwoarang@g.o>
   -files/0.9.6-moving_share_dir.patch, -files/0.9.7.1-fix_spellcheck.patch:



1.1                  media-video/griffith/griffith-0.12.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/griffith/griffith-0.12.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/griffith/griffith-0.12.ebuild?rev=1.1&content-type=text/plain

Index: griffith-0.12.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-video/griffith/griffith-0.12.ebuild,v 1.1 2010/10/10 01:49:41 hwoarang Exp $

EAPI="2"

PYTHON_DEPEND="2"

inherit eutils versionator python multilib

ARTWORK_PV="0.9.4"

DESCRIPTION="Movie collection manager"
HOMEPAGE="http://griffith.berlios.de/"
SRC_URI="http://launchpad.net/${PN}/trunk/${PV}/+download/${P}.tar.gz
	mirror://berlios/griffith/${PN}-extra-artwork-${ARTWORK_PV}.tar.gz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86 ~x86-fbsd"
IUSE="csv doc spell"

RDEPEND="dev-python/imaging
	gnome-base/libglade
	dev-python/pyxml
	>=dev-python/pygtk-2.6.1
	dev-python/pysqlite:2
	>=dev-python/sqlalchemy-0.5.2
	>=dev-python/reportlab-1.19
	csv? ( dev-python/chardet )
	spell? ( >=dev-python/gnome-python-extras-2.0 )"
DEPEND="${RDEPEND}
	doc? ( app-text/docbook2X )"

pkg_setup() {
	python_set_active_version 2
	python_pkg_setup
}

src_prepare() {
	sed -i \
		-e 's#/pl/#/pl.UTF-8/#' \
		"${S}"/docs/pl/Makefile || die "sed failed"

	sed -i \
		-e 's/ISO-8859-1/UTF-8/' \
		"${S}"/lib/gconsole.py || die "sed failed"
	epatch "${FILESDIR}/0.10-fix_lib_path.patch"
}

src_compile() {
	# Nothing to compile and default `emake` spews an error message
	true
}

src_install() {
	use doc || sed -i -e '/docs/d' Makefile

	emake \
		LIBDIR="${D}/usr/$(get_libdir)/griffith" \
		DESTDIR="${D}" DOC2MAN=docbook2man.pl install || die "emake install failed"
	dodoc AUTHORS ChangeLog README THANKS TODO NEWS TRANSLATORS

	cd "${WORKDIR}/${PN}-extra-artwork-${ARTWORK_PV}/"
	emake DESTDIR="${D}" install || die "emake install artwork failed"
}

pkg_postinst() {
	python_mod_optimize /usr/$(get_libdir)/${PN}
}

pkg_postrm() {
	python_mod_cleanup /usr/$(get_libdir)/${PN}
}