[gentoo-commits] gentoo-x86 commit in dev-libs/eet: ChangeLog eet-1.4.1.ebuild

[Thomas Sachau (tommy)]

tommy       11/05/29 16:04:51

  Modified:             ChangeLog
  Added:                eet-1.4.1.ebuild
  Log:
  Version bump
  
  (Portage version: 2.2.0_alpha37-r1/cvs/Linux x86_64)

Revision  Changes    Path
1.17                 dev-libs/eet/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/eet/ChangeLog?rev=1.17&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/eet/ChangeLog?rev=1.17&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/eet/ChangeLog?r1=1.16&r2=1.17

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/eet/ChangeLog,v
retrieving revision 1.16
retrieving revision 1.17
diff -u -r1.16 -r1.17
--- ChangeLog	25 Feb 2011 19:35:52 -0000	1.16
+++ ChangeLog	29 May 2011 16:04:51 -0000	1.17
@@ -1,6 +1,11 @@
 # ChangeLog for dev-libs/eet
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/eet/ChangeLog,v 1.16 2011/02/25 19:35:52 signals Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/eet/ChangeLog,v 1.17 2011/05/29 16:04:51 tommy Exp $
+
+*eet-1.4.1 (29 May 2011)
+
+  29 May 2011; Thomas Sachau (Tommy[D]) <tommy@g.o> +eet-1.4.1.ebuild:
+  Version bump
 
   25 Feb 2011; Kevin McCarthy <signals@g.o> eet-1.4.0.ebuild:
   Update depends from media-libs/jpeg to virtual/jpeg



1.1                  dev-libs/eet/eet-1.4.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/eet/eet-1.4.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/eet/eet-1.4.1.ebuild?rev=1.1&content-type=text/plain

Index: eet-1.4.1.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/eet/eet-1.4.1.ebuild,v 1.1 2011/05/29 16:04:51 tommy Exp $

EAPI=2

inherit enlightenment

DESCRIPTION="E file chunk reading/writing library"
HOMEPAGE="http://trac.enlightenment.org/e/wiki/Eet"
SRC_URI="http://download.enlightenment.org/releases/${P}.tar.bz2"

KEYWORDS="~amd64 ~x86"
IUSE="debug examples gnutls ssl static-libs test +threads"

RDEPEND=">=dev-libs/eina-1.0.0_beta
	virtual/jpeg
	sys-libs/zlib
	gnutls? ( net-libs/gnutls )
	!gnutls? ( ssl? ( dev-libs/openssl ) )"
DEPEND="${RDEPEND}
	test? ( dev-libs/check
		dev-util/lcov )"

src_configure() {
	local SSL_FLAGS=""

	if use gnutls; then
		if use ssl; then
			ewarn "You have enabled both 'ssl' and 'gnutls', so we will use"
			ewarn "gnutls and not openssl for cipher and signature support"
		fi
		SSL_FLAGS="
			--enable-cipher
			--enable-signature
			--disable-openssl
			--enable-gnutls"
	elif use ssl; then
		SSL_FLAGS="
			--enable-cipher
			--enable-signature
			--enable-openssl
			--disable-gnutls"
	else
		SSL_FLAGS="
			--disable-cipher
			--disable-signature
			--disable-openssl
			--disable-gnutls"
	fi

	export MY_ECONF="
		$(use_enable !debug amalgamation)
		$(use_enable debug assert)
		$(use_enable doc)
		$(use_enable test tests)
		$(use_enable test coverage)
		$(use_enable threads posix-threads)
		${SSL_FLAGS}
		${MY_ECONF}"

	enlightenment_src_configure
}

src_install() {
	enlightenment_src_install
	rm -r src/examples/Makefile* || die
	docinto examples
	dodoc src/examples/* || die
}