[gentoo-commits] gentoo-x86 commit in x11-libs/libcryptui: metadata.xml ChangeLog libcryptui-3.2.0.ebuild

[Alexandre Rostovtsev (tetromino)]

tetromino    11/10/30 07:47:05

  Added:                metadata.xml ChangeLog libcryptui-3.2.0.ebuild
  Log:
  New ebuild from the gnome overlay. Contains the widget library that was split off from app-crypt/seahorse in gnome-3.1.x.
  
  (Portage version: 2.2.0_alpha71/cvs/Linux x86_64)

Revision  Changes    Path
1.1                  x11-libs/libcryptui/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/libcryptui/metadata.xml?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/libcryptui/metadata.xml?rev=1.1&content-type=text/plain

Index: metadata.xml
===================================================================
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
<herd>gnome</herd>
<use>
  <flag name="introspection">Use <pkg>dev-libs/gobject-introspection</pkg>
    for introspection</flag>
</use>
</pkgmetadata>



1.1                  x11-libs/libcryptui/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/libcryptui/ChangeLog?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/libcryptui/ChangeLog?rev=1.1&content-type=text/plain

Index: ChangeLog
===================================================================
# ChangeLog for x11-libs/libcryptui
# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
# $Header: /var/cvsroot/gentoo-x86/x11-libs/libcryptui/ChangeLog,v 1.1 2011/10/30 07:47:05 tetromino Exp $

*libcryptui-3.2.0 (30 Oct 2011)

  30 Oct 2011; Alexandre Rostovtsev <tetromino@g.o>
  +libcryptui-3.2.0.ebuild, +metadata.xml:
  New ebuild from the gnome overlay. Contains the widget library that was split
  off from app-crypt/seahorse in gnome-3.1.x.




1.1                  x11-libs/libcryptui/libcryptui-3.2.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/libcryptui/libcryptui-3.2.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/libcryptui/libcryptui-3.2.0.ebuild?rev=1.1&content-type=text/plain

Index: libcryptui-3.2.0.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-libs/libcryptui/libcryptui-3.2.0.ebuild,v 1.1 2011/10/30 07:47:05 tetromino Exp $

EAPI="4"
GCONF_DEBUG="yes"
GNOME2_LA_PUNT="yes"

inherit gnome2

DESCRIPTION="User interface components for OpenPGP"
HOMEPAGE="http://www.gnome.org/projects/seahorse/index.html"

LICENSE="GPL-2 LGPL-2"
SLOT="0"
IUSE="debug doc +introspection libnotify test"
KEYWORDS="~alpha ~amd64 ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"

# Pull in libnotify-0.7 because it's controlled via an automagic ifdef
COMMON_DEPEND="
	>=dev-libs/glib-2.10:2
	>=x11-libs/gtk+-2.90.0:3[introspection?]
	>=dev-libs/dbus-glib-0.72
	>=gnome-base/gnome-keyring-2.91.2

	>=app-crypt/gpgme-1
	|| (
		=app-crypt/gnupg-2.0*
		=app-crypt/gnupg-1.4* )

	introspection? ( >=dev-libs/gobject-introspection-0.6.4 )
	libnotify? ( >=x11-libs/libnotify-0.7.0 )
"
DEPEND="${COMMON_DEPEND}
	sys-devel/gettext
	>=app-text/scrollkeeper-0.3
	>=dev-util/pkgconfig-0.20
	>=dev-util/intltool-0.35
	doc? ( >=dev-util/gtk-doc-1.9 )
"
# Before 3.1.4, libcryptui was part of seahorse
RDEPEND="${COMMON_DEPEND}
	!<app-crypt/seahorse-3.1.4
"

pkg_setup() {
	G2CONF="${G2CONF}
		--disable-static
		--disable-scrollkeeper
		--disable-update-mime-database
		$(use_enable debug)
		$(use_enable introspection)
		$(use_enable libnotify)
		$(use_enable test tests)"
	DOCS="AUTHORS ChangeLog NEWS README"
}

src_prepare() {
	# FIXME: Do not mess with CFLAGS with USE="debug"
	sed -e '/CFLAGS="$CFLAGS -g -O0/d' \
		-e 's/-Werror//' \
		-i configure.ac configure || die "sed failed"

	gnome2_src_prepare
}