[gentoo-commits] gentoo-x86 commit in app-arch/dpkg: metadata.xml ChangeLog dpkg-1.17.0.ebuild

[Jeroen Roovers (jer)]

jer         13/07/27 13:21:54

  Modified:             metadata.xml ChangeLog
  Added:                dpkg-1.17.0.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.0_alpha190/cvs/Linux x86_64, signed Manifest commit with key A792A613)

Revision  Changes    Path
1.8                  app-arch/dpkg/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/dpkg/metadata.xml?rev=1.8&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/dpkg/metadata.xml?rev=1.8&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/dpkg/metadata.xml?r1=1.7&r2=1.8

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-arch/dpkg/metadata.xml,v
retrieving revision 1.7
retrieving revision 1.8
diff -u -r1.7 -r1.8
--- metadata.xml	24 Mar 2010 19:30:13 -0000	1.7
+++ metadata.xml	27 Jul 2013 13:21:53 -0000	1.8
@@ -4,5 +4,6 @@
 <herd>deb-tools</herd>
 <use>
 <flag name="dselect">Build the dselect package-management frontend</flag>
+<flag name="update-alternatives">Install update-alternatives</flag>
 </use>
 </pkgmetadata>



1.231                app-arch/dpkg/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/dpkg/ChangeLog?rev=1.231&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/dpkg/ChangeLog?rev=1.231&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/dpkg/ChangeLog?r1=1.230&r2=1.231

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-arch/dpkg/ChangeLog,v
retrieving revision 1.230
retrieving revision 1.231
diff -u -r1.230 -r1.231
--- ChangeLog	2 Jul 2013 07:41:42 -0000	1.230
+++ ChangeLog	27 Jul 2013 13:21:53 -0000	1.231
@@ -1,6 +1,12 @@
 # ChangeLog for app-arch/dpkg
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-arch/dpkg/ChangeLog,v 1.230 2013/07/02 07:41:42 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-arch/dpkg/ChangeLog,v 1.231 2013/07/27 13:21:53 jer Exp $
+
+*dpkg-1.17.0 (27 Jul 2013)
+
+  27 Jul 2013; Jeroen Roovers <jer@g.o> +dpkg-1.17.0.ebuild,
+  +files/dpkg-1.17.0-gzip-rsyncable.patch, metadata.xml:
+  Version bump.
 
   02 Jul 2013; Agostino Sarubbo <ago@g.o> dpkg-1.16.10.ebuild:
   Stable for sh, wrt bug #473840



1.1                  app-arch/dpkg/dpkg-1.17.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/dpkg/dpkg-1.17.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/dpkg/dpkg-1.17.0.ebuild?rev=1.1&content-type=text/plain

Index: dpkg-1.17.0.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-arch/dpkg/dpkg-1.17.0.ebuild,v 1.1 2013/07/27 13:21:53 jer Exp $

EAPI=5
inherit eutils multilib autotools toolchain-funcs

DESCRIPTION="Package maintenance system for Debian"
HOMEPAGE="http://packages.qa.debian.org/dpkg"
SRC_URI="mirror://debian/pool/main/d/${PN}/${P/-/_}.tar.xz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-linux ~ia64-linux ~x86-linux ~ppc-macos ~x64-solaris ~x86-solaris"
IUSE="+bzip2 dselect +lzma nls test unicode +update-alternatives +zlib"
REQUIRED_USE="dselect? ( nls )"

RDEPEND="
	>=dev-lang/perl-5.6.0
	dev-perl/TimeDate
	>=sys-libs/ncurses-5.2-r7
	lzma? ( app-arch/xz-utils )
	zlib? ( >=sys-libs/zlib-1.1.4 )
	bzip2? ( app-arch/bzip2 )
"
DEPEND="
	${RDEPEND}
	app-arch/xz-utils
	sys-devel/flex
	virtual/pkgconfig
	nls? (
		app-text/po4a
		sys-devel/gettext
	)
	test? (
		dev-perl/DateTime-Format-DateParse
		dev-perl/IO-String
		dev-perl/Test-Pod
	)
"

DOCS=( ChangeLog THANKS TODO )

src_prepare() {
	# do not expect Debian's gzip --rsyncable extension
	epatch "${FILESDIR}"/${PN}-1.17.0-gzip-rsyncable.patch

	# Force the use of the running bash for get-version (this file is never
	# installed, so no need to worry about hardcoding a temporary bash)
	sed -i -e '1c\#!'"${BASH}" get-version || die

	# this test depends on a Debian only gzip extension that adds --rsyncable
	# which will therefore always fail on Gentoo. (bug #310847).
	sed -i scripts/Makefile.am \
		-e '/850_Dpkg_Compression.t/d' \
		|| die "sed failed"

	# test fails (bug #414095)
	sed -i utils/Makefile.am \
		-e '/^test_cases/d;/100_update_alternatives/d' || die

	use nls && strip-linguas -i po

	eautoreconf
}

src_configure() {
	tc-export CC
	econf \
		$(use_enable dselect) \
		$(use_enable nls) \
		$(use_enable unicode) \
		$(use_enable update-alternatives) \
		$(use_with bzip2 bz2) \
		$(use_with zlib) \
		$(use_with lzma liblzma) \
		--disable-compiler-optimisations \
		--disable-compiler-warnings \
		--disable-linker-optimisations \
		--disable-silent-rules \
		--disable-start-stop-daemon \
		--localstatedir="${EPREFIX}"/var \
		--without-selinux
}

src_compile() {
	emake AR=$(tc-getAR)
}

src_install() {
	default

	keepdir /usr/$(get_libdir)/db/methods/{mnt,floppy,disk}
	keepdir /usr/$(get_libdir)/db/{alternatives,info,methods,parts,updates}
}