[gentoo-commits] gentoo-x86 commit in app-portage/cfg-update: cfg-update-1.8.8.ebuild ChangeLog

[Richard Freeman (rich0)]

rich0       14/03/22 11:43:41

  Modified:             ChangeLog
  Added:                cfg-update-1.8.8.ebuild
  Log:
  New release - remove need to modify .bashrc
  
  (Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key 0x08C170DE55EC123A)

Revision  Changes    Path
1.36                 app-portage/cfg-update/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-portage/cfg-update/ChangeLog?rev=1.36&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-portage/cfg-update/ChangeLog?rev=1.36&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-portage/cfg-update/ChangeLog?r1=1.35&r2=1.36

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-portage/cfg-update/ChangeLog,v
retrieving revision 1.35
retrieving revision 1.36
diff -u -r1.35 -r1.36
--- ChangeLog	18 Mar 2012 15:13:25 -0000	1.35
+++ ChangeLog	22 Mar 2014 11:43:41 -0000	1.36
@@ -1,6 +1,11 @@
 # ChangeLog for app-portage/cfg-update
-# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-portage/cfg-update/ChangeLog,v 1.35 2012/03/18 15:13:25 armin76 Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/app-portage/cfg-update/ChangeLog,v 1.36 2014/03/22 11:43:41 rich0 Exp $
+
+*cfg-update-1.8.8 (22 Mar 2014)
+
+  22 Mar 2014; Richard Freeman <rich0@g.o> +cfg-update-1.8.8.ebuild:
+  New release - remove need to modify .bashrc
 
   18 Mar 2012; Raúl Porcel <armin76@g.o> cfg-update-1.8.2-r1.ebuild,
   cfg-update-1.8.7.ebuild:



1.1                  app-portage/cfg-update/cfg-update-1.8.8.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-portage/cfg-update/cfg-update-1.8.8.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-portage/cfg-update/cfg-update-1.8.8.ebuild?rev=1.1&content-type=text/plain

Index: cfg-update-1.8.8.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-portage/cfg-update/cfg-update-1.8.8.ebuild,v 1.1 2014/03/22 11:43:41 rich0 Exp $

EAPI=2
inherit eutils

DESCRIPTION="Easy to use GUI & CLI alternative for etc-update with safe automatic updating functionality"
HOMEPAGE="https://github.com/rich0/cfg-update"
SRC_URI="https://github.com/rich0/cfg-update/tarball/${PV} -> ${P}.tgz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~arm ~ppc ~x86"
IUSE="X"

RDEPEND="X? ( >=x11-misc/sux-1.0
	x11-apps/xhost )"

S="${WORKDIR}/rich0-cfg-update-b98fa99"

src_unpack() {
	unpack ${A}
	cd "${S}"
}

pkg_prerm() {
	if [[ ${ROOT} == / ]]
	then
		ebegin "Disabling portage hook"
		cfg-update --ebuild --disable-portage-hook
		eend $?
		ebegin "Disabling paludis hook"
		cfg-update --ebuild --disable-paludis-hook
		eend $?
	fi
}

pkg_postrm() {
	ewarn
	ewarn "If you want to permanently remove cfg-update from your system"
	ewarn "you should remove the index file /var/lib/cfg-update/checksum.index"
	ewarn
}

src_install() {
	exeinto /usr/bin
	doexe cfg-update emerge_with_indexing_for_cfg-update emerge_with_indexing_for_cfg-update_phphelper cfg-update_phphelper emerge_with_indexing_for_cfg-update_bashhelper
	insinto /usr/lib/cfg-update
	doins cfg-update cfg-update_indexing test.tgz
	dodoc ChangeLog
	doman *.8
	insinto /etc
	doins cfg-update.conf
	doins cfg-update.hosts
	keepdir /var/lib/cfg-update
}

pkg_postinst() {
	if [[ ! -e "${ROOT}"/var/lib/cfg-update/checksum.index \
		&& -e "${ROOT}"/var/lib/cfg-update/checksum.index ]]
	then
		ebegin "Moving checksum.index from /usr/lib/cfg-update to /var/lib/cfg-update"
		mv "${ROOT}"/usr/lib/cfg-update/checksum.index \
			"${ROOT}"/var/lib/cfg-update/checksum.index
		eend $?
	fi

	if [[ -e "${ROOT}"/usr/bin/paludis ]]
	then
		ewarn
		ewarn "If you have used Paludis version <0.20.0 on your system, chances are"
		ewarn "that you have some corrupted CONTENTS files on your system..."
		ewarn
		ewarn "Please run: cfg-update --check-packages"
		ewarn
		ewarn "The above command will check all packages installed with Paludis and"
		ewarn "will output a list of packages that need to be re-installed with"
		ewarn "Paludis 0.20.0 or higher. If you do not re-install these packages"
		ewarn "you risk losing your custom settings when updating configuration"
		ewarn "files, that belong to these packages, with cfg-update!"
		ewarn
	fi

	if [[ ${ROOT} == / ]]
	then
		ebegin "Moving backups to /var/lib/cfg-update/backups"
		/usr/bin/cfg-update --ebuild --move-backups
		eend $?
	fi

	einfo
	einfo "If this is a first time install, please check the configuration"
	einfo "in /etc/cfg-update.conf before using cfg-update:"
	einfo
	einfo "If your system does not have an X-server installed you need to"
	einfo "change the MERGE_TOOL to sdiff, imediff2 or vimdiff."
	einfo "If you have X installed, set MERGE_TOOL to your favorite GUI tool:"
	einfo "xxdiff, beediff, kdiff3, meld (default), gtkdiff, gvimdiff, tkdiff"
	einfo
	einfo "TIP: to maximize the chances of future automatic updates, run:"
	einfo "cfg-update --optimize-backups"
	einfo
}