[gentoo-commits] gentoo-x86 commit in dev-python/webtest: webtest-2.0.15.ebuild ChangeLog

[Ian Delaney (idella4)]

idella4     14/05/23 10:51:26

  Modified:             ChangeLog
  Added:                webtest-2.0.15.ebuild
  Log:
  bump; drop py2.6, tidy
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key 0xB8072B0D)

Revision  Changes    Path
1.81                 dev-python/webtest/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/webtest/ChangeLog?rev=1.81&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/webtest/ChangeLog?rev=1.81&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/webtest/ChangeLog?r1=1.80&r2=1.81

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/webtest/ChangeLog,v
retrieving revision 1.80
retrieving revision 1.81
diff -u -r1.80 -r1.81
--- ChangeLog	31 Mar 2014 09:48:16 -0000	1.80
+++ ChangeLog	23 May 2014 10:51:26 -0000	1.81
@@ -1,6 +1,11 @@
 # ChangeLog for dev-python/webtest
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/webtest/ChangeLog,v 1.80 2014/03/31 09:48:16 patrick Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/webtest/ChangeLog,v 1.81 2014/05/23 10:51:26 idella4 Exp $
+
+*webtest-2.0.15 (23 May 2014)
+
+  23 May 2014; Ian Delaney <idella4@g.o> +webtest-2.0.15.ebuild:
+  bump; drop py2.6, tidy
 
 *webtest-2.0.14 (31 Mar 2014)
 



1.1                  dev-python/webtest/webtest-2.0.15.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/webtest/webtest-2.0.15.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/webtest/webtest-2.0.15.ebuild?rev=1.1&content-type=text/plain

Index: webtest-2.0.15.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/webtest/webtest-2.0.15.ebuild,v 1.1 2014/05/23 10:51:26 idella4 Exp $

EAPI=5

PYTHON_COMPAT=( python{2_7,3_2,3_3} )

inherit distutils-r1

MY_PN="WebTest"
MY_P="${MY_PN}-${PV}"

DESCRIPTION="Helper to test WSGI applications"
HOMEPAGE="http://pythonpaste.org/webtest/ http://pypi.python.org/pypi/WebTest"
SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.zip"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="doc test"

#nose<1.3.0
RDEPEND="
	dev-python/six[${PYTHON_USEDEP}]
	>=dev-python/waitress-0.8.5[${PYTHON_USEDEP}]
	>=dev-python/webob-1.2[${PYTHON_USEDEP}]
	dev-python/beautifulsoup:4[${PYTHON_USEDEP}]"
DEPEND="${RDEPEND}
	app-arch/unzip
	dev-python/setuptools[${PYTHON_USEDEP}]
	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
	test? ( dev-python/nose[${PYTHON_USEDEP}]
		dev-python/pyquery[${PYTHON_USEDEP}]
		dev-python/pastedeploy[${PYTHON_USEDEP}]
		dev-python/wsgiproxy2[${PYTHON_USEDEP}]
		dev-python/coverage[${PYTHON_USEDEP}]
		dev-python/mock[${PYTHON_USEDEP}]
		virtual/python-unittest2[${PYTHON_USEDEP}]
	)"

S="${WORKDIR}/${MY_P}"

# Makes testing easier; otherwise we get errors from pkg_resources.
DISTUTILS_IN_SOURCE_BUILD=1

python_prepare_all() {
	# Prevent un-needed d'loading during doc build
	sed -s 's:intersphinx_mapping:_&:' -i docs/conf.py || die
	distutils-r1_python_prepare_all
}

python_compile_all() {
	if use doc; then
		sphinx-build docs html || die
	fi
}

src_test() {
	DISTUTILS_NO_PARALLEL_BUILD=1 distutils-r1_src_test
}

python_test() {
	# Tests raise ImportErrors with our default PYTHONPATH.
	local -x PYTHONPATH=
	nosetests || die "Tests fail with ${EPYTHON}"
}

python_install() {
	distutils-r1_python_install

	# Why is it so?
	if python_is_python3; then
		rm -f "${D}$(python_get_sitedir)"/webtest/lint3.py
	fi
}

python_install_all() {
	use doc && local HTML_DOCS=( html/. )
	distutils-r1_python_install_all
}