[gentoo-commits] gentoo-x86 commit in sys-power/upower: ChangeLog upower-0.9.3.ebuild

[Samuli Suominen (ssuominen)]

ssuominen    10/05/10 22:09:39

  Modified:             ChangeLog
  Added:                upower-0.9.3.ebuild
  Log:
  Version bump.
  (Portage version: 2.2_rc67/cvs/Linux x86_64)

Revision  Changes    Path
1.4                  sys-power/upower/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-power/upower/ChangeLog?rev=1.4&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-power/upower/ChangeLog?rev=1.4&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-power/upower/ChangeLog?r1=1.3&r2=1.4

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-power/upower/ChangeLog,v
retrieving revision 1.3
retrieving revision 1.4
diff -u -r1.3 -r1.4
--- ChangeLog	17 Apr 2010 11:37:26 -0000	1.3
+++ ChangeLog	10 May 2010 22:09:39 -0000	1.4
@@ -1,6 +1,11 @@
 # ChangeLog for sys-power/upower
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-power/upower/ChangeLog,v 1.3 2010/04/17 11:37:26 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-power/upower/ChangeLog,v 1.4 2010/05/10 22:09:39 ssuominen Exp $
+
+*upower-0.9.3 (10 May 2010)
+
+  10 May 2010; Samuli Suominen <ssuominen@g.o> +upower-0.9.3.ebuild:
+  Version bump.
 
   17 Apr 2010; Samuli Suominen <ssuominen@g.o> upower-0.9.2.ebuild:
   Raise pm-utils depend to 1.3.0-r2 for on_ac_power support wrt #315663.



1.1                  sys-power/upower/upower-0.9.3.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-power/upower/upower-0.9.3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-power/upower/upower-0.9.3.ebuild?rev=1.1&content-type=text/plain

Index: upower-0.9.3.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-power/upower/upower-0.9.3.ebuild,v 1.1 2010/05/10 22:09:39 ssuominen Exp $

EAPI=3
inherit linux-info

DESCRIPTION="D-Bus abstraction for enumerating power devices and querying history and statistics"
HOMEPAGE="http://upower.freedesktop.org/"
SRC_URI="http://upower.freedesktop.org/releases/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86 ~x86-fbsd"
IUSE="debug doc nls kernel_FreeBSD kernel_linux test"

COMMON_DEPEND=">=dev-libs/glib-2.21.5:2
	>=sys-apps/dbus-1
	>=dev-libs/dbus-glib-0.76
	>=sys-auth/polkit-0.91
	kernel_linux? ( >=sys-fs/udev-151[extras]
		virtual/libusb:0 )
	!sys-apps/devicekit-power"
RDEPEND="${COMMON_DEPEND}
	kernel_linux? ( >=sys-power/pm-utils-1.3.0-r2 )"
DEPEND="${COMMON_DEPEND}
	dev-util/pkgconfig
	dev-libs/libxslt
	app-text/docbook-xsl-stylesheets
	doc? ( dev-util/gtk-doc
		app-text/docbook-xml-dtd:4.1.2 )
	nls? ( >=dev-util/intltool-0.40.0 )"

pkg_setup() {
	if use kernel_linux; then
		if use amd64 || use x86; then
			CONFIG_CHECK="~ACPI_SYSFS_POWER"
			linux-info_pkg_setup
		fi
	fi
}

src_prepare() {
	sed -i \
		-e '/DISABLE_DEPRECATED/d' \
		configure || die
}

src_configure() {
	local backend

	if use kernel_linux; then
		backend=linux
	elif use kernel_FreeBSD; then
		backend=freebsd
	else
		backend=dummy
	fi

	econf \
		--localstatedir="${EPREFIX}/var" \
		--disable-dependency-tracking \
		--disable-static \
		$(use_enable debug verbose-mode) \
		--enable-man-pages \
		$(use_enable doc gtk-doc) \
		$(use_enable test tests) \
		$(use_enable nls) \
		--with-html-dir="${EPREFIX}/usr/share/doc/${PF}/html" \
		--with-backend=${backend}
}

src_install() {
	emake DESTDIR="${D}" install || die
	dodoc AUTHORS HACKING NEWS README

	find "${ED}" -name '*.la' -delete
}