[gentoo-commits] repo/gentoo:master commit in: dev-java/commons-logging/

[Patrice Clement]

commit:     d865bf61655e46f7c83d864c6a8d5a49c0f49704
Author:     Patrice Clement <monsieurp <AT> gentoo <DOT> org>
AuthorDate: Fri Feb 16 10:11:35 2018 +0000
Commit:     Patrice Clement <monsieurp <AT> gentoo <DOT> org>
CommitDate: Fri Feb 16 10:27:47 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=d865bf61

dev-java/commons-logging: EAPI 6 bump.

Package-Manager: Portage-2.3.19, Repoman-2.3.6

 .../commons-logging/commons-logging-1.2-r2.ebuild  | 89 ++++++++++++++++++++++
 1 file changed, 89 insertions(+)

diff --git a/dev-java/commons-logging/commons-logging-1.2-r2.ebuild b/dev-java/commons-logging/commons-logging-1.2-r2.ebuild
new file mode 100644
index 00000000000..bb17056e251
--- /dev/null
+++ b/dev-java/commons-logging/commons-logging-1.2-r2.ebuild
@@ -0,0 +1,89 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+JAVA_PKG_IUSE="doc source"
+
+inherit java-pkg-2 java-ant-2 java-osgi
+
+DESCRIPTION="An ultra-thin bridge between different Java logging libraries"
+HOMEPAGE="https://commons.apache.org/logging/"
+SRC_URI="mirror://apache/commons/logging/source/${P}-src.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="avalon-framework avalon-logkit log4j servletapi test"
+RESTRICT="!servletapi? ( test )"
+
+CDEPEND="
+	log4j? ( dev-java/log4j:0 )
+	servletapi? ( java-virtuals/servlet-api:3.1 )
+	avalon-logkit? ( dev-java/avalon-logkit:2.0 )
+	avalon-framework? ( dev-java/avalon-framework:4.2 )"
+
+RDEPEND="
+	${CDEPEND}
+	>=virtual/jre-1.6"
+
+DEPEND="
+	${CDEPEND}
+	>=virtual/jdk-1.6
+	test? ( dev-java/ant-junit:0 )"
+
+S="${WORKDIR}/${P}-src"
+
+JAVA_ANT_IGNORE_SYSTEM_CLASSES="yes"
+JAVA_ANT_REWRITE_CLASSPATH="yes"
+EANT_BUILD_TARGET="compile"
+EANT_DOC_TARGET=""
+
+PATCH=(
+	# patch to make the build.xml respect no servletapi
+	"${FILESDIR}/${P}-servletapi.patch"
+	"${FILESDIR}/${P}-gentoo.patch"
+)
+
+DOCS=( RELEASE-NOTES.txt PROPOSAL.html )
+
+src_prepare() {
+	default
+
+	# bug #208098
+	echo "jdk.1.4.present=true" > build.properties || die
+
+	if use servletapi; then
+		echo "servletapi.jar=$(java-pkg_getjar --virtual servlet-api-3.1 servlet-api.jar)" >> build.properties || die
+	fi
+	if use avalon-framework; then
+		echo "avalon-framework.jar=$(java-pkg_getjars avalon-framework-4.2)" >> build.properties || die
+	fi
+	if use avalon-logkit; then
+		echo "logkit.jar=$(java-pkg_getjars avalon-logkit-2.0)" >> build.properties || die
+	fi
+	if use log4j; then
+		echo "log4j12.jar=$(java-pkg_getjars log4j)" >> build.properties || die
+	fi
+}
+
+src_compile() {
+	java-pkg-2_src_compile
+	if use doc; then
+		ejavadoc -d api -sourcepath src/main/java -subpackages org || die
+	fi
+}
+
+src_install() {
+	local pkg="org.apache.commons.logging"
+	java-osgi_newjar "target/${P}.jar" "${pkg}" "Apache Commons Logging" "${pkg};version=\"${PV}\", ${pkg}.impl;version=\"${PV}\""
+	java-pkg_newjar target/${PN}-api-${PV}.jar ${PN}-api.jar
+	java-pkg_newjar target/${PN}-adapters-${PV}.jar ${PN}-adapters.jar
+
+	use doc && java-pkg_dojavadoc api
+	use source && java-pkg_dosrc src/main/java/org
+}
+
+src_test() {
+	java-pkg-2_src_test
+}