[gentoo-commits] gentoo-x86 commit in app-vim/vim-latex: vim-latex-1.8.23.20130116.ebuild metadata.xml ChangeLog

[Tim Harder (radhermit)]

radhermit    13/04/01 08:52:51

  Modified:             metadata.xml ChangeLog
  Added:                vim-latex-1.8.23.20130116.ebuild
  Log:
  Version bump, add python use flag (bug #458634).
  
  (Portage version: 2.2.0_alpha169/cvs/Linux x86_64, signed Manifest commit with key 4AB3E85B4F064CA3)

Revision  Changes    Path
1.4                  app-vim/vim-latex/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-vim/vim-latex/metadata.xml?rev=1.4&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-vim/vim-latex/metadata.xml?rev=1.4&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-vim/vim-latex/metadata.xml?r1=1.3&r2=1.4

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-vim/vim-latex/metadata.xml,v
retrieving revision 1.3
retrieving revision 1.4
diff -u -r1.3 -r1.4
--- metadata.xml	17 Mar 2013 23:32:06 -0000	1.3
+++ metadata.xml	1 Apr 2013 08:52:51 -0000	1.4
@@ -10,5 +10,6 @@
 	</maintainer>
 	<use>
 		<flag name="html">Install HTML documentation</flag>
+		<flag name="python">Enable python support which can help speed up some functionality</flag>
 	</use>
 </pkgmetadata>



1.22                 app-vim/vim-latex/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-vim/vim-latex/ChangeLog?rev=1.22&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-vim/vim-latex/ChangeLog?rev=1.22&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-vim/vim-latex/ChangeLog?r1=1.21&r2=1.22

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-vim/vim-latex/ChangeLog,v
retrieving revision 1.21
retrieving revision 1.22
diff -u -r1.21 -r1.22
--- ChangeLog	17 Mar 2013 23:32:06 -0000	1.21
+++ ChangeLog	1 Apr 2013 08:52:51 -0000	1.22
@@ -1,6 +1,12 @@
 # ChangeLog for app-vim/vim-latex
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-vim/vim-latex/ChangeLog,v 1.21 2013/03/17 23:32:06 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-vim/vim-latex/ChangeLog,v 1.22 2013/04/01 08:52:51 radhermit Exp $
+
+*vim-latex-1.8.23.20130116 (01 Apr 2013)
+
+  01 Apr 2013; Tim Harder <radhermit@g.o>
+  +vim-latex-1.8.23.20130116.ebuild, metadata.xml:
+  Version bump, add python use flag (bug #458634).
 
   17 Mar 2013; Tim Harder <radhermit@g.o> metadata.xml:
   Remove proxy-maintainers from metadata.



1.1                  app-vim/vim-latex/vim-latex-1.8.23.20130116.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-vim/vim-latex/vim-latex-1.8.23.20130116.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-vim/vim-latex/vim-latex-1.8.23.20130116.ebuild?rev=1.1&content-type=text/plain

Index: vim-latex-1.8.23.20130116.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-vim/vim-latex/vim-latex-1.8.23.20130116.ebuild,v 1.1 2013/04/01 08:52:51 radhermit Exp $

EAPI=5
PYTHON_COMPAT=( python{2_5,2_6,2_7} )

inherit vim-plugin versionator python-single-r1

MY_REV="788-git2ef9956"
MY_P="${PN}-$( replace_version_separator 3 - ).${MY_REV}"

DESCRIPTION="vim plugin: a comprehensive set of tools to view, edit and compile LaTeX documents"
HOMEPAGE="http://vim-latex.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.gz"

LICENSE="vim"
KEYWORDS="~alpha ~amd64 ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos ~sparc-solaris"
IUSE="html python"

RDEPEND="|| ( app-editors/vim[python?] app-editors/gvim[python?] )
	virtual/latex-base"

S=${WORKDIR}/${MY_P}

VIM_PLUGIN_HELPFILES="latex-suite.txt latex-suite-quickstart.txt latexhelp.txt imaps.txt"

src_prepare() {
	# The makefiles do weird stuff, including running the svn command
	rm Makefile Makefile.in || die "rm Makefile Makefile.in failed"
}

src_install() {
	use html && dohtml -r doc/

	# Don't mess up vim's doc dir with random files
	mv doc mydoc || die
	mkdir doc || die
	mv mydoc/*.txt doc/ || die
	rm -rf mydoc || die

	# Don't install buggy tags scripts, use ctags instead
	rm latextags ltags || die

	vim-plugin_src_install

	# Use executable permissions (bug #352403)
	fperms a+x /usr/share/vim/vimfiles/ftplugin/latex-suite/outline.py

	python_fix_shebang "${ED}"
}

pkg_postinst() {
	vim-plugin_pkg_postinst
	elog
	elog "To use the vim-latex plugin add:"
	elog "   filetype plugin on"
	elog '   set grepprg=grep\ -nH\ $*'
	elog "   let g:tex_flavor='latex'"
	elog "to your ~/.vimrc-file"
	elog
}