[gentoo-commits] repo/gentoo:master commit in: dev-libs/elfutils/

[Manuel Rüger]

commit:     84c99b77da0b644d8087cf9a76d2c163cb094878
Author:     Manuel Rüger <mrueg <AT> gentoo <DOT> org>
AuthorDate: Sun May 28 21:13:56 2017 +0000
Commit:     Manuel Rüger <mrueg <AT> gentoo <DOT> org>
CommitDate: Sun May 28 21:13:56 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=84c99b77

dev-libs/elfutils: Fix incorrect logic for IUSE=utils

Gentoo-Bug: #619658

Package-Manager: Portage-2.3.6, Repoman-2.3.1

 dev-libs/elfutils/elfutils-0.169-r1.ebuild | 64 ++++++++++++++++++++++++++++++
 1 file changed, 64 insertions(+)

diff --git a/dev-libs/elfutils/elfutils-0.169-r1.ebuild b/dev-libs/elfutils/elfutils-0.169-r1.ebuild
new file mode 100644
index 00000000000..47328a2ac4f
--- /dev/null
+++ b/dev-libs/elfutils/elfutils-0.169-r1.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit eutils flag-o-matic multilib-minimal
+
+DESCRIPTION="Libraries/utilities to handle ELF objects (drop in replacement for libelf)"
+HOMEPAGE="http://elfutils.org/"
+SRC_URI="https://sourceware.org/elfutils/ftp/${PV}/${P}.tar.bz2"
+
+LICENSE="|| ( GPL-2+ LGPL-3+ ) utils? ( GPL-3+ )"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-linux ~arm-linux ~x86-linux"
+IUSE="bzip2 lzma nls static-libs test +threads +utils"
+
+RDEPEND=">=sys-libs/zlib-1.2.8-r1[${MULTILIB_USEDEP}]
+	bzip2? ( >=app-arch/bzip2-1.0.6-r4[${MULTILIB_USEDEP}] )
+	lzma? ( >=app-arch/xz-utils-5.0.5-r1[${MULTILIB_USEDEP}] )
+	!dev-libs/libelf"
+DEPEND="${RDEPEND}
+	nls? ( sys-devel/gettext )
+	>=sys-devel/flex-2.5.4a
+	sys-devel/m4"
+
+src_prepare() {
+	default
+	epatch "${FILESDIR}"/${PN}-0.118-PaX-support.patch
+	if use static-libs; then
+		sed -i -e '/^lib_LIBRARIES/s:=.*:=:' -e '/^%.os/s:%.o$::' lib{asm,dw,elf}/Makefile.in || die
+	fi
+	sed -i 's:-Werror::' */Makefile.in || die
+}
+
+src_configure() {
+	use test && append-flags -g #407135
+	multilib-minimal_src_configure
+}
+
+multilib_src_configure() {
+	ECONF_SOURCE="${S}" econf \
+		$(use_enable nls) \
+		$(use_enable threads thread-safety) \
+		--program-prefix="eu-" \
+		--with-zlib \
+		$(use_with bzip2 bzlib) \
+		$(use_with lzma)
+}
+
+multilib_src_test() {
+	env	LD_LIBRARY_PATH="${BUILD_DIR}/libelf:${BUILD_DIR}/libebl:${BUILD_DIR}/libdw:${BUILD_DIR}/libasm" \
+		LC_ALL="C" \
+		emake check
+}
+
+multilib_src_install_all() {
+	einstalldocs
+	dodoc NOTES
+	# These build quick, and are needed for most tests, so don't
+	# disable their building when the USE flag is disabled.
+	if ! use utils; then
+		rm -rf "${ED}"/usr/bin || die
+	fi
+}