[gentoo-commits] repo/gentoo:master commit in: dev-python/django/

[Michał Górny]

commit:     2696e4ff092c8485e1ee7118fda42ffbf6b2744a
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Mon Jan  2 14:07:11 2023 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Mon Jan  2 14:54:12 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=2696e4ff

dev-python/django: Bump to 4.1.5

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/django/Manifest            |   2 +
 dev-python/django/django-4.1.5.ebuild | 103 ++++++++++++++++++++++++++++++++++
 2 files changed, 105 insertions(+)

diff --git a/dev-python/django/Manifest b/dev-python/django/Manifest
index 561337149b9b..81d695ae9dd0 100644
--- a/dev-python/django/Manifest
+++ b/dev-python/django/Manifest
@@ -6,3 +6,5 @@ DIST Django-4.1.3.checksum.txt 2547 BLAKE2B d4a0c921360871495c16c9f44c0b7fef4372
 DIST Django-4.1.3.tar.gz 10476258 BLAKE2B 9c4865ba86f846a017a7f382320c965fa67f56dbe660a1bf0e974d5cbde21f6c8a88f80675d884d03424e9cd4f1d89af0c9f76be135e875e003f45b1cff5b604 SHA512 3bc77444f22b9dc029d5f45b6481224b99afe41f43d6306db69d01ca5ba24ed05f6c3bd7b3f5320dd96e6d79a47ac1c8f45a86cd8d3822432be4e73b006026ca
 DIST Django-4.1.4.checksum.txt 2553 BLAKE2B 18a8a5de5148f1ade673fc158c756a5b9dc70a2164d7d094ce56dae67a89ea9e8ee808f8319508a7af9229642a80215bd25980257bc78ad982ccf91722379f97 SHA512 d39791499b59b9912eb589a7174a012a33a61d74f5bcbaedca6bdf78cf584296a52f221affc1ddae696a114695c8d533cbbc94d2d855abae40a2b811db40f036
 DIST Django-4.1.4.tar.gz 10517427 BLAKE2B aee4e92dc2e87dc4281025f68274380da46661c504e65db516f0565fc225388e1fb35d7a742a19b8768a31e416bcc82db9c38f4a397c9a88c50448a09a2370e3 SHA512 43649665ac6235b103a3d2c1271dfa0c6177dd2eeca24cefe210809bca85b29b7ecd10de1e7a88677c7ab26b0a1c1912af013bbcbcfadcbc1f85416c10ec7d5f
+DIST Django-4.1.5.checksum.txt 2546 BLAKE2B 3555213c23228ca26b7944c6c13a57232b17cda457c624ca38a3e05149bee5cff0f4c83e3677e775b7acdcff0157219488f82a1091234ace037097b8fe016ab4 SHA512 8fe18f80e8f3ae9635d55dcc48854e533437f938775de095c211e82f6ac97272c9af0fd5beb22f2f64894a2d64d6ab24f19c4d4aad4a483b7ad7d60c52e84974
+DIST Django-4.1.5.tar.gz 10507020 BLAKE2B 8fad2919cbe421524289f52c448b77f48abb87a61480db8c5e93ecdbf3b4410f3c5cb678a8643a13c21a236790e891dfc50159c5619847bd7085764c2734763d SHA512 483acebcc0cdc7f7e6e6264b23fd6528d1a8e66c9ccd421506bb2504ff55b058d514a2a359618892a786a0784d9580041db715b1990d8f5ae3c2e59a242eb578

diff --git a/dev-python/django/django-4.1.5.ebuild b/dev-python/django/django-4.1.5.ebuild
new file mode 100644
index 000000000000..7aeae03c53af
--- /dev/null
+++ b/dev-python/django/django-4.1.5.ebuild
@@ -0,0 +1,103 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..11} )
+PYTHON_REQ_USE='sqlite?,threads(+)'
+
+inherit bash-completion-r1 distutils-r1 optfeature verify-sig
+
+DESCRIPTION="High-level Python web framework"
+HOMEPAGE="
+	https://www.djangoproject.com/
+	https://github.com/django/django/
+	https://pypi.org/project/Django/
+"
+SRC_URI="
+	https://media.djangoproject.com/releases/$(ver_cut 1-2)/${P^}.tar.gz
+	verify-sig? ( https://media.djangoproject.com/pgp/${P^}.checksum.txt )
+"
+S="${WORKDIR}/${P^}"
+
+LICENSE="BSD"
+# admin fonts: Roboto (media-fonts/roboto)
+LICENSE+=" Apache-2.0"
+# admin icons, jquery, xregexp.js
+LICENSE+=" MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86 ~x64-macos"
+IUSE="doc sqlite test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	<dev-python/asgiref-4[${PYTHON_USEDEP}]
+	>=dev-python/asgiref-3.5.2[${PYTHON_USEDEP}]
+	>=dev-python/sqlparse-0.2.2[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		dev-python/backports-zoneinfo[${PYTHON_USEDEP}]
+	' 3.8)
+"
+BDEPEND="
+	test? (
+		$(python_gen_impl_dep sqlite)
+		${RDEPEND}
+		dev-python/docutils[${PYTHON_USEDEP}]
+		dev-python/jinja[${PYTHON_USEDEP}]
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/pillow[webp,${PYTHON_USEDEP}]
+		dev-python/pyyaml[${PYTHON_USEDEP}]
+		dev-python/selenium[${PYTHON_USEDEP}]
+		dev-python/tblib[${PYTHON_USEDEP}]
+		sys-devel/gettext
+		!!<dev-python/ipython-7.21.0-r1
+		!!=dev-python/ipython-7.22.0-r0
+	)
+	verify-sig? ( >=sec-keys/openpgp-keys-django-20201201 )
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-4.0-bashcomp.patch
+)
+
+distutils_enable_sphinx docs --no-autodoc
+
+VERIFY_SIG_OPENPGP_KEY_PATH=${BROOT}/usr/share/openpgp-keys/django.asc
+
+src_unpack() {
+	if use verify-sig; then
+		cd "${DISTDIR}" || die
+		verify-sig_verify_signed_checksums \
+			"${P^}.checksum.txt" sha256 "${P^}.tar.gz"
+		cd "${WORKDIR}" || die
+	fi
+
+	default
+}
+
+python_test() {
+	# Tests have non-standard assumptions about PYTHONPATH,
+	# and don't work with ${BUILD_DIR}/lib.
+	PYTHONPATH=. "${EPYTHON}" tests/runtests.py --settings=test_sqlite -v2 ||
+		die "Tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+	newbashcomp extras/django_bash_completion ${PN}-admin
+	bashcomp_alias ${PN}-admin django-admin.py
+
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	optfeature_header "Additional Backend support can be enabled via:"
+	optfeature "MySQL backend support" dev-python/mysqlclient
+	optfeature "PostgreSQL backend support" dev-python/psycopg:2
+	optfeature_header
+	optfeature "GEO Django" "sci-libs/gdal[geos]"
+	optfeature "Memcached support" dev-python/pylibmc dev-python/python-memcached
+	optfeature "ImageField Support" dev-python/pillow
+	optfeature "Password encryption" dev-python/bcrypt
+	optfeature "High-level abstractions for Django forms" dev-python/django-formtools
+}