[gentoo-commits] repo/gentoo:master commit in: dev-python/cheetah3/

[Alexys Jacob]

commit:     463f43f31b8622aeda1c2eb5b37639ef5bd6229d
Author:     Alexys Jacob <ultrabug <AT> gentoo <DOT> org>
AuthorDate: Sun Sep 22 13:32:42 2019 +0000
Commit:     Alexys Jacob <ultrabug <AT> gentoo <DOT> org>
CommitDate: Sun Sep 22 18:58:25 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=463f43f3

dev-python/cheetah3: new ebuild needed by >=mongodb-4.2

Package-Manager: Portage-2.3.75, Repoman-2.3.17
Signed-off-by: Alexys Jacob <ultrabug <AT> gentoo.org>

 dev-python/cheetah3/Manifest              |  1 +
 dev-python/cheetah3/cheetah3-3.2.3.ebuild | 44 +++++++++++++++++++++++++++++++
 dev-python/cheetah3/metadata.xml          | 15 +++++++++++
 3 files changed, 60 insertions(+)

diff --git a/dev-python/cheetah3/Manifest b/dev-python/cheetah3/Manifest
new file mode 100644
index 00000000000..7aca2361cfc
--- /dev/null
+++ b/dev-python/cheetah3/Manifest
@@ -0,0 +1 @@
+DIST Cheetah3-3.2.3.tar.gz 875441 BLAKE2B 0fa4a533bd66f98e982312a451f464a2c3fb645916b98aaa92d3af219cb49e252985b4c675a612c1c9265f8028577be4be78b551ad4cdbbaca7f4439624193b9 SHA512 ebc735b59d61912679405469f9d509fc73bbdde51c414320994421849f4a02266d2c286c0f618cab2a592ab47ac0a4be9ec444fab75145a0c31dd0c3c39fc1e3

diff --git a/dev-python/cheetah3/cheetah3-3.2.3.ebuild b/dev-python/cheetah3/cheetah3-3.2.3.ebuild
new file mode 100644
index 00000000000..57e7486829a
--- /dev/null
+++ b/dev-python/cheetah3/cheetah3-3.2.3.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+PYTHON_COMPAT=( python3_{5,6,7} )
+
+inherit distutils-r1
+
+MY_PN="Cheetah3"
+MY_P="${MY_PN}-${PV/_}"
+
+DESCRIPTION="Python-powered template engine and code generator"
+HOMEPAGE="http://www.cheetahtemplate.org/ https://pypi.org/project/Cheetah3/"
+SRC_URI="mirror://pypi/${MY_P:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="MIT"
+IUSE=""
+KEYWORDS="~amd64 ~x86"
+SLOT="0"
+
+RDEPEND="dev-python/markdown[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]"
+
+S="${WORKDIR}/${MY_P}"
+
+DOCS=( ANNOUNCE.rst README.rst TODO )
+# Race in the test suite
+DISTUTILS_IN_SOURCE_BUILD=1
+
+python_prepare_all() {
+	# Disable broken tests.
+	sed \
+		-e "/Unicode/d" \
+		-e "s/if not sys.platform.startswith('java'):/if False:/" \
+		-e "/results =/a\\    sys.exit(not results.wasSuccessful())" \
+		-i Cheetah/Tests/Test.py || die "sed failed"
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	"${PYTHON}" Cheetah/Tests/Test.py || die "Testing failed with ${EPYTHON}"
+}

diff --git a/dev-python/cheetah3/metadata.xml b/dev-python/cheetah3/metadata.xml
new file mode 100644
index 00000000000..52f8ccc1f81
--- /dev/null
+++ b/dev-python/cheetah3/metadata.xml
@@ -0,0 +1,15 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>python@g.o</email>
+		<name>Python</name>
+	</maintainer>
+	<longdescription>Cheetah is a Python-powered template engine and code generator. It can be used
+as a standalone utility or it can be combined with other tools. Web developers
+are its principle user group, but it has many potential uses and is also being
+used to generate C++ game code, Java, SQL, form emails, and even Python code.</longdescription>
+	<upstream>
+		<remote-id type="pypi">Cheetah3</remote-id>
+	</upstream>
+</pkgmetadata>