[gentoo-commits] gentoo-x86 commit in games-strategy/galaxyhack: ChangeLog galaxyhack-1.74.ebuild

[Alfredo Tupone (tupone)]

tupone      07/11/10 00:47:18

  Modified:             ChangeLog
  Added:                galaxyhack-1.74.ebuild
  Log:
  Version bump to 1.74
  (Portage version: 2.1.3.16)

Revision  Changes    Path
1.5                  games-strategy/galaxyhack/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-strategy/galaxyhack/ChangeLog?rev=1.5&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-strategy/galaxyhack/ChangeLog?rev=1.5&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-strategy/galaxyhack/ChangeLog?r1=1.4&r2=1.5

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/games-strategy/galaxyhack/ChangeLog,v
retrieving revision 1.4
retrieving revision 1.5
diff -u -r1.4 -r1.5
--- ChangeLog	13 Jun 2007 23:30:54 -0000	1.4
+++ ChangeLog	10 Nov 2007 00:47:17 -0000	1.5
@@ -1,6 +1,13 @@
 # ChangeLog for games-strategy/galaxyhack
 # Copyright 1999-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-strategy/galaxyhack/ChangeLog,v 1.4 2007/06/13 23:30:54 nyhm Exp $
+# $Header: /var/cvsroot/gentoo-x86/games-strategy/galaxyhack/ChangeLog,v 1.5 2007/11/10 00:47:17 tupone Exp $
+
+*galaxyhack-1.74 (10 Nov 2007)
+
+  10 Nov 2007; Tupone Alfredo <tupone@g.o>
+  +files/galaxyhack-1.74-boost.patch, +files/galaxyhack-1.74-destdirs.patch,
+  +galaxyhack-1.74.ebuild:
+  Version bump
 
   13 Jun 2007; Tristan Heaven <nyhm@g.o>
   +files/galaxyhack-1.69-boost.patch, galaxyhack-1.69.ebuild:



1.1                  games-strategy/galaxyhack/galaxyhack-1.74.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-strategy/galaxyhack/galaxyhack-1.74.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-strategy/galaxyhack/galaxyhack-1.74.ebuild?rev=1.1&content-type=text/plain

Index: galaxyhack-1.74.ebuild
===================================================================
# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-strategy/galaxyhack/galaxyhack-1.74.ebuild,v 1.1 2007/11/10 00:47:17 tupone Exp $

inherit eutils games

DESCRIPTION="Multiplayer AI script based strategy game."
HOMEPAGE="http://galaxyhack.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2
	mirror://gentoo/${PN}.png"

LICENSE="GPL-2 galaxyhack"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""

DEPEND="media-libs/libsdl
	media-libs/sdl-image
	media-libs/sdl-mixer
	>=dev-libs/boost-1.34"

S=${WORKDIR}/${PN}/src

src_unpack() {
	unpack ${A}
	cd "${S}"
	edos2unix Makefile
	epatch \
		"${FILESDIR}"/${P}-destdirs.patch \
		"${FILESDIR}"/${P}-boost.patch
	sed -i "s:@GAMES_DATADIR@:${GAMES_DATADIR}:" \
		Main.cpp \
		|| die "sed Main.cpp failed"
	sed -i "/Base data path/s:pwd:${GAMES_DATADIR}/${PN}:" \
		../settings.dat \
		|| die "sed settings.dat failed"
	sed -i \
		-e "/^CXXFLAGS/s:-O3:${CXXFLAGS}:" \
		-e '/^LDFLAGS/s:=:+=:' \
		Makefile \
		|| die "sed Makefile failed"
}

src_install() {
	dogamesbin "${PN}" || die "dogamesbin failed"
	cd ..
	insinto "${GAMES_DATADIR}"/${PN}
	doins -r fleets gamedata graphics music standardpictures \
		settings.dat || die "doins failed"
	dodoc readme.txt
	doicon "${DISTDIR}"/${PN}.png
	make_desktop_entry ${PN} GalaxyHack
	prepgamesdirs
}

pkg_postinst() {
	games_pkg_postinst
	elog "Settings will default to those found in"
	elog "${GAMES_DATADIR}/galaxyhack/settings.dat"
	elog "Per user settings can be specified by creating"
	elog "~/.galaxyhack/settings.dat"
	elog "Additional user submitted fleets can be downloaded from"
	elog "http://galaxyhack.sourceforge.net/viewfleets.php"
}



-- 
gentoo-commits@g.o mailing list