[gentoo-commits] gentoo-x86 commit in sys-apps/usb_modeswitch: usb_modeswitch-2.1.1_p20140327.ebuild ChangeLog

[Samuli Suominen (ssuominen)]

ssuominen    14/04/01 10:20:12

  Modified:             ChangeLog
  Added:                usb_modeswitch-2.1.1_p20140327.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key 4868F14D)

Revision  Changes    Path
1.55                 sys-apps/usb_modeswitch/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/usb_modeswitch/ChangeLog?rev=1.55&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/usb_modeswitch/ChangeLog?rev=1.55&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/usb_modeswitch/ChangeLog?r1=1.54&r2=1.55

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-apps/usb_modeswitch/ChangeLog,v
retrieving revision 1.54
retrieving revision 1.55
diff -u -r1.54 -r1.55
--- ChangeLog	6 Mar 2014 16:30:07 -0000	1.54
+++ ChangeLog	1 Apr 2014 10:20:12 -0000	1.55
@@ -1,6 +1,12 @@
 # ChangeLog for sys-apps/usb_modeswitch
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/usb_modeswitch/ChangeLog,v 1.54 2014/03/06 16:30:07 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/usb_modeswitch/ChangeLog,v 1.55 2014/04/01 10:20:12 ssuominen Exp $
+
+*usb_modeswitch-2.1.1_p20140327 (01 Apr 2014)
+
+  01 Apr 2014; Samuli Suominen <ssuominen@g.o>
+  +usb_modeswitch-2.1.1_p20140327.ebuild:
+  Version bump.
 
   06 Mar 2014; Samuli Suominen <ssuominen@g.o>
   usb_modeswitch-2.1.0_p20140129.ebuild:



1.1                  sys-apps/usb_modeswitch/usb_modeswitch-2.1.1_p20140327.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/usb_modeswitch/usb_modeswitch-2.1.1_p20140327.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/usb_modeswitch/usb_modeswitch-2.1.1_p20140327.ebuild?rev=1.1&content-type=text/plain

Index: usb_modeswitch-2.1.1_p20140327.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-apps/usb_modeswitch/usb_modeswitch-2.1.1_p20140327.ebuild,v 1.1 2014/04/01 10:20:12 ssuominen Exp $

EAPI=5
inherit eutils linux-info toolchain-funcs udev systemd

MY_PN=${PN/_/-}
MY_P=${MY_PN}-${PV/_p*}
DATA_VER=${PV/*_p}

DESCRIPTION="USB_ModeSwitch is a tool for controlling 'flip flop' (multiple devices) USB gear like UMTS sticks"
HOMEPAGE="http://www.draisberghof.de/usb_modeswitch/ http://www.draisberghof.de/usb_modeswitch/device_reference.txt"
SRC_URI="http://www.draisberghof.de/${PN}/${MY_P}.tar.bz2
	http://www.draisberghof.de/${PN}/${MY_PN}-data-${DATA_VER}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~arm ~x86"
IUSE="jimtcl"

COMMON_DEPEND="virtual/udev
	virtual/libusb:1"
RDEPEND="${COMMON_DEPEND}
	jimtcl? ( dev-lang/jimtcl )
	!jimtcl? ( dev-lang/tcl )" # usb_modeswitch script is tcl
DEPEND="${COMMON_DEPEND}
	virtual/pkgconfig"

S=${WORKDIR}/${MY_P}

CONFIG_CHECK="~USB_SERIAL"

src_prepare() {
	sed -i -e '/install.*BIN/s:-s::' Makefile || die
}

src_compile() {
	emake CC="$(tc-getCC)"
}

src_install() {
	emake \
		DESTDIR="${D}" \
		SYSDIR="${D}/$(systemd_get_unitdir)" \
		UDEVDIR="${D}/$(get_udevdir)" \
		$(usex jimtcl install-shared install)

	# Even if we set SYSDIR above, the Makefile is causing automagic detection of `systemctl` binary,
	# which is why we need to force the .service file to be installed:
	systemd_dounit ${PN}@.service

	dodoc ChangeLog README

	pushd ../${MY_PN}-data-${DATA_VER} >/dev/null
	emake \
		DESTDIR="${D}" \
		RULESDIR="${D}/$(get_udevdir)/rules.d" \
		files-install db-install
	docinto data
	dodoc ChangeLog README
	popd >/dev/null
}