[gentoo-commits] gentoo-x86 commit in app-accessibility/orca: ChangeLog orca-3.12.1.ebuild

[Gilles Dartiguelongue (eva)]

eva         14/04/27 15:18:30

  Modified:             ChangeLog
  Added:                orca-3.12.1.ebuild
  Log:
  Version bump for Gnome 3.12.
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key C6085806)

Revision  Changes    Path
1.129                app-accessibility/orca/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-accessibility/orca/ChangeLog?rev=1.129&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-accessibility/orca/ChangeLog?rev=1.129&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-accessibility/orca/ChangeLog?r1=1.128&r2=1.129

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-accessibility/orca/ChangeLog,v
retrieving revision 1.128
retrieving revision 1.129
diff -u -r1.128 -r1.129
--- ChangeLog	5 Apr 2014 07:28:08 -0000	1.128
+++ ChangeLog	27 Apr 2014 15:18:30 -0000	1.129
@@ -1,6 +1,11 @@
 # ChangeLog for app-accessibility/orca
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-accessibility/orca/ChangeLog,v 1.128 2014/04/05 07:28:08 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-accessibility/orca/ChangeLog,v 1.129 2014/04/27 15:18:30 eva Exp $
+
+*orca-3.12.1 (27 Apr 2014)
+
+  27 Apr 2014; Gilles Dartiguelongue <eva@g.o> +orca-3.12.1.ebuild:
+  Version bump for Gnome 3.12.
 
 *orca-3.10.3 (05 Apr 2014)
 



1.1                  app-accessibility/orca/orca-3.12.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-accessibility/orca/orca-3.12.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-accessibility/orca/orca-3.12.1.ebuild?rev=1.1&content-type=text/plain

Index: orca-3.12.1.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-accessibility/orca/orca-3.12.1.ebuild,v 1.1 2014/04/27 15:18:30 eva Exp $

EAPI="5"
GCONF_DEBUG="no"
GNOME2_LA_PUNT="yes"
PYTHON_COMPAT=( python3_3 )
PYTHON_REQ_USE="threads"

inherit gnome2 python-r1

DESCRIPTION="Extensible screen reader that provides access to the desktop"
HOMEPAGE="https://wiki.gnome.org/Projects/Orca"

LICENSE="LGPL-2.1+ CC-BY-SA-3.0"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE=""
REQUIRED_USE="${PYTHON_REQUIRED_USE}"

# liblouis is not in portage yet
# it is used to provide contracted braille support
# XXX: Check deps for correctness
COMMON_DEPEND="
	>=app-accessibility/at-spi2-atk-2.10:2
	>=app-accessibility/at-spi2-core-2.10:2[introspection]
	>=dev-libs/atk-2.10
	>=dev-libs/glib-2.28:2
	>=dev-python/pygobject-3.10:3[${PYTHON_USEDEP}]
	>=x11-libs/gtk+-3.6.2:3[introspection]
	${PYTHON_DEPS}
"
RDEPEND="${COMMON_DEPEND}
	>=app-accessibility/speech-dispatcher-0.8[python,${PYTHON_USEDEP}]
	dev-libs/atk[introspection]
	dev-python/pyatspi[${PYTHON_USEDEP}]
	dev-python/setproctitle[${PYTHON_USEDEP}]
	x11-libs/libwnck:3[introspection]
	x11-libs/pango[introspection]
"
DEPEND="${COMMON_DEPEND}
	>=dev-util/intltool-0.50
	virtual/pkgconfig
"
#	app-text/yelp-tools

src_prepare() {
	gnome2_src_prepare

	python_copy_sources
}

src_configure() {
	python_foreach_impl run_in_build_dir gnome2_src_configure ITSTOOL="$(type -P true)"
}

src_compile() {
	python_foreach_impl run_in_build_dir gnome2_src_compile
}

src_install() {
	DOCS="AUTHORS ChangeLog MAINTAINERS NEWS README TODO"
	installing() {
		gnome2_src_install
		# Massage shebang to make python_doscript happy
		sed -e 's:#!'"${PYTHON}:#!/usr/bin/python:" \
			-i src/orca/orca || die
		python_doscript src/orca/orca
	}
	python_foreach_impl run_in_build_dir installing
}