[gentoo-commits] gentoo-x86 commit in dev-python/elasticsearch-curator: elasticsearch-curator-3.2.3.ebuild ChangeLog

[Ian Delaney (idella4)]

idella4     15/07/23 08:54:36

  Modified:             ChangeLog
  Added:                elasticsearch-curator-3.2.3.ebuild
  Log:
  bump
  
  (Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key 0xB8072B0D)

Revision  Changes    Path
1.4                  dev-python/elasticsearch-curator/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/elasticsearch-curator/ChangeLog?rev=1.4&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/elasticsearch-curator/ChangeLog?rev=1.4&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/elasticsearch-curator/ChangeLog?r1=1.3&r2=1.4

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/elasticsearch-curator/ChangeLog,v
retrieving revision 1.3
retrieving revision 1.4
diff -u -r1.3 -r1.4
--- ChangeLog	7 Jun 2015 13:14:29 -0000	1.3
+++ ChangeLog	23 Jul 2015 08:54:36 -0000	1.4
@@ -1,6 +1,12 @@
 # ChangeLog for dev-python/elasticsearch-curator
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/elasticsearch-curator/ChangeLog,v 1.3 2015/06/07 13:14:29 jlec Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/elasticsearch-curator/ChangeLog,v 1.4 2015/07/23 08:54:36 idella4 Exp $
+
+*elasticsearch-curator-3.2.3 (23 Jul 2015)
+
+  23 Jul 2015; Ian Delaney <idella4@g.o>
+  +elasticsearch-curator-3.2.3.ebuild:
+  bump
 
   07 Jun 2015; Justin Lecher <jlec@g.o> metadata.xml:
   Add github to remote-id in metadata.xml



1.1                  dev-python/elasticsearch-curator/elasticsearch-curator-3.2.3.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/elasticsearch-curator/elasticsearch-curator-3.2.3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/elasticsearch-curator/elasticsearch-curator-3.2.3.ebuild?rev=1.1&content-type=text/plain

Index: elasticsearch-curator-3.2.3.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/elasticsearch-curator/elasticsearch-curator-3.2.3.ebuild,v 1.1 2015/07/23 08:54:36 idella4 Exp $

EAPI=5

PYTHON_COMPAT=( python{2_7,3_3,3_4} )

MY_PN="curator"
ES_VERSION="1.7.0"

inherit distutils-r1

DESCRIPTION="Tending time-series indices in Elasticsearch"
HOMEPAGE="https://github.com/elasticsearch/curator"
SRC_URI="https://github.com/elasticsearch/${MY_PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz
	test? ( https://download.elasticsearch.org/elasticsearch/elasticsearch/elasticsearch-${ES_VERSION}.tar.gz )"

LICENSE="Apache-2.0"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="doc test"

RDEPEND="
	>=dev-python/elasticsearch-py-1.0.0[${PYTHON_USEDEP}]
	<dev-python/elasticsearch-py-2.0.0[${PYTHON_USEDEP}]
	>=dev-python/click-3.3[${PYTHON_USEDEP}]
	dev-python/certifi[${PYTHON_USEDEP}]"
DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
	test? ( ${RDEPEND}
		|| ( virtual/jre:1.8 virtual/jre:1.7 )
		dev-python/mock[${PYTHON_USEDEP}]
		dev-python/nose[${PYTHON_USEDEP}]
		dev-python/coverage[${PYTHON_USEDEP}]
		dev-python/nosexcover[${PYTHON_USEDEP}]
		dev-python/six[${PYTHON_USEDEP}] )
	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )"

S="${WORKDIR}/${MY_PN}-${PV}"

python_test() {
	ES="${WORKDIR}/elasticsearch-${ES_VERSION}"
	ES_PORT="25123"
	ES_LOG="${ES}/logs/elasticsearch.log"
	PID="${ES}/elasticsearch.pid"

	# run Elasticsearch instance on custom port
	sed -i "s/#http.port: 9200/http.port: ${ES_PORT}/g; \
		s/#cluster.name: elasticsearch/cluster.name: gentoo-es-curator-test/g" \
		${ES}/config/elasticsearch.yml

	# Elasticsearch 1.6+ needs to set path.repo
	echo "path.repo: /" >> ${ES}/config/elasticsearch.yml

	# start local instance of elasticsearch
	${ES}/bin/elasticsearch -d -p ${PID}

	for i in `seq 10`; do
		grep -q "started" ${ES_LOG} 2> /dev/null
		if [ $? -eq 0 ]; then
			einfo "Elasticsearch started"
			eend 0
			break
		elif grep -q 'BindException\[Address already in use\]' "${ES_LOG}" 2>/dev/null; then
			eend 1
			eerror "Elasticsearch already running"
			die "Cannot start Elasticsearch for tests"
		else
			einfo "Waiting for Elasticsearch"
			eend 1
			sleep 2
			continue
		fi
	done

	export TEST_ES_SERVER="localhost:${ES_PORT}"
	esetup.py test || die "Tests failed on ${EPYTHON}"

	pkill -F ${PID}
}

python_compile_all() {
	use doc && emake -C docs html
}

python_install_all() {
	use doc && local HTML_DOCS=( docs/_build/html/. )
	distutils-r1_python_install_all
}

pkg_postinst() {
	ewarn ""
	ewarn "For Python 3 support information please read: http://click.pocoo.org/3/python3/"
	ewarn ""
	ewarn "Example usage on Python 3:"
	ewarn "export LC_ALL=en_US.UTF-8"
	ewarn "export LANG=en_US.UTF-8"
	ewarn "curator ..."
}