[gentoo-commits] gentoo-x86 commit in gnome-extra/gnome-tweak-tool: ChangeLog gnome-tweak-tool-3.2.2-r1.ebuild

[Alexandre Rostovtsev (tetromino)]

tetromino    11/12/26 04:16:32

  Modified:             ChangeLog
  Added:                gnome-tweak-tool-3.2.2-r1.ebuild
  Log:
  Update for new user theme extension ID in gnome-shell-extensions-3.2.2 (bug #395733, thanks to Stefan Zwanenburg for reporting).
  
  (Portage version: 2.2.0_alpha83/cvs/Linux x86_64)

Revision  Changes    Path
1.3                  gnome-extra/gnome-tweak-tool/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/gnome-tweak-tool/ChangeLog?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/gnome-tweak-tool/ChangeLog?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/gnome-tweak-tool/ChangeLog?r1=1.2&r2=1.3

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/gnome-extra/gnome-tweak-tool/ChangeLog,v
retrieving revision 1.2
retrieving revision 1.3
diff -u -r1.2 -r1.3
--- ChangeLog	20 Nov 2011 19:47:06 -0000	1.2
+++ ChangeLog	26 Dec 2011 04:16:32 -0000	1.3
@@ -1,6 +1,14 @@
 # ChangeLog for gnome-extra/gnome-tweak-tool
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-extra/gnome-tweak-tool/ChangeLog,v 1.2 2011/11/20 19:47:06 eva Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-extra/gnome-tweak-tool/ChangeLog,v 1.3 2011/12/26 04:16:32 tetromino Exp $
+
+*gnome-tweak-tool-3.2.2-r1 (26 Dec 2011)
+
+  26 Dec 2011; Alexandre Rostovtsev (tetromino) <tetromino@×××××.com>
+  +gnome-tweak-tool-3.2.2-r1.ebuild,
+  +files/gnome-tweak-tool-3.2.2-user-theme-ext-id.patch:
+  Update for new user theme extension ID in gnome-shell-extensions-3.2.2 (bug
+  #395733, thanks to Stefan Zwanenburg for reporting).
 
 *gnome-tweak-tool-3.2.2 (20 Nov 2011)
 



1.1                  gnome-extra/gnome-tweak-tool/gnome-tweak-tool-3.2.2-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/gnome-tweak-tool/gnome-tweak-tool-3.2.2-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/gnome-tweak-tool/gnome-tweak-tool-3.2.2-r1.ebuild?rev=1.1&content-type=text/plain

Index: gnome-tweak-tool-3.2.2-r1.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/gnome-extra/gnome-tweak-tool/gnome-tweak-tool-3.2.2-r1.ebuild,v 1.1 2011/12/26 04:16:32 tetromino Exp $

EAPI="4"
GNOME2_LA_PUNT="yes"
GCONF_DEBUG="no"
PYTHON_DEPEND="2:2.6"

inherit eutils gnome2 python

DESCRIPTION="Tool to customize GNOME 3 options"
HOMEPAGE="http://live.gnome.org/GnomeTweakTool"

LICENSE="GPL-2"
SLOT="0"
IUSE=""
KEYWORDS="~amd64 ~x86"

COMMON_DEPEND="
	>=gnome-base/gsettings-desktop-schemas-3
	>=dev-python/pygobject-2.90.0:3
	gnome-base/gconf:2"
# g-s-d, gnome-shell etc. needed at runtime for the gsettings schemas
RDEPEND="${COMMON_DEPEND}
	gnome-base/gconf:2[introspection]
	x11-libs/gtk+:3[introspection]

	>=gnome-base/gnome-settings-daemon-3
	gnome-base/gnome-shell
	>=gnome-base/nautilus-3
	x11-wm/metacity"
DEPEND="${COMMON_DEPEND}
	>=dev-util/intltool-0.40.0
	>=dev-util/pkgconfig-0.9
	>=sys-devel/gettext-0.17"

pkg_setup() {
	DOCS="AUTHORS NEWS README"
	G2CONF="${G2CONF} --disable-schemas-compile"
	python_set_active_version 2
	python_pkg_setup
}

src_prepare() {
	# Add contents of Gentoo's cursor theme directory to cursor theme list
	epatch "${FILESDIR}/${PN}-3.0.4-gentoo-cursor-themes.patch"

	# Patch from upstream git master; user theme extension ID changed in 3.2.2
	epatch "${FILESDIR}/${PN}-3.2.2-user-theme-ext-id.patch"

	# disable pyc compiling
	mv py-compile py-compile.orig
	ln -s $(type -P true) py-compile

	gnome2_src_prepare
}

src_install() {
	gnome2_src_install
	python_convert_shebangs 2 "${ED}"/usr/bin/gnome-tweak-tool
}

pkg_postinst() {
	gnome2_pkg_postinst
	python_mod_optimize gtweak
}

pkg_postrm() {
	gnome2_pkg_postrm
	python_mod_cleanup gtweak
}