[gentoo-commits] gentoo-x86 commit in net-ftp/lftp: lftp-4.3.6.ebuild ChangeLog lftp-4.3.4-r1.ebuild lftp-4.3.3.ebuild

[Jeroen Roovers (jer)]

jer         12/04/02 03:25:18

  Modified:             ChangeLog
  Added:                lftp-4.3.6.ebuild
  Removed:              lftp-4.3.4-r1.ebuild lftp-4.3.3.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.0_alpha97/cvs/Linux x86_64)

Revision  Changes    Path
1.351                net-ftp/lftp/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-ftp/lftp/ChangeLog?rev=1.351&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-ftp/lftp/ChangeLog?rev=1.351&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-ftp/lftp/ChangeLog?r1=1.350&r2=1.351

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-ftp/lftp/ChangeLog,v
retrieving revision 1.350
retrieving revision 1.351
diff -u -r1.350 -r1.351
--- ChangeLog	1 Apr 2012 14:44:49 -0000	1.350
+++ ChangeLog	2 Apr 2012 03:25:18 -0000	1.351
@@ -1,6 +1,12 @@
 # ChangeLog for net-ftp/lftp
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-ftp/lftp/ChangeLog,v 1.350 2012/04/01 14:44:49 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-ftp/lftp/ChangeLog,v 1.351 2012/04/02 03:25:18 jer Exp $
+
+*lftp-4.3.6 (02 Apr 2012)
+
+  02 Apr 2012; Jeroen Roovers <jer@g.o> -lftp-4.3.3.ebuild,
+  -lftp-4.3.4-r1.ebuild, +lftp-4.3.6.ebuild:
+  Version bump.
 
   01 Apr 2012; Raúl Porcel <armin76@g.o> lftp-4.3.5.ebuild:
   alpha/ia64/s390/sparc stable wrt #405981



1.1                  net-ftp/lftp/lftp-4.3.6.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-ftp/lftp/lftp-4.3.6.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-ftp/lftp/lftp-4.3.6.ebuild?rev=1.1&content-type=text/plain

Index: lftp-4.3.6.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-ftp/lftp/lftp-4.3.6.ebuild,v 1.1 2012/04/02 03:25:18 jer Exp $

EAPI="4"

inherit autotools eutils

DESCRIPTION="A sophisticated ftp/sftp/http/https/torrent client and file transfer program"
HOMEPAGE="http://lftp.yar.ru/"
SRC_URI="http://ftp.yars.free.net/pub/source/${PN}/${P}.tar.xz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86 ~sparc-fbsd ~x86-fbsd"

LFTP_LINGUAS="cs de es fr it ja ko pl pt_BR ru zh_CN zh_HK zh_TW"

IUSE="
	$( for i in ${LFTP_LINGUAS}; do echo linguas_${i}; done )
	gnutls nls socks5 +ssl
"

RDEPEND="
	dev-libs/expat
	>=sys-libs/ncurses-5.1
	socks5? (
		>=net-proxy/dante-1.1.12
		virtual/pam )
	ssl? (
		gnutls? ( >=net-libs/gnutls-1.2.3 )
		!gnutls? ( >=dev-libs/openssl-0.9.6 )
	)
	>=sys-libs/readline-5.1
"

DEPEND="
	${RDEPEND}
	=sys-devel/libtool-2*
	app-arch/xz-utils
	dev-lang/perl
	dev-util/pkgconfig
	nls? ( sys-devel/gettext )
"

DOCS=(
	BUGS ChangeLog FAQ FEATURES MIRRORS NEWS README  README.debug-levels
	README.dnssec  README.modules THANKS TODO
)

src_prepare() {
	epatch \
		"${FILESDIR}/${PN}-4.0.2.91-lafile.patch" \
		"${FILESDIR}/${PN}-4.0.3-autoconf-2.64.patch"
	eautoreconf
}

src_configure() {
	local myconf=""

	if use ssl && use gnutls ; then
		myconf="${myconf} --without-openssl"
	elif use ssl && ! use gnutls ; then
		myconf="${myconf} --without-gnutls --with-openssl=/usr"
	else
		myconf="${myconf} --without-gnutls --without-openssl"
	fi

	use socks5 && myconf="${myconf} --with-socksdante=/usr" \
		|| myconf="${myconf} --without-socksdante"

	econf \
		--enable-packager-mode \
		--sysconfdir=/etc/lftp \
		--with-modules \
		$(use_enable nls) \
		${myconf}
}