[gentoo-commits] gentoo-x86 commit in sys-boot/unetbootin: ChangeLog unetbootin-581.ebuild

[Jeroen Roovers (jer)]

jer         12/08/27 10:06:48

  Modified:             ChangeLog
  Added:                unetbootin-581.ebuild
  Log:
  Version bump. Fix desktop file issues.
  
  (Portage version: 2.2.0_alpha123/cvs/Linux x86_64)

Revision  Changes    Path
1.87                 sys-boot/unetbootin/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-boot/unetbootin/ChangeLog?rev=1.87&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-boot/unetbootin/ChangeLog?rev=1.87&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-boot/unetbootin/ChangeLog?r1=1.86&r2=1.87

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-boot/unetbootin/ChangeLog,v
retrieving revision 1.86
retrieving revision 1.87
diff -u -r1.86 -r1.87
--- ChangeLog	16 Aug 2012 08:07:05 -0000	1.86
+++ ChangeLog	27 Aug 2012 10:06:48 -0000	1.87
@@ -1,6 +1,12 @@
 # ChangeLog for sys-boot/unetbootin
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-boot/unetbootin/ChangeLog,v 1.86 2012/08/16 08:07:05 johu Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-boot/unetbootin/ChangeLog,v 1.87 2012/08/27 10:06:48 jer Exp $
+
+*unetbootin-581 (27 Aug 2012)
+
+  27 Aug 2012; Jeroen Roovers <jer@g.o> +unetbootin-581.ebuild,
+  +files/unetbootin-581-desktop.patch:
+  Version bump. Fix desktop file issues.
 
   16 Aug 2012; Johannes Huber <johu@g.o> unetbootin-578.ebuild:
   Stable for x86, wrt bug #431592



1.1                  sys-boot/unetbootin/unetbootin-581.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-boot/unetbootin/unetbootin-581.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-boot/unetbootin/unetbootin-581.ebuild?rev=1.1&content-type=text/plain

Index: unetbootin-581.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-boot/unetbootin/unetbootin-581.ebuild,v 1.1 2012/08/27 10:06:48 jer Exp $

EAPI="4"

inherit qt4-r2

DESCRIPTION="Universal Netboot Installer creates Live USB systems for various OS
distributions."
HOMEPAGE="http://unetbootin.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${PN}-source-${PV}.tar.gz"

SLOT="0"
LICENSE="GPL-2"
KEYWORDS="~amd64 ~x86"
IUSE=""

UNBI_LINGUAS="
	am ar ast be bg bn ca cs da de el eo es et eu fi fo fr gl he hr hu id it ja lt
	lv ml ms nan nb nl nn pl pt pt_BR ro ru sk sl sr sv sw tr uk ur vi zh_CN zh_TW
"

for lingua in ${UNBI_LINGUAS}; do
	IUSE="${IUSE} linguas_${lingua}"
done

S="${WORKDIR}"

DEPEND="x11-libs/qt-gui:4"
RDEPEND="${DEPEND}
		 sys-fs/mtools
		 sys-boot/syslinux
		 app-arch/p7zip"

src_prepare() {
	epatch "${FILESDIR}/${P}-desktop.patch"

	# QA check in case linguas are added or removed
	enum() {
		echo ${#}
	}
	[[ $(enum ${UNBI_LINGUAS}) -eq $(( $(enum $(echo ${PN}_*.ts) ) -1 )) ]] \
		|| die "Numbers of recorded and actual linguas do not match"
	unset enum

	# Put all localisation file names on a single line
	sed -i ${PN}.pro \
		-e ':a;/unetbootin_[[:graph:]]*\.ts \\/{N;s|\\\n| |;s|    ||g;ba}' \
		|| die

	# Remove localisations
	local lingua
	for lingua in ${UNBI_LINGUAS}; do
		if ! use linguas_${lingua}; then
			sed -i ${PN}.pro -e "s| ${PN}_${lingua}.ts||g" || die
			rm ${PN}_${lingua}.ts || die
		fi
	done
}

src_configure() {
	lupdate ${PN}.pro || die
	lrelease ${PN}.pro || die
	eqmake4 ${PN}.pro || die
}

src_install() {
	dobin ${PN}

	insinto /usr/share/applications
	doins ${PN}.desktop

	for file in ${PN}*.png; do
		size="${file/${PN}_}"
		size="${size/.png}x${size/.png}"
		insinto /usr/share/icons/hicolor/${size}/apps
		newins ${file} ${PN}.png
	done

	local lingua
	for lingua in ${UNBI_LINGUAS}; do
		if use linguas_${lingua}; then
			insinto /usr/share/${PN}
			doins ${PN}_${lingua}.qm
		fi
	done
}