[gentoo-commits] gentoo-x86 commit in dev-libs/opensc: ChangeLog opensc-0.11.13.ebuild opensc-0.11.13-r1.ebuild

[Diego Petteno (flameeyes)]

flameeyes    10/11/29 13:43:03

  Modified:             ChangeLog opensc-0.11.13.ebuild
  Added:                opensc-0.11.13-r1.ebuild
  Log:
  Fix build with recent pcsc-lite (backport from upstream); closes bug #341371; add dependency over libtool (needed for ltdl), and over readline (it was automagic before). In r1 instead add USE flag for readline, OpenSSL and zlib, and rebuild autotools with modern versions to fix bug #317295.
  
  (Portage version: 2.2.0_alpha6/cvs/Linux x86_64)

Revision  Changes    Path
1.102                dev-libs/opensc/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/opensc/ChangeLog?rev=1.102&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/opensc/ChangeLog?rev=1.102&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/opensc/ChangeLog?r1=1.101&r2=1.102

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/opensc/ChangeLog,v
retrieving revision 1.101
retrieving revision 1.102
diff -u -r1.101 -r1.102
--- ChangeLog	17 Oct 2010 18:02:28 -0000	1.101
+++ ChangeLog	29 Nov 2010 13:43:03 -0000	1.102
@@ -1,6 +1,15 @@
 # ChangeLog for dev-libs/opensc
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/opensc/ChangeLog,v 1.101 2010/10/17 18:02:28 arfrever Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/opensc/ChangeLog,v 1.102 2010/11/29 13:43:03 flameeyes Exp $
+
+*opensc-0.11.13-r1 (29 Nov 2010)
+
+  29 Nov 2010; Diego E. Pettenò <flameeyes@g.o> opensc-0.11.13.ebuild,
+  +opensc-0.11.13-r1.ebuild, +files/opensc-0.11.13+pcsc-lite-1.6.2.patch:
+  Fix build with recent pcsc-lite (backport from upstream); closes bug #341371;
+  add dependency over libtool (needed for ltdl), and over readline (it was
+  automagic before). In r1 instead add USE flag for readline, OpenSSL and zlib,
+  and rebuild autotools with modern versions to fix bug #317295.
 
   17 Oct 2010; Arfrever Frehtes Taifersar Arahesis <arfrever@g.o>
   opensc-0.11.13.ebuild:



1.8                  dev-libs/opensc/opensc-0.11.13.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/opensc/opensc-0.11.13.ebuild?rev=1.8&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/opensc/opensc-0.11.13.ebuild?rev=1.8&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/opensc/opensc-0.11.13.ebuild?r1=1.7&r2=1.8

Index: opensc-0.11.13.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/opensc/opensc-0.11.13.ebuild,v
retrieving revision 1.7
retrieving revision 1.8
diff -u -r1.7 -r1.8
--- opensc-0.11.13.ebuild	17 Oct 2010 18:02:28 -0000	1.7
+++ opensc-0.11.13.ebuild	29 Nov 2010 13:43:03 -0000	1.8
@@ -1,9 +1,11 @@
 # Copyright 1999-2010 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/opensc/opensc-0.11.13.ebuild,v 1.7 2010/10/17 18:02:28 arfrever Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/opensc/opensc-0.11.13.ebuild,v 1.8 2010/11/29 13:43:03 flameeyes Exp $
 
 EAPI="2"
 
+inherit eutils
+
 DESCRIPTION="SmartCard library and applications"
 HOMEPAGE="http://www.opensc-project.org/opensc/"
 
@@ -14,8 +16,11 @@
 SLOT="0"
 IUSE="doc openct pcsc-lite"
 
+# libtool is required at runtime for libltdl
 RDEPEND="dev-libs/openssl
 	sys-libs/zlib
+	sys-devel/libtool
+	sys-libs/readline
 	openct? ( >=dev-libs/openct-0.5.0 )
 	pcsc-lite? ( >=sys-apps/pcsc-lite-1.3.0 )"
 DEPEND="${RDEPEND}
@@ -28,6 +33,10 @@
 	fi
 }
 
+src_prepare() {
+	epatch "${FILESDIR}"/${P}+pcsc-lite-1.6.2.patch
+}
+
 src_configure() {
 	econf \
 		--docdir="/usr/share/doc/${PF}" \



1.1                  dev-libs/opensc/opensc-0.11.13-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/opensc/opensc-0.11.13-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/opensc/opensc-0.11.13-r1.ebuild?rev=1.1&content-type=text/plain

Index: opensc-0.11.13-r1.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/opensc/opensc-0.11.13-r1.ebuild,v 1.1 2010/11/29 13:43:03 flameeyes Exp $

EAPI="2"

inherit eutils autotools

DESCRIPTION="SmartCard library and applications"
HOMEPAGE="http://www.opensc-project.org/opensc/"

SRC_URI="http://www.opensc-project.org/files/${PN}/${P}.tar.gz"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"

LICENSE="LGPL-2.1"
SLOT="0"
IUSE="doc openct pcsc-lite readline ssl zlib"

# libtool is required at runtime for libltdl
RDEPEND="
	sys-devel/libtool
	zlib? ( sys-libs/zlib )
	readline? ( sys-libs/readline )
	ssl? ( dev-libs/openssl )
	openct? ( >=dev-libs/openct-0.5.0 )
	pcsc-lite? ( >=sys-apps/pcsc-lite-1.3.0 )"
DEPEND="${RDEPEND}
	dev-util/pkgconfig"

pkg_setup() {
	if use openct; then
		elog "Support for openct is deprecated."
		elog "It is recommended to use pcsc-lite."
	fi
}

src_prepare() {
	epatch "${FILESDIR}"/${P}+pcsc-lite-1.6.2.patch

	eautoreconf
}

src_configure() {
	econf \
		--docdir="/usr/share/doc/${PF}" \
		--htmldir="/usr/share/doc/${PF}/html" \
		$(use_enable doc) \
		$(use_enable openct) \
		$(use_enable pcsc-lite pcsc) \
		$(use_enable readline) \
		$(use_enable ssl openssl) \
		$(use_enable zlib) \
		--with-pinentry="/usr/bin/pinentry"
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"
}