[gentoo-commits] repo/gentoo:master commit in: dev-python/pygments/

[Michał Górny]

commit:     5f365b06c8d8f3a27ef8540690ca2c1acbd6f7b9
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Wed May 11 17:17:00 2022 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Wed May 11 17:54:36 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=5f365b06

dev-python/pygments: Use PEP517 build

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/pygments/pygments-2.12.0-r1.ebuild | 45 +++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

diff --git a/dev-python/pygments/pygments-2.12.0-r1.ebuild b/dev-python/pygments/pygments-2.12.0-r1.ebuild
new file mode 100644
index 000000000000..a9ce01eaa3ee
--- /dev/null
+++ b/dev-python/pygments/pygments-2.12.0-r1.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} pypy3 )
+
+inherit distutils-r1 bash-completion-r1
+
+MY_P=${P^}
+DESCRIPTION="Pygments is a syntax highlighting package written in Python"
+HOMEPAGE="
+	https://pygments.org/
+	https://github.com/pygments/pygments/
+	https://pypi.org/project/Pygments/
+"
+SRC_URI="mirror://pypi/${MY_P:0:1}/${PN^}/${MY_P}.tar.gz"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+BDEPEND="
+	test? (
+		dev-python/lxml[${PYTHON_USEDEP}]
+		dev-python/pillow[${PYTHON_USEDEP}]
+		dev-python/wcag-contrast-ratio[${PYTHON_USEDEP}]
+		virtual/ttf-fonts
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-2.11.2-fix-docs-relative.patch"
+)
+
+distutils_enable_sphinx doc \
+	dev-python/wcag-contrast-ratio
+distutils_enable_tests pytest
+
+python_install_all() {
+	distutils-r1_python_install_all
+	newbashcomp external/pygments.bashcomp pygmentize
+}