[gentoo-commits] gentoo-x86 commit in net-fs/openafs: ChangeLog openafs-1.6.2.ebuild openafs-1.6.5.ebuild

[Tom Wijsman (tomwij)]

tomwij      13/08/27 08:15:30

  Modified:             ChangeLog openafs-1.6.2.ebuild
  Added:                openafs-1.6.5.ebuild
  Log:
  Version bump to 1.6.5. Fixes bug #478498 which fixes security bug #478296, security bug #478282, bug #472184, bug #469992, bug #463477 and bug #460494. Proxied commit for Andrej Filipcic. Drop autotools eclass because none of its functions are used.
  
  (Portage version: 2.2.1/cvs/Linux x86_64, signed Manifest commit with key 6D34E57D)

Revision  Changes    Path
1.194                net-fs/openafs/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-fs/openafs/ChangeLog?rev=1.194&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-fs/openafs/ChangeLog?rev=1.194&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-fs/openafs/ChangeLog?r1=1.193&r2=1.194

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-fs/openafs/ChangeLog,v
retrieving revision 1.193
retrieving revision 1.194
diff -u -r1.193 -r1.194
--- ChangeLog	13 Apr 2013 14:21:07 -0000	1.193
+++ ChangeLog	27 Aug 2013 08:15:30 -0000	1.194
@@ -1,6 +1,13 @@
 # ChangeLog for net-fs/openafs
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-fs/openafs/ChangeLog,v 1.193 2013/04/13 14:21:07 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-fs/openafs/ChangeLog,v 1.194 2013/08/27 08:15:30 tomwij Exp $
+
+*openafs-1.6.5 (27 Aug 2013)
+
+  27 Aug 2013; Tom Wijsman <TomWij@g.o> +openafs-1.6.5.ebuild:
+  Version bump to 1.6.5. Fixes bug #478498 which fixes security bug #478296,
+  security bug #478282, bug #472184, bug #469992, bug #463477 and bug #460494.
+  Proxied commit for Andrej Filipcic.
 
   13 Apr 2013; Agostino Sarubbo <ago@g.o> -openafs-1.4.14.1-r1.ebuild,
   -openafs-1.4.14.1.ebuild, -openafs-1.6.1-r2.ebuild, -openafs-1.6.1-r3.ebuild,



1.5                  net-fs/openafs/openafs-1.6.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-fs/openafs/openafs-1.6.2.ebuild?rev=1.5&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-fs/openafs/openafs-1.6.2.ebuild?rev=1.5&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-fs/openafs/openafs-1.6.2.ebuild?r1=1.4&r2=1.5

Index: openafs-1.6.2.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-fs/openafs/openafs-1.6.2.ebuild,v
retrieving revision 1.4
retrieving revision 1.5
diff -u -r1.4 -r1.5
--- openafs-1.6.2.ebuild	13 Apr 2013 14:20:09 -0000	1.4
+++ openafs-1.6.2.ebuild	27 Aug 2013 08:15:30 -0000	1.5
@@ -1,10 +1,10 @@
 # Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-fs/openafs/openafs-1.6.2.ebuild,v 1.4 2013/04/13 14:20:09 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-fs/openafs/openafs-1.6.2.ebuild,v 1.5 2013/08/27 08:15:30 tomwij Exp $
 
 EAPI="4"
 
-inherit flag-o-matic eutils autotools multilib toolchain-funcs versionator pam
+inherit flag-o-matic eutils multilib toolchain-funcs versionator pam
 
 MY_PV=$(delete_version_separator '_')
 MY_P="${PN}-${MY_PV}"



1.1                  net-fs/openafs/openafs-1.6.5.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-fs/openafs/openafs-1.6.5.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-fs/openafs/openafs-1.6.5.ebuild?rev=1.1&content-type=text/plain

Index: openafs-1.6.5.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-fs/openafs/openafs-1.6.5.ebuild,v 1.1 2013/08/27 08:15:30 tomwij Exp $

EAPI="4"

inherit flag-o-matic eutils multilib toolchain-funcs versionator pam

MY_PV=$(delete_version_separator '_')
MY_P="${PN}-${MY_PV}"
PVER="1"
DESCRIPTION="The OpenAFS distributed file system"
HOMEPAGE="http://www.openafs.org/"
# We always d/l the doc tarball as man pages are not USE=doc material
SRC_URI="http://openafs.org/dl/openafs/${MY_PV}/${MY_P}-src.tar.bz2
	http://openafs.org/dl/openafs/${MY_PV}/${MY_P}-doc.tar.bz2
	mirror://gentoo/${P}-patches-${PVER}.tar.bz2"

LICENSE="IBM BSD openafs-krb5-a APSL-2"
SLOT="0"
KEYWORDS="~amd64 ~sparc ~x86 ~amd64-linux ~x86-linux"
IUSE="doc kerberos pam"

