[gentoo-commits] gentoo-x86 commit in dev-db/couchdb: couchdb-1.5.1.ebuild ChangeLog

[Dirkjan Ochtman (djc)]

djc         14/06/05 08:10:53

  Modified:             ChangeLog
  Added:                couchdb-1.5.1.ebuild
  Log:
  Version bump couchdb to 1.5.1 (fixes bug 506354)
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key 30380381)

Revision  Changes    Path
1.94                 dev-db/couchdb/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-db/couchdb/ChangeLog?rev=1.94&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-db/couchdb/ChangeLog?rev=1.94&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-db/couchdb/ChangeLog?r1=1.93&r2=1.94

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-db/couchdb/ChangeLog,v
retrieving revision 1.93
retrieving revision 1.94
diff -u -r1.93 -r1.94
--- ChangeLog	24 Mar 2014 15:05:37 -0000	1.93
+++ ChangeLog	5 Jun 2014 08:10:53 -0000	1.94
@@ -1,6 +1,11 @@
 # ChangeLog for dev-db/couchdb
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-db/couchdb/ChangeLog,v 1.93 2014/03/24 15:05:37 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-db/couchdb/ChangeLog,v 1.94 2014/06/05 08:10:53 djc Exp $
+
+*couchdb-1.5.1 (05 Jun 2014)
+
+  05 Jun 2014; Dirkjan Ochtman <djc@g.o> +couchdb-1.5.1.ebuild:
+  Version bump couchdb to 1.5.1 (fixes bug 506354)
 
   24 Mar 2014; Agostino Sarubbo <ago@g.o> couchdb-1.5.0.ebuild:
   Stable for ppc, wrt bug #495362



1.1                  dev-db/couchdb/couchdb-1.5.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-db/couchdb/couchdb-1.5.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-db/couchdb/couchdb-1.5.1.ebuild?rev=1.1&content-type=text/plain

Index: couchdb-1.5.1.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-db/couchdb/couchdb-1.5.1.ebuild,v 1.1 2014/06/05 08:10:53 djc Exp $

EAPI=5

inherit eutils multilib pax-utils user

DESCRIPTION="Apache CouchDB is a distributed, fault-tolerant and schema-free document-oriented database."
HOMEPAGE="http://couchdb.apache.org/"
SRC_URI="mirror://apache/couchdb/source/${PV}/apache-${P}.tar.gz"

LICENSE="Apache-2.0"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="selinux test"

RDEPEND=">=dev-libs/icu-4.3.1:=
		dev-lang/erlang[ssl]
		>=dev-libs/openssl-0.9.8j:0
		>=net-misc/curl-7.18.2
		<dev-lang/spidermonkey-1.8.7
		selinux? ( sec-policy/selinux-couchdb )"

DEPEND="${RDEPEND}"
RESTRICT=test

S="${WORKDIR}/apache-${P}"

pkg_setup() {
	enewgroup couchdb
	enewuser couchdb -1 -1 /var/lib/couchdb couchdb
}

src_prepare() {
	sed -i ./src/couchdb/priv/Makefile.* -e 's|-Werror||g'
}

src_configure() {
	econf \
		--with-erlang=/usr/lib/erlang/usr/include \
		--localstatedir=/var \
		--with-js-lib=/usr/lib
	# bug 296609, upstream bug #COUCHDB-621
	sed -e "s#localdocdir = /usr/share/doc/couchdb#localdocdir = /usr/share/doc/${PF}#" -i Makefile || die "sed failed"
}

src_compile() {
	emake
	# bug 442616
	pax-mark mr src/couchdb/priv/couchjs
}

src_test() {
	emake distcheck
}

src_install() {
	emake DESTDIR="${D}" install

	fowners couchdb:couchdb \
		/var/lib/couchdb \
		/var/log/couchdb

	for f in "${D}"/etc/couchdb/*.ini ; do
		fowners root:couchdb "${f#${D}}"
		fperms 660 "${f#${D}}"
	done
	fperms 664 /etc/couchdb/default.ini

	newinitd "${FILESDIR}/couchdb.init-4" couchdb
	newconfd "${FILESDIR}/couchdb.conf-2" couchdb

	sed -i -e "s:LIBDIR:$(get_libdir):" "${D}/etc/conf.d/couchdb"
}