[gentoo-commits] repo/gentoo:master commit in: sys-kernel/ck-sources/

[Michał Górny]

commit:     672fe71d4394906c4b7fad9fd977a5eaf2f40f7d
Author:     kuzetsa <kuzetsa <AT> gmail <DOT> com>
AuthorDate: Mon Aug  7 11:07:25 2017 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Thu Aug 10 11:00:40 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=672fe71d

sys-kernel/ck-sources: 4.9 (longterm branch) --> EAPI 6

Commit also minimizes layout diffs from 4.11 (EOL branch)

Status: 4.12 branch from ck-patches upstream still pending.

Package-Manager: Portage-2.3.6, Repoman-2.3.1

 sys-kernel/ck-sources/ck-sources-4.9.39-r1.ebuild | 65 +++++++++++++++++++++++
 1 file changed, 65 insertions(+)

diff --git a/sys-kernel/ck-sources/ck-sources-4.9.39-r1.ebuild b/sys-kernel/ck-sources/ck-sources-4.9.39-r1.ebuild
new file mode 100644
index 00000000000..a13a8782cb4
--- /dev/null
+++ b/sys-kernel/ck-sources/ck-sources-4.9.39-r1.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+ETYPE="sources"
+KEYWORDS="~amd64 ~x86"
+
+HOMEPAGE="https://dev.gentoo.org/~mpagano/genpatches/
+	http://users.tpg.com.au/ckolivas/kernel/"
+
+K_WANT_GENPATCHES="base extras experimental"
+K_EXP_GENPATCHES_PULL="1"
+K_EXP_GENPATCHES_NOUSE="1"
+K_GENPATCHES_VER="40"
+K_SECURITY_UNSUPPORTED="1"
+K_DEBLOB_AVAILABLE="1"
+
+PYTHON_COMPAT=( python2_7 )
+inherit python-any-r1 kernel-2
+detect_version
+detect_arch
+
+DEPEND="deblob? ( ${PYTHON_DEPS} )"
+
+K_BRANCH_ID="${KV_MAJOR}.${KV_MINOR}"
+
+DESCRIPTION="Con Kolivas' high performance patchset and Gentoo's genpatches for Linux ${K_BRANCH_ID}"
+
+CK_VERSION="1"
+
+CK_FILE="patch-${K_BRANCH_ID}-ck${CK_VERSION}.xz"
+
+CK_BASE_URL="http://ck.kolivas.org/patches/4.0"
+CK_LVER_URL="${CK_BASE_URL}/${K_BRANCH_ID}/${K_BRANCH_ID}-ck${CK_VERSION}"
+CK_URI="${CK_LVER_URL}/${CK_FILE}"
+
+# solves bug #606866 (Fix build for CONFIG_FREEZER disabled.x)
+FRZR_HASH="7de569950716147ed436b27936628ee3ab5b45cc"
+FRZR_FILE="${PN}-4.9-freezer-fix.patch"
+FRZR_URI="https://github.com/ckolivas/linux/commit/${FRZR_HASH}.patch -> ${FRZR_FILE}"
+
+SRC_URI="${KERNEL_URI} ${GENPATCHES_URI} ${ARCH_URI} ${CK_URI} ${FRZR_URI}"
+
+UNIPATCH_LIST="${DISTDIR}/${CK_FILE} ${DISTDIR}/${FRZR_FILE}"
+UNIPATCH_STRICTORDER="yes"
+
+# ck-patches already includes BFQ (similar version as genpatches "experimental" USE flag)
+# what's not included is: "additional cpu optimizations" (5010) from genpatches experimental
+
+K_EXP_GENPATCHES_LIST="5010_*.patch*"
+
+pkg_setup() {
+	use deblob && python-any-r1_pkg_setup
+	kernel-2_pkg_setup
+}
+
+src_prepare() {
+
+#-- Comment out CK's EXTRAVERSION in Makefile ---------------------------------
+
+	# linux-info eclass cannot handle recursively expanded variables in Makefile #490328
+	sed -i -e 's/\(^EXTRAVERSION :=.*$\)/# \1/' "${S}/Makefile" || die
+
+	kernel-2_src_prepare
+}