[gentoo-commits] gentoo-x86 commit in media-plugins/alsa-plugins: alsa-plugins-1.0.27-r3.ebuild ChangeLog alsa-plugins-1.0.27-r2.ebuild

[Michal Gorny (mgorny)]

mgorny      14/05/21 12:03:50

  Modified:             ChangeLog
  Added:                alsa-plugins-1.0.27-r3.ebuild
  Removed:              alsa-plugins-1.0.27-r2.ebuild
  Log:
  ...and bump revision to make sure people do not end up with a broken systems.
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key EFB4464E!)

Revision  Changes    Path
1.195                media-plugins/alsa-plugins/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-plugins/alsa-plugins/ChangeLog?rev=1.195&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-plugins/alsa-plugins/ChangeLog?rev=1.195&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-plugins/alsa-plugins/ChangeLog?r1=1.194&r2=1.195

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-plugins/alsa-plugins/ChangeLog,v
retrieving revision 1.194
retrieving revision 1.195
diff -u -r1.194 -r1.195
--- ChangeLog	21 May 2014 12:01:53 -0000	1.194
+++ ChangeLog	21 May 2014 12:03:50 -0000	1.195
@@ -1,6 +1,12 @@
 # ChangeLog for media-plugins/alsa-plugins
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-plugins/alsa-plugins/ChangeLog,v 1.194 2014/05/21 12:01:53 mgorny Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-plugins/alsa-plugins/ChangeLog,v 1.195 2014/05/21 12:03:50 mgorny Exp $
+
+*alsa-plugins-1.0.27-r3 (21 May 2014)
+
+  21 May 2014; Michał Górny <mgorny@g.o> +alsa-plugins-1.0.27-r3.ebuild,
+  -alsa-plugins-1.0.27-r2.ebuild:
+  ...and bump revision to make sure people do not end up with a broken systems.
 
   21 May 2014; Michał Górny <mgorny@g.o> alsa-plugins-1.0.27-r2.ebuild:
   Fix multilib_src_install_all() phase name, bug #510928.



1.1                  media-plugins/alsa-plugins/alsa-plugins-1.0.27-r3.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-plugins/alsa-plugins/alsa-plugins-1.0.27-r3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-plugins/alsa-plugins/alsa-plugins-1.0.27-r3.ebuild?rev=1.1&content-type=text/plain

Index: alsa-plugins-1.0.27-r3.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-plugins/alsa-plugins/alsa-plugins-1.0.27-r3.ebuild,v 1.1 2014/05/21 12:03:50 mgorny Exp $

EAPI=5
inherit autotools eutils flag-o-matic multilib multilib-minimal

DESCRIPTION="ALSA extra plugins"
HOMEPAGE="http://www.alsa-project.org/"
SRC_URI="mirror://alsaproject/plugins/${P}.tar.bz2"

LICENSE="GPL-2 LGPL-2.1"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-linux"
IUSE="debug ffmpeg jack libsamplerate pulseaudio speex"

# TODO: handle USE=ffmpeg once it is converted

RDEPEND=">=media-libs/alsa-lib-${PV}:=[${MULTILIB_USEDEP}]
	ffmpeg? ( virtual/ffmpeg )
	jack? ( >=media-sound/jack-audio-connection-kit-0.98[${MULTILIB_USEDEP}] )
	libsamplerate? ( media-libs/libsamplerate:=[${MULTILIB_USEDEP}] )
	pulseaudio? ( media-sound/pulseaudio[${MULTILIB_USEDEP}] )
	speex? ( media-libs/speex:=[${MULTILIB_USEDEP}] )
	abi_x86_32? (
		!<app-emulation/emul-linux-x86-soundlibs-20140406-r1
		!app-emulation/emul-linux-x86-soundlibs[-abi_x86_32]
	)"
DEPEND="${RDEPEND}
	virtual/pkgconfig"

src_prepare() {
	epatch \
		"${FILESDIR}"/${PN}-1.0.19-missing-avutil.patch \
		"${FILESDIR}"/${PN}-1.0.23-automagic.patch \
		"${FILESDIR}"/${P}-{ffmpeg,ffmpeg-version-check}.patch

	epatch_user

	# For some reasons the polyp/pulse plugin does fail with alsaplayer with a
	# failed assert. As the code works just fine with asserts disabled, for now
	# disable them waiting for a better solution.
	sed -i \
		-e '/AM_CFLAGS/s:-Wall:-DNDEBUG -Wall:' \
		pulse/Makefile.am || die

	eautoreconf
}

multilib_src_configure() {
	use debug || append-cppflags -DNDEBUG

	local myspeex=no
	use speex && myspeex=lib

	ECONF_SOURCE=${S} \
	econf \
		$(multilib_native_use_enable ffmpeg avcodec) \
		$(use_enable jack) \
		$(use_enable libsamplerate samplerate) \
		$(use_enable pulseaudio) \
		--with-speex=${myspeex}
}

multilib_src_install_all() {
	einstalldocs

	cd doc || die
	dodoc upmix.txt vdownmix.txt README-pcm-oss
	use jack && dodoc README-jack
	use libsamplerate && dodoc samplerate.txt
	use ffmpeg && dodoc lavcrate.txt a52.txt

	if use pulseaudio; then
		dodoc README-pulse
		# install ALSA configuration files
		# making PA to be used by alsa clients
		insinto /usr/share/alsa
		doins "${FILESDIR}"/pulse-default.conf
		insinto /usr/share/alsa/alsa.conf.d
		doins "${FILESDIR}"/51-pulseaudio-probe.conf
		# bug #410261, comment 5+
		# seems to work fine without any path
		sed -i \
			-e "s:/usr/lib/alsa-lib/::" \
			"${ED}"/usr/share/alsa/alsa.conf.d/51-pulseaudio-probe.conf || die #410261
	fi

	prune_libtool_files --all
}

pkg_postinst() {
	if use pulseaudio; then
		einfo "The PulseAudio device is now set as the default device if the"
		einfo "PulseAudio server is found to be running. Any custom"
		einfo "configuration in /etc/asound.conf or ~/.asoundrc for this"
		einfo "purpose should now be unnecessary."
	fi
}