[gentoo-commits] gentoo-x86 commit in media-plugins/audacious-plugins: audacious-plugins-3.4.1.ebuild ChangeLog

[Jeff Horelick (jdhore)]

jdhore      13/09/02 21:12:53

  Modified:             ChangeLog
  Added:                audacious-plugins-3.4.1.ebuild
  Log:
  Version bump
  
  (Portage version: 2.2.1/cvs/Linux i686, unsigned Manifest commit)

Revision  Changes    Path
1.265                media-plugins/audacious-plugins/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-plugins/audacious-plugins/ChangeLog?rev=1.265&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-plugins/audacious-plugins/ChangeLog?rev=1.265&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-plugins/audacious-plugins/ChangeLog?r1=1.264&r2=1.265

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-plugins/audacious-plugins/ChangeLog,v
retrieving revision 1.264
retrieving revision 1.265
diff -u -r1.264 -r1.265
--- ChangeLog	7 Feb 2013 07:10:53 -0000	1.264
+++ ChangeLog	2 Sep 2013 21:12:53 -0000	1.265
@@ -1,6 +1,12 @@
 # ChangeLog for media-plugins/audacious-plugins
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-plugins/audacious-plugins/ChangeLog,v 1.264 2013/02/07 07:10:53 jdhore Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-plugins/audacious-plugins/ChangeLog,v 1.265 2013/09/02 21:12:53 jdhore Exp $
+
+*audacious-plugins-3.4.1 (02 Sep 2013)
+
+  02 Sep 2013; Jeff Horelick <jdhore@g.o>
+  +audacious-plugins-3.4.1.ebuild:
+  Version bump
 
 *audacious-plugins-3.3.4 (07 Feb 2013)
 



1.1                  media-plugins/audacious-plugins/audacious-plugins-3.4.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-plugins/audacious-plugins/audacious-plugins-3.4.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-plugins/audacious-plugins/audacious-plugins-3.4.1.ebuild?rev=1.1&content-type=text/plain

Index: audacious-plugins-3.4.1.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-plugins/audacious-plugins/audacious-plugins-3.4.1.ebuild,v 1.1 2013/09/02 21:12:53 jdhore Exp $

EAPI=5
inherit eutils

MY_P="${P/_/-}"
S="${WORKDIR}/${MY_P}"
DESCRIPTION="Audacious Player - Your music, your way, no exceptions"
HOMEPAGE="http://audacious-media-player.org/"
SRC_URI="http://distfiles.audacious-media-player.org/${MY_P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~hppa ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~x86-linux"
IUSE="aac adplug alsa bs2b cdda cue ffmpeg flac fluidsynth gnome ipv6 jack
lame libnotify libsamplerate lirc midi mms mp3 nls pulseaudio scrobbler sdl sid sndfile vorbis wavpack"

RDEPEND="app-arch/unzip
	>=dev-libs/dbus-glib-0.60
	dev-libs/libxml2:2
	media-libs/libmodplug
	~media-sound/audacious-3.4.1
	>=net-libs/neon-0.26.4
	x11-libs/gtk+:3
	( || ( >=dev-libs/glib-2.32.2 dev-util/gdbus-codegen ) )
	aac? ( >=media-libs/faad2-2.7 )
	adplug? ( >=dev-cpp/libbinio-1.4 )
	alsa? ( >=media-libs/alsa-lib-1.0.16 )
	bs2b? ( media-libs/libbs2b )
	cdda? ( >=media-libs/libcddb-1.2.1
		|| ( dev-libs/libcdio-paranoia <dev-libs/libcdio-0.90[-minimal] ) )
	cue? ( media-libs/libcue )
	ffmpeg? ( >=virtual/ffmpeg-0.7.3 )
	flac? ( >=media-libs/libvorbis-1.0
		>=media-libs/flac-1.2.1-r1 )
	fluidsynth? ( media-sound/fluidsynth )
	jack? ( >=media-libs/bio2jack-0.4
		media-sound/jack-audio-connection-kit )
	lame? ( media-sound/lame )
	libnotify? ( x11-libs/libnotify )
	libsamplerate? ( media-libs/libsamplerate )
	lirc? ( app-misc/lirc )
	mms? ( >=media-libs/libmms-0.3 )
	mp3? ( >=media-sound/mpg123-1.12.1 )
	pulseaudio? ( >=media-sound/pulseaudio-0.9.3 )
	scrobbler? ( net-misc/curl )
	sdl? ( media-libs/libsdl[audio] )
	sid? ( media-libs/libsidplayfp )
	sndfile? ( >=media-libs/libsndfile-1.0.17-r1 )
	vorbis? ( >=media-libs/libvorbis-1.2.0
		  >=media-libs/libogg-1.1.3 )
	wavpack? ( >=media-sound/wavpack-4.50.1-r1 )"

DEPEND="${RDEPEND}
	nls? ( dev-util/intltool )
	virtual/pkgconfig"

DOCS="AUTHORS"

mp3_warning() {
	if ! use mp3 ; then
		ewarn "MP3 support is optional, you may want to enable the mp3 USE-flag"
	fi
}

src_prepare() {
	has_version "<dev-libs/glib-2.32" && \
		cd "${S}"/src/mpris2 && \
		gdbus-codegen --interface-prefix org.mpris. \
			--c-namespace Mpris --generate-c-code object-core mpris2.xml && \
		gdbus-codegen --interface-prefix org.mpris. \
			--c-namespace Mpris \
			--generate-c-code object-player mpris2-player.xml && \
		cd "${S}"
}

src_configure() {
	mp3_warning

	econf \
		--enable-modplug \
		--disable-soxr \
		--enable-neon \
		$(use_enable adplug) \
		$(use_enable aac) \
		$(use_enable alsa) \
		$(use_enable alsa amidiplug-alsa) \
		$(use_enable bs2b) \
		$(use_enable cdda cdaudio) \
		$(use_enable cue) \
		$(use_enable ffmpeg ffaudio) \
		$(use_enable flac flacng) \
		$(use_enable fluidsynth amidiplug-flsyn) \
		$(use_enable flac filewriter_flac) \
		$(use_enable ipv6) \
		$(use_enable jack) \
		$(use_enable gnome gnomeshortcuts) \
		$(use_enable lame filewriter_mp3) \
		$(use_enable libnotify notify) \
		$(use_enable libsamplerate resample) \
		$(use_enable lirc) \
		$(use_enable mms) \
		$(use_enable mp3) \
		$(use_enable midi amidiplug) \
		$(use_enable nls) \
		$(use_enable pulseaudio pulse) \
		$(use_enable scrobbler) \
		$(use_enable sdl sdlout) \
		$(use_enable sid) \
		$(use_enable sndfile) \
		$(use_enable vorbis) \
		$(use_enable wavpack)
}