[gentoo-commits] gentoo-x86 commit in media-libs/clutter: metadata.xml ChangeLog clutter-1.12.2-r1.ebuild

[Justin Lecher (jlec)]

jlec        13/06/05 14:58:47

  Modified:             metadata.xml ChangeLog
  Added:                clutter-1.12.2-r1.ebuild
  Log:
  media-libs/clutter: Backport patch to fix segfault due to unrespected array bounds, #469196
  
  (Portage version: 2.2.0_alpha177/cvs/Linux x86_64, signed Manifest commit with key 8009D6F070EB7916)

Revision  Changes    Path
1.4                  media-libs/clutter/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/clutter/metadata.xml?rev=1.4&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/clutter/metadata.xml?rev=1.4&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/clutter/metadata.xml?r1=1.3&r2=1.4

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-libs/clutter/metadata.xml,v
retrieving revision 1.3
retrieving revision 1.4
diff -u -r1.3 -r1.4
--- metadata.xml	16 Dec 2012 22:04:03 -0000	1.3
+++ metadata.xml	5 Jun 2013 14:58:46 -0000	1.4
@@ -1,8 +1,8 @@
 <?xml version="1.0" encoding="UTF-8"?>
 <!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
 <pkgmetadata>
-<herd>gnome</herd>
-<use>
-	<flag name="gtk">Use gdk-pixbuf from <pkg>x11-libs/gtk+</pkg> as image rendering backend</flag>
-</use>
+  <herd>gnome</herd>
+  <use>
+    <flag name="gtk">Use gdk-pixbuf from <pkg>x11-libs/gtk+</pkg> as image rendering backend</flag>
+  </use>
 </pkgmetadata>



1.72                 media-libs/clutter/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/clutter/ChangeLog?rev=1.72&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/clutter/ChangeLog?rev=1.72&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/clutter/ChangeLog?r1=1.71&r2=1.72

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-libs/clutter/ChangeLog,v
retrieving revision 1.71
retrieving revision 1.72
diff -u -r1.71 -r1.72
--- ChangeLog	15 May 2013 07:01:15 -0000	1.71
+++ ChangeLog	5 Jun 2013 14:58:46 -0000	1.72
@@ -1,6 +1,12 @@
 # ChangeLog for media-libs/clutter
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/clutter/ChangeLog,v 1.71 2013/05/15 07:01:15 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/clutter/ChangeLog,v 1.72 2013/06/05 14:58:46 jlec Exp $
+
+*clutter-1.12.2-r1 (05 Jun 2013)
+
+  05 Jun 2013; Justin Lecher <jlec@g.o> +clutter-1.12.2-r1.ebuild,
+  +files/clutter-1.12.2-array-bounds.patch, metadata.xml:
+  Backport patch to fix segfault due to unrespected array bounds, #469196
 
 *clutter-1.14.4 (15 May 2013)
 



1.1                  media-libs/clutter/clutter-1.12.2-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/clutter/clutter-1.12.2-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/clutter/clutter-1.12.2-r1.ebuild?rev=1.1&content-type=text/plain

Index: clutter-1.12.2-r1.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-libs/clutter/clutter-1.12.2-r1.ebuild,v 1.1 2013/06/05 14:58:46 jlec Exp $

EAPI="5"
CLUTTER_LA_PUNT="yes"

# Inherit gnome2 after clutter to download sources from gnome.org
# since clutter-project.org doesn't provide .xz tarballs
inherit clutter gnome2 virtualx

DESCRIPTION="Clutter is a library for creating graphical user interfaces"

LICENSE="LGPL-2.1+ FDL-1.1+"
SLOT="1.0"
IUSE="debug doc gtk +introspection test" # evdev tslib
KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86"

# NOTE: glx flavour uses libdrm + >=mesa-7.3
# XXX: uprof needed for profiling
# >=libX11-1.3.1 needed for X Generic Event support
RDEPEND="
	>=dev-libs/glib-2.31.19:2
	>=dev-libs/atk-2.5.3[introspection?]
	>=dev-libs/json-glib-0.12[introspection?]
	>=media-libs/cogl-1.9.6:1.0=[introspection?,pango]
	media-libs/fontconfig
	>=x11-libs/cairo-1.10:=[glib]
	>=x11-libs/pango-1.30[introspection?]

	virtual/opengl
	x11-libs/libdrm:=
	>=x11-libs/libX11-1.3.1
	x11-libs/libXext
	x11-libs/libXdamage
	x11-proto/inputproto
	>=x11-libs/libXi-1.3
	>=x11-libs/libXfixes-3
	>=x11-libs/libXcomposite-0.4

	gtk? ( >=x11-libs/gtk+-3.3.18:3 )
	introspection? ( >=dev-libs/gobject-introspection-0.9.6 )"
DEPEND="${RDEPEND}
	>=dev-util/gtk-doc-am-1.15
	virtual/pkgconfig
	>=sys-devel/gettext-0.17
	doc? (
		>=dev-util/gtk-doc-1.15
		>=app-text/docbook-sgml-utils-0.6.14[jadetex]
		dev-libs/libxslt )
	test? ( x11-libs/gdk-pixbuf )"

# Tests fail with both swrast and llvmpipe
# They pass under r600g or i965, so the bug is in mesa
RESTRICT="test"

src_prepare() {
	DOCS="README NEWS ChangeLog*"

	# XXX: Conformance test suite (and clutter itself) does not work under Xvfb
	# (GLX error blabla)
	# XXX: Profiling, coverage disabled for now
	# XXX: What about cex100/egl/osx/wayland/win32 backends?
	# XXX: evdev/tslib input seem to be experimental?
	G2CONF="${G2CONF} ${myconf}
		--enable-xinput
		--enable-x11-backend=yes
		--disable-profile
		--disable-maintainer-flags
		--disable-gcov
		--disable-cex100-backend
		--disable-egl-backend
		--disable-quartz-backend
		--disable-wayland-backend
		--disable-win32-backend
		--disable-tslib-input
		--disable-evdev-input
		$(usex debug --enable-debug=yes --enable-debug=minimum)
		$(use_enable gtk gdk-backend)
		$(use_enable introspection)
		$(use_enable doc docs)
		$(use_enable test conformance)
		$(use_enable test gdk-pixbuf)"

	# We only need conformance tests, the rest are useless for us
	sed -e 's/^\(SUBDIRS =\).*/\1/g' \
		-i tests/Makefile.am || die "am tests sed failed"
	sed -e 's/^\(SUBDIRS =\)[^\]*/\1/g' \
		-i tests/Makefile.in || die "in tests sed failed"

	epatch "${FILESDIR}"/${P}-array-bounds.patch

	gnome2_src_prepare
}

src_compile() {
	default
	if use test; then
		emake -C tests/conform
	fi
}

src_test() {
	Xemake check
}

src_install() {
	clutter_src_install
}