[gentoo-commits] repo/gentoo:master commit in: lxqt-base/lxqt-config/

[Andreas Sturmlechner]

commit:     1f5f1f0b63dbc5ebefe091150330120863a45034
Author:     Jimi Huotari <chiitoo <AT> gentoo <DOT> org>
AuthorDate: Thu Oct 31 21:40:30 2019 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Sat Nov  2 22:40:59 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=1f5f1f0b

lxqt-base/lxqt-config: add a missing dependency

The 'x11-libs/libXi' package is needed when USE="touchpad".

Package-Manager: Portage-2.3.78, Repoman-2.3.17
Signed-off-by: Jimi Huotari <chiitoo <AT> gentoo.org>
Closes: https://github.com/gentoo/gentoo/pull/13511
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 lxqt-base/lxqt-config/lxqt-config-0.14.1-r1.ebuild | 74 ++++++++++++++++++++++
 1 file changed, 74 insertions(+)

diff --git a/lxqt-base/lxqt-config/lxqt-config-0.14.1-r1.ebuild b/lxqt-base/lxqt-config/lxqt-config-0.14.1-r1.ebuild
new file mode 100644
index 00000000000..263309fa6e7
--- /dev/null
+++ b/lxqt-base/lxqt-config/lxqt-config-0.14.1-r1.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake-utils xdg-utils
+
+DESCRIPTION="LXQt system configuration control center"
+HOMEPAGE="https://lxqt.org/"
+
+if [[ ${PV} = *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/lxqt/${PN}.git"
+else
+	SRC_URI="https://downloads.lxqt.org/downloads/${PN}/${PV}/${P}.tar.xz"
+	KEYWORDS="amd64 ~arm ~arm64 ~ppc64 x86"
+fi
+
+LICENSE="GPL-2 GPL-2+ GPL-3 LGPL-2 LGPL-2+ LGPL-2.1+ WTFPL-2"
+SLOT="0"
+IUSE="+monitor +touchpad"
+
+BDEPEND="
+	dev-qt/linguist-tools:5
+	>=dev-util/lxqt-build-tools-0.6.0
+"
+DEPEND="
+	>=dev-libs/libqtxdg-3.3.1
+	dev-qt/qtcore:5
+	dev-qt/qtdbus:5
+	dev-qt/qtgui:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtx11extras:5
+	dev-qt/qtxml:5
+	kde-frameworks/kwindowsystem:5
+	=lxqt-base/liblxqt-$(ver_cut 1-2)*
+	sys-libs/zlib:=
+	x11-apps/setxkbmap
+	x11-libs/libxcb:=
+	x11-libs/libX11
+	x11-libs/libXcursor
+	x11-libs/libXfixes
+	monitor? ( kde-plasma/libkscreen:5= )
+	touchpad? (
+		virtual/libudev
+		x11-drivers/xf86-input-libinput
+		x11-libs/libXext
+		x11-libs/libXi
+	)
+"
+RDEPEND="${DEPEND}
+	!lxqt-base/lxqt-l10n
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-DWITH_MONITOR="$(usex monitor)"
+		-DWITH_TOUCHPAD="$(usex touchpad)"
+	)
+	cmake-utils_src_configure
+}
+
+src_install() {
+	cmake-utils_src_install
+	doman man/*.1 liblxqt-config-cursor/man/*.1 lxqt-config-appearance/man/*.1
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}