RDEPEND="~net-fs/openafs-kernel-${PV}
	sys-libs/ncurses
	pam? ( sys-libs/pam )
	kerberos? ( virtual/krb5 )"

S="${WORKDIR}/${MY_P}"

src_prepare() {
	EPATCH_SUFFIX="patch" \
	epatch "${WORKDIR}"/gentoo/patches

	# packaging is f-ed up, so we can't run automake (i.e. eautoreconf)
	sed -i 's/^\(\s*\)a/\1ea/' regen.sh
	: # this line makes repoman ok with not calling eautoconf etc. directly
	skipman=1
	. regen.sh
}

src_configure() {
	# cannot use "use_with" macro, as --without-krb5-config crashes the econf
	local myconf=""
	if use kerberos; then
		myconf="--with-krb5-conf=$(type -p krb5-config)"
	fi

	AFS_SYSKVERS=26 \
	XCFLAGS="${CFLAGS}" \
	econf \
		$(use_enable pam) \
		--enable-supergroups \
		--disable-kernel-module \
		--disable-strip-binaries \
		${myconf}
}

src_compile() {
	emake all_nolibafs
}

src_install() {
	local CONFDIR=${WORKDIR}/gentoo/configs
	local SCRIPTDIR=${WORKDIR}/gentoo/scripts

	emake DESTDIR="${ED}" install_nolibafs

	insinto /etc/openafs
	doins src/afsd/CellServDB
	echo "/afs:/var/cache/openafs:200000" > "${ED}"/etc/openafs/cacheinfo
	echo "openafs.org" > "${ED}"/etc/openafs/ThisCell

	# pam_afs and pam_afs.krb have been installed in irregular locations, fix
	if use pam ; then
		dopammod "${ED}"/usr/$(get_libdir)/pam_afs*
	fi
	rm -f "${ED}"/usr/$(get_libdir)/pam_afs* || die

	# remove kdump stuff provided by kexec-tools #222455
	rm -rf "${ED}"/usr/sbin/kdump*

	# avoid collision with mit_krb5's version of kpasswd
	mv "${ED}"/usr/bin/kpasswd{,_afs} || die
	mv "${ED}"/usr/share/man/man1/kpasswd{,_afs}.1 || die

	# move lwp stuff around #200674 #330061
	mv "${ED}"/usr/include/{lwp,lock,timer}.h "${ED}"/usr/include/afs/ || die
	mv "${ED}"/usr/$(get_libdir)/liblwp* "${ED}"/usr/$(get_libdir)/afs/ || die
	# update paths to the relocated lwp headers
	sed -ri \
		-e '/^#include <(lwp|lock|timer).h>/s:<([^>]*)>:<afs/\1>:' \
		"${ED}"/usr/include/*.h \
		"${ED}"/usr/include/*/*.h \
		|| die

	# minimal documentation
	use pam && doman src/pam/pam_afs.5
	dodoc "${CONFDIR}"/README src/afsd/CellServDB

	# documentation package
	if use doc ; then
		find doc/{arch,examples,pdf,protocol,txt}/ -type f -exec dodoc {} +
		dohtml -A xml -r doc/{html,xml}/*
	fi

	# Gentoo related scripts
	newinitd "${SCRIPTDIR}"/openafs-client openafs-client || die
	newconfd "${CONFDIR}"/openafs-client openafs-client || die
	newinitd "${SCRIPTDIR}"/openafs-server openafs-server || die
	newconfd "${CONFDIR}"/openafs-server openafs-server || die

	# used directories: client
	keepdir /etc/openafs
	keepdir /var/cache/openafs

	# used directories: server
	keepdir /etc/openafs/server
	diropts -m0700
	keepdir /var/lib/openafs
	keepdir /var/lib/openafs/db
	diropts -m0755
	keepdir /var/lib/openafs/logs

	# link logfiles to /var/log
	dosym ../lib/openafs/logs /var/log/openafs
}

pkg_preinst() {
	## Somewhat intelligently install default configuration files
	## (when they are not present)
	local x
	for x in cacheinfo CellServDB ThisCell ; do
		if [ -e "${EROOT}"/etc/openafs/${x} ] ; then
			cp "${EROOT}"/etc/openafs/${x} "${ED}"/etc/openafs/
		fi
	done
}

pkg_postinst() {
	elog "This installation should work out of the box (at least the"
	elog "client part doing global afs-cell browsing, unless you had"
	elog "a previous and different configuration).  If you want to"
	elog "set up your own cell or modify the standard config,"
	elog "please have a look at the Gentoo OpenAFS documentation"
	elog "(warning: it is not yet up to date wrt the new file locations)"
	elog
	elog "The documentation can be found at:"
	elog "  http://www.gentoo.org/doc/en/openafs.xml"
}