[gentoo-commits] repo/gentoo:master commit in: media-libs/zvbi/

[Marek Szuba]

commit:     1124a8ddffa62062f9398114a619f312999c4f1b
Author:     Marek Szuba <marecki <AT> gentoo <DOT> org>
AuthorDate: Thu Nov 25 14:40:06 2021 +0000
Commit:     Marek Szuba <marecki <AT> gentoo <DOT> org>
CommitDate: Thu Nov 25 14:45:11 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=1124a8dd

media-libs/zvbi: update EAPI 5 -> 8

Signed-off-by: Marek Szuba <marecki <AT> gentoo.org>

 media-libs/zvbi/zvbi-0.2.35-r2.ebuild | 62 +++++++++++++++++++++++++++++++++++
 1 file changed, 62 insertions(+)

diff --git a/media-libs/zvbi/zvbi-0.2.35-r2.ebuild b/media-libs/zvbi/zvbi-0.2.35-r2.ebuild
new file mode 100644
index 000000000000..7e283497ec0b
--- /dev/null
+++ b/media-libs/zvbi/zvbi-0.2.35-r2.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit libtool multilib-minimal
+
+DESCRIPTION="VBI Decoding Library for Zapping"
+HOMEPAGE="http://zapping.sourceforge.net"
+SRC_URI="mirror://sourceforge/project/zapping/${PN}/${PV}/${P}.tar.bz2"
+
+LICENSE="GPL-2 LGPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+IUSE="doc dvb nls v4l X"
+
+RDEPEND=">=media-libs/libpng-1.5.18:0=[${MULTILIB_USEDEP}]
+	>=sys-libs/zlib-1.2.8-r1[${MULTILIB_USEDEP}]
+	nls? ( >=virtual/libintl-0-r1[${MULTILIB_USEDEP}] )
+	X? ( >=x11-libs/libX11-1.6.2[${MULTILIB_USEDEP}] )"
+DEPEND="${RDEPEND}
+	virtual/os-headers
+	X? ( x11-libs/libXt )"
+BDEPEND="doc? ( app-doc/doxygen )
+	nls? ( sys-devel/gettext )"
+
+PATCHES=(
+	"${FILESDIR}"/tests-gcc7.patch
+)
+
+src_prepare() {
+	default
+	elibtoolize
+}
+
+multilib_src_configure() {
+	ECONF_SOURCE="${S}" econf \
+		$(use_enable v4l) \
+		$(use_enable dvb) \
+		$(use_enable nls) \
+		$(use_with X x) \
+		$(multilib_native_use_with doc doxygen)
+}
+
+multilib_src_install() {
+	emake DESTDIR="${D}" install
+
+	if multilib_is_native_abi; then
+		if use doc; then
+			docinto html
+			dodoc doc/html/*.{png,gif,html,css}
+		fi
+	fi
+}
+
+multilib_src_install_all() {
+	# This may have been left pointing to "html"
+	docinto
+	dodoc AUTHORS BUGS ChangeLog NEWS README TODO
+
+	find "${ED}" -name '*.la' -delete
+}