[gentoo-commits] repo/gentoo:master commit in: app-misc/golly/

[Sergei Trofimovich]

commit:     2e023c9420fe1e39660698d5c0c5f7492b22bc5f
Author:     Sergei Trofimovich <slyfox <AT> gentoo <DOT> org>
AuthorDate: Sat Jun 27 19:29:42 2020 +0000
Commit:     Sergei Trofimovich <slyfox <AT> gentoo <DOT> org>
CommitDate: Sat Jun 27 21:02:05 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=2e023c94

app-misc/golly: drop unused eclasses

Package-Manager: Portage-2.3.103, Repoman-2.3.23
Signed-off-by: Sergei Trofimovich <slyfox <AT> gentoo.org>

 app-misc/golly/golly-3.3-r2.ebuild | 51 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 51 insertions(+)

diff --git a/app-misc/golly/golly-3.3-r2.ebuild b/app-misc/golly/golly-3.3-r2.ebuild
new file mode 100644
index 00000000000..9ae4bf4acd8
--- /dev/null
+++ b/app-misc/golly/golly-3.3-r2.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+WX_GTK_VER=3.0
+PYTHON_COMPAT=( python2_7 )
+
+inherit desktop python-single-r1 wxwidgets xdg-utils
+
+DESCRIPTION="simulator for Conway's Game of Life and other cellular automata"
+HOMEPAGE="http://golly.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${P}-src.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="tiff"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+DEPEND="virtual/opengl
+	sys-libs/zlib
+	x11-libs/wxGTK:${WX_GTK_VER}[X,opengl,tiff?]"
+RDEPEND="${DEPEND}
+	${PYTHON_DEPS}"
+
+S=${WORKDIR}/${P}-src
+
+pkg_setup() {
+	setup-wxwidgets
+}
+
+src_configure() {
+	ECONF_SOURCE=gui-wx/configure econf \
+		--with-wxshared
+}
+
+src_install() {
+	emake docdir= DESTDIR="${D}" install
+	dodoc docs/ReadMe.html
+	newicon --size 32 gui-wx/icons/appicon.xpm ${PN}.xpm
+	make_desktop_entry ${PN} "Golly" ${PN} "Science"
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